-
Notifications
You must be signed in to change notification settings - Fork 280
/
TreeView.re
302 lines (260 loc) · 8.33 KB
/
TreeView.re
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
open Revery;
open Revery.UI;
open Revery.UI.Components;
open Oni_Core;
open Utility;
module Log = (val Log.withNamespace("Oni2.UI.TreeView"));
module type TreeModel = {
type t;
let children: t => list(t);
let kind: t => [ | `Node([ | `Open | `Closed]) | `Leaf];
let expandedSubtreeSize: t => int;
};
module Constants = {
let arrowSize = 15;
let indentSize = 12.;
let scrollWheelMultiplier = 25;
let scrollBarThickness = 6;
let scrollTrackColor = Color.rgba(0.0, 0.0, 0.0, 0.4);
let scrollThumbColor = Color.rgba(0.5, 0.5, 0.5, 0.4);
};
module Styles = {
open Style;
let container = [overflow(`Hidden), flexGrow(1)];
let slider = [
position(`Absolute),
right(0),
top(0),
bottom(0),
width(Constants.scrollBarThickness),
];
let viewport = (~showScrollbar) => [
position(`Absolute),
top(0),
left(0),
bottom(0),
right(showScrollbar ? 0 : Constants.scrollBarThickness),
];
let content = (~scrollTop) => [
position(`Absolute),
top(- scrollTop),
left(0),
bottom(0),
];
let item = (~itemHeight) => [
height(itemHeight),
cursor(Revery.MouseCursors.pointer),
flexDirection(`Row),
overflow(`Hidden),
];
let placeholder = (~height) => [Style.height(height)];
let children = [transform(Transform.[TranslateX(Constants.indentSize)])];
let loading = [
fontFamily("selawk.ttf"),
fontSize(12),
color(Colors.white),
];
};
module Make = (Model: TreeModel) => {
let arrow = (~isOpen, ()) =>
<FontIcon
fontSize=Constants.arrowSize
color=Colors.white
icon={isOpen ? FontAwesome.caretDown : FontAwesome.caretRight}
backgroundColor=Colors.transparentWhite
/>;
let noArrow = () =>
<View
style=Style.[width(Constants.arrowSize), height(Constants.arrowSize)]
/>;
let rec nodeView =
(
~renderContent,
~itemHeight,
~clipRange as (clipStart, clipEnd),
~onClick,
~node,
(),
) => {
let subtreeSize = Model.expandedSubtreeSize(node);
let placeholder = (~size, ()) =>
<View style={Styles.placeholder(~height=size * itemHeight)} />;
let item = (~arrow, ()) =>
<Sneakable
onClick={() => onClick(node)} style={Styles.item(~itemHeight)}>
<arrow />
{renderContent(node)}
</Sneakable>;
let renderChildren = children => {
let rec loop = (count, elements, children) =>
switch (children) {
| [child, ...rest] =>
let element =
<nodeView
renderContent
itemHeight
clipRange=(clipStart - count, clipEnd - count)
onClick
node=child
/>;
loop(
count + Model.expandedSubtreeSize(child),
[element, ...elements],
rest,
);
| [] => elements |> List.rev |> React.listToElement
};
loop(1, [], children);
};
if (subtreeSize < clipStart || clipEnd < 0) {
<placeholder
// If the entire node is out of view, render a placeholder with the appropriate height
size=subtreeSize
/>;
} else {
switch (Model.kind(node)) {
| `Node(state) =>
<View>
<item arrow={arrow(~isOpen=state == `Open)} />
<View style=Styles.children>
{switch (state) {
| `Open => node |> Model.children |> renderChildren
| `Closed => React.empty
}}
</View>
</View>
| `Leaf => <item arrow=noArrow />
};
};
};
let useScroll = (~itemHeight, ~count, ~viewportHeight, ~scrollOffset) => {
// We need to keep the previous value to know which edge to align a revealed item to
let%hook (prevScrollTop, setPrevScrollTop) = Hooks.ref(0);
// The internal value is used if scrollOffset isn't being passed in
let%hook (internalScrollTop, setInternalScrollTop) = Hooks.state(0);
let targetScrollTop =
scrollOffset
|> Option.map(
fun
| `Start(offset) => int_of_float(offset *. float(itemHeight))
| `Middle(offset) => {
let pixelOffset = int_of_float(offset *. float(itemHeight));
let halfHeight = (viewportHeight - itemHeight) / 2;
pixelOffset - halfHeight;
}
| `Reveal(index) => {
let offset = index * itemHeight;
if (offset < prevScrollTop) {
// out of view above, so align with top edge
offset;
} else if (offset + itemHeight > prevScrollTop + viewportHeight) {
// out of view below, so align with bottom edge
offset + itemHeight - viewportHeight;
} else {
prevScrollTop;
};
},
)
|> Option.value(~default=internalScrollTop)
// Make sure we're not scrolled past the items
|> IntEx.clamp(~lo=0, ~hi=itemHeight * count - viewportHeight);
setPrevScrollTop(targetScrollTop);
let%hook (actualScrollTop, setScrollTopImmediately) =
Hooks.spring(
~target=float(targetScrollTop),
~restThreshold=3.,
Spring.Options.stiff,
);
let setScrollTopImmediately = updater =>
setInternalScrollTop(_ => {
let scrollTop' =
updater(targetScrollTop)
|> IntEx.clamp(~lo=0, ~hi=itemHeight * count - viewportHeight);
setScrollTopImmediately(float(scrollTop'));
scrollTop';
});
(int_of_float(actualScrollTop), setScrollTopImmediately);
};
let%component make =
(
~children as renderContent,
~itemHeight,
~initialRowsToRender=10,
~onClick,
~scrollOffset:
option(
[ | `Start(float) | `Middle(float) | `Reveal(int)],
)=?,
~onScrollOffsetChange:
[ | `Start(float) | `Middle(float) | `Reveal(int)] =>
unit=_ => (),
~tree,
(),
) => {
let%hook (outerRef, setOuterRef) = Hooks.ref(None);
let menuHeight =
switch (outerRef) {
| Some(node) =>
let dimensions: Dimensions.t = node#measurements();
dimensions.height;
| None => itemHeight * initialRowsToRender
};
let count = Model.expandedSubtreeSize(tree);
let%hook (scrollTop, setScrollTop) =
useScroll(
~itemHeight,
~count,
~viewportHeight=menuHeight,
~scrollOffset,
);
let setScrollTop = updater =>
setScrollTop(scrollTop => {
let scrollTop' = updater(scrollTop);
onScrollOffsetChange(
`Start(float(scrollTop') /. float(itemHeight)),
);
scrollTop';
});
let onMouseWheel = (wheelEvent: NodeEvents.mouseWheelEventParams) => {
let delta =
int_of_float(wheelEvent.deltaY) * (- Constants.scrollWheelMultiplier);
setScrollTop(target => target + delta);
};
let maxHeight = count * itemHeight - menuHeight;
let showScrollbar = maxHeight > 0;
let scrollbar = () => {
let thumbHeight = menuHeight * menuHeight / max(1, count * itemHeight);
<View style=Styles.slider>
<Slider
onValueChanged={value => setScrollTop(_ => int_of_float(value))}
minimumValue=0.
maximumValue={float_of_int(maxHeight)}
sliderLength=menuHeight
thumbLength=thumbHeight
value={float(scrollTop)}
trackThickness=Constants.scrollBarThickness
thumbThickness=Constants.scrollBarThickness
minimumTrackColor=Constants.scrollTrackColor
maximumTrackColor=Constants.scrollTrackColor
thumbColor=Constants.scrollThumbColor
vertical=true
/>
</View>;
};
let clipRange = (
scrollTop / itemHeight,
(scrollTop + menuHeight) / itemHeight,
);
<View
style=Styles.container
ref={ref => setOuterRef(Some(ref))}
onMouseWheel>
<View style={Styles.viewport(~showScrollbar)}>
<View style={Styles.content(~scrollTop)}>
<nodeView renderContent itemHeight clipRange onClick node=tree />
</View>
</View>
{showScrollbar ? <scrollbar /> : React.empty}
</View>;
};
};