-
Notifications
You must be signed in to change notification settings - Fork 40
/
build.gradle
506 lines (450 loc) · 18.6 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
/*
* Copyright (c) Contributors to the Eclipse Foundation
*
* Licensed under the Apache License, Version 2.0 (the "License");
* you may not use this file except in compliance with the License.
* You may obtain a copy of the License at
*
* http://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing, software
* distributed under the License is distributed on an "AS IS" BASIS,
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
* See the License for the specific language governing permissions and
* limitations under the License.
*
* SPDX-License-Identifier: Apache-2.0
*/
/*
* osgi.specs Gradle build script
*/
import org.apache.tools.ant.filters.ReplaceTokens
interface Injected {
@Inject ExecOperations getExec()
@Inject FileSystemOperations getFs()
}
version = bnd.get("osgi.version")
def licensed = bnd.get("licensed")
def saxon = bnd.get("saxon")
ext.fop_home = file("${licensed}/fop")
ext.fop_classpath = files(fileTree("dir": new File(fop_home, "lib"), "include": "*.jar"),
fileTree("dir": new File(fop_home, "build"), "includes": ["fop.jar", "fop-hyph.jar"]))
def javadoc = tasks.named("javadoc") {
description = "Build the docbook flavored javadoc."
group = "documentation"
/*
* Our doclet is based upon the pre-Java 9 doclet api
*/
javadocTool = javaToolchains.javadocToolFor {
languageVersion = JavaLanguageVersion.of(8)
}
def destinationDirectory = objects.directoryProperty().convention(layout.getBuildDirectory().dir("javadoc"))
destinationDir = file(destinationDirectory)
def javadocxml = destinationDirectory.file("javadoc.xml")
def docbookDir = destinationDirectory.dir("docbook")
def stylesheet = file("docbook/xsl/javadoc2docbook.xsl")
classpath = sourceSets.main.compileClasspath
source = bnd.allSrcDirs
bnd.get("javadoc.specs").split(/\s*,\s*/).each {
include it.replace((char)'.',(char)'/')+"/**/*.java"
}
title = ""
options.memberLevel = JavadocMemberLevel.PROTECTED
options.encoding = "UTF-8"
options.noTimestamp = false
options.doclet = "org.osgi.tools.xmldoclet.XmlDoclet"
options.docletpath = sourceSets.main.output.files as List
inputs.files(sourceSets.main.output).withPathSensitivity(PathSensitivity.RELATIVE).withPropertyName("docletpath")
inputs.file(stylesheet).withPathSensitivity(PathSensitivity.RELATIVE).withPropertyName("stylesheet")
doLast("xslt") { t ->
def javadocxmlFile = javadocxml.get().getAsFile()
def docbookDirFile = docbookDir.get().getAsFile()
ant.xslt("style": stylesheet,
"in": javadocxmlFile,
"out": new File(temporaryDir, "javadoc.txt"),
"force": true) {
classpath("location": saxon)
factory("name": "com.icl.saxon.TransformerFactoryImpl")
param("name": "destdir", "expression": docbookDirFile)
param("name": "ddf.only", "expression": "0")
}
ant.xslt("style": stylesheet,
"in": javadocxmlFile,
"out": new File(temporaryDir, "ddf.txt"),
"force": true) {
classpath("location": saxon)
factory("name": "com.icl.saxon.TransformerFactoryImpl")
param("name": "destdir", "expression": docbookDirFile)
param("name": "ddf.only", "expression": "1")
}
}
}
def rdmtsummary = tasks.register("rdmtsummary") {
description = "Build the docbook flavored Residential DMT summary."
group = "documentation"
def runtimeClasspath = sourceSets.main.runtimeClasspath
def treesummaryxml = layout.getBuildDirectory().file("residentialdmt/treesummary.xml")
inputs.files(parent.project("dmforest").sourceSets.main.allJava).withPathSensitivity(PathSensitivity.RELATIVE).withPropertyName("dmforest")
inputs.files(runtimeClasspath).withNormalizer(ClasspathNormalizer.class).withPropertyName("runtimeClasspath")
outputs.file(treesummaryxml).withPropertyName("treesummaryxml")
def injected = objects.newInstance(Injected)
doLast("rdmtsummary") { t ->
treesummaryxml.get().getAsFile().withOutputStream { os ->
injected.exec.javaexec {
classpath(runtimeClasspath)
mainClass = "org.osgi.tools.dmt.TreeSummary"
standardOutput = new BufferedOutputStream(os)
args("org.osgi.dmt.residential.\$")
}.assertNormalExitValue()
}
}
}
def xmlns = tasks.register("xmlns", Copy.class) {
description = "Build the docbook flavored schemas."
group = "documentation"
from(parent.file("xmlns"))
into(layout.getBuildDirectory().dir("xmlns"))
include("**/*.xsd")
includeEmptyDirs = false
doLast("strip-comments") { t ->
ant.replaceregexp("match": /.*(<(\w+:)?schema)/,
"replace": /\1/,
"flags": "s",
"encoding": "UTF-8") {
fileset("dir": destinationDir, "includes": "**/*.xsd")
}
}
}
def specifications = tasks.register("specifications") {
description = "Generates all the specifications."
group = "documentation"
}
defaultTasks += absoluteProjectPath(specifications.name)
def books = ["core", "cmpn"]
books.forEach { book ->
def booktask = tasks.register("${book}.xml") {
description = "Generate the docbook xml file for the book ${book}."
group = "documentation"
ext.bookxml = layout.getBuildDirectory().file("book/${name}")
def watermark = bnd.get("${book}.draft", "no")
ext.draftmode = objects.property(String.class).convention((watermark != "no") ? "yes" : "no")
def stylesheet = file("docbook/xsl/custom-profile.xsl")
def xmlFiles = objects.fileTree().from("docbook").include("**/*.xml")
def copyrightyear = "2000, ${bnd.get('copyright.year')}"
def runtimeClasspath = sourceSets.main.runtimeClasspath
def docbookxsd = file("${licensed}/docbook-xsd/docbook.xsd")
inputs.file(stylesheet).withPathSensitivity(PathSensitivity.RELATIVE).withPropertyName("stylesheet")
inputs.files(xmlFiles).withPathSensitivity(PathSensitivity.RELATIVE).withPropertyName("xmlFiles")
inputs.files(runtimeClasspath).withNormalizer(ClasspathNormalizer.class).withPropertyName("runtimeClasspath")
inputs.files(javadoc).withPropertyName(javadoc.name)
inputs.files(xmlns).withPropertyName(xmlns.name)
if (book != "core") {
inputs.files(rdmtsummary).withPropertyName(rdmtsummary.name)
}
inputs.property("draft.mode", draftmode)
inputs.property("copyright.year", copyrightyear)
inputs.file(docbookxsd).withPathSensitivity(PathSensitivity.RELATIVE).withPropertyName("docbookxsd")
outputs.file(bookxml).withPropertyName("bookxml")
def injected = objects.newInstance(Injected)
doLast("xml") { t ->
def bookxmlFile = bookxml.get().getAsFile()
ant.xslt("style": stylesheet,
"in": "docbook/${book}/book.xml",
"out": bookxmlFile,
"force": true) {
sysproperty("key": "org.apache.xerces.xni.parser.XMLParserConfiguration",
"value": "org.apache.xerces.parsers.XIncludeParserConfiguration")
classpath {
fileset("dir": "${fop_home}/lib") {
include("name": "xercesImpl*.jar")
include("name": "xml-apis*.jar")
}
pathelement("location": saxon)
}
factory("name": "com.icl.saxon.TransformerFactoryImpl")
param("name": "draft.mode", "expression": draftmode.get())
param("name": "copyright.year", "expression": copyrightyear)
}
injected.exec.javaexec {
classpath(runtimeClasspath)
mainClass = "org.osgi.tools.xmlvalidation.XmlValidator"
args(docbookxsd)
args(bookxmlFile)
}.assertNormalExitValue()
}
}
def bookdifftask = tasks.register("${book}-diff.xml") {
description = "Generate the docbook diff xml file for the book ${book}."
group = "documentation"
ext.bookxml = layout.getBuildDirectory().file("book/${name}")
def watermark = bnd.get("${book}.draft", "no")
ext.draftmode = objects.property(String.class).convention((watermark != "no") ? "yes" : "no")
def stylesheet = file("${licensed}/diffmk/style/docbook.xsl")
def baselinexml = file("baseline/${book}.xml")
def booktaskXml = booktask.flatMap({it.bookxml})
inputs.files(booktask).withPropertyName(booktask.name)
inputs.file(stylesheet).withPathSensitivity(PathSensitivity.RELATIVE).withPropertyName("stylesheet")
inputs.file(baselinexml).withPathSensitivity(PathSensitivity.RELATIVE).withPropertyName("baselinexml")
outputs.file(bookxml).withPropertyName("bookxml")
def injected = objects.newInstance(Injected)
doLast("xml-diff") { t ->
def tmpxml = new File(temporaryDir, "diff.xml")
injected.exec.javaexec {
classpath("${licensed}/diffmk/bin/diffmk.jar")
mainClass = "net.sf.diffmk.DiffMk"
minHeapSize = "1g"
maxHeapSize = "2g"
args("--verbose")
args("1")
args("--words")
args(baselinexml)
args(booktaskXml.get().getAsFile())
args(tmpxml)
}.assertNormalExitValue()
ant.xslt("style": stylesheet,
"in": tmpxml,
"out": bookxml.get().getAsFile(),
"force": true) {
classpath("location": saxon)
factory("name": "com.icl.saxon.TransformerFactoryImpl")
}
}
}
def fotask = tasks.register("${book}.fo", fotaskConfiguration(book, booktask))
def fodifftask = tasks.register("${book}-diff.fo", fotaskConfiguration("${book}-diff", bookdifftask))
def pdftask = tasks.register("${book}.pdf", pdftaskConfiguration(book, book, fotask))
tasks.register("${book}-diff.pdf", pdftaskConfiguration(book, "${book}-diff", fodifftask))
def rasterizelisttask = tasks.register("${book}.rasterizelist") {
description = "Generate list of SVGs to rasterize for the book ${book}."
group = "documentation"
def imagesXSL = file("docbook/xsl/custom-html-images.xsl")
ext.imagesFile = layout.getBuildDirectory().file("images/${book}.txt")
def watermark = bnd.get("${book}.draft", "no")
def booktaskXml = booktask.flatMap({it.bookxml})
def booktaskDraftmode = booktask.flatMap({it.draftmode})
inputs.files(booktask).withPropertyName(booktask.name)
inputs.file(imagesXSL).withPathSensitivity(PathSensitivity.RELATIVE).withPropertyName("imagesXSL")
inputs.property("watermark", watermark)
outputs.file(imagesFile).withPropertyName("imagesFile")
doLast("xslt") { t ->
ant.xslt("style": imagesXSL,
"in": booktaskXml.get().getAsFile(),
"out": imagesFile.get().getAsFile(),
"force": true) {
classpath("location": saxon)
factory("name": "com.icl.saxon.TransformerFactoryImpl")
param("name": "draft.mode", "expression": booktaskDraftmode.get())
if (booktaskDraftmode.get() != "no") {
param("name": "draft.watermark.image", "expression": "../graphics/${watermark}.svg")
}
}
}
}
def rasterizetask = tasks.register("${book}.rasterize") {
description = "Rasterize SVGs for the book ${book}."
group = "documentation"
def svgFiles = objects.fileTree().from("docbook").include("**/*.svg")
def bookFolder = layout.getProjectDirectory().dir("docbook/${book}")
def imagesFile = rasterizelisttask.flatMap({it.imagesFile}).map({it.getAsFile()})
def imageFiles = objects.fileCollection().from(imagesFile.map({f -> f.collect({bookFolder.file(it)})}))
def runtimeClasspath = sourceSets.main.runtimeClasspath
def destinationDirectory = layout.getBuildDirectory().dir("images/${book}")
def fontbasedir = file("fonts")
inputs.files(rasterizelisttask).withPropertyName(rasterizelisttask.name)
inputs.files(svgFiles).withPathSensitivity(PathSensitivity.RELATIVE).withPropertyName("svgFiles")
inputs.files(runtimeClasspath).withNormalizer(ClasspathNormalizer.class).withPropertyName("runtimeClasspath")
outputs.dir(destinationDirectory).withPropertyName("destinationDirectory")
def injected = objects.newInstance(Injected)
def outputFiles = objects.fileTree().from(destinationDirectory)
doFirst("clean") { t ->
injected.fs.delete {
delete(outputFiles)
}
}
doLast("exec") { t ->
injected.exec.javaexec {
systemProperty("scale", "2")
systemProperty("dpi", "300")
systemProperty("JAVA_FONTS", fontbasedir)
classpath(runtimeClasspath)
mainClass = "org.osgi.tools.rasterizer.RasterizerMain"
minHeapSize = "1g"
maxHeapSize = "2g"
args(destinationDirectory.get().getAsFile())
args(imageFiles.getFiles())
}.assertNormalExitValue()
}
}
def htmltask = tasks.register("${book}.html") {
description = "Generate the docbook html files for the book ${book}."
group = "documentation"
def stylesheet = file("docbook/xsl/custom-html.xsl")
def commonXSL = file("docbook/xsl/custom-html-common.xsl")
def htmlResources = file("docbook/xsl/html-resources")
def licensedResources = file("${licensed}/webresources")
def watermark = bnd.get("${book}.draft", "no")
def release_version = bnd.get("osgi.release")
def destinationDirectory = layout.getBuildDirectory().dir("html/${book}")
def booktaskXml = booktask.flatMap({it.bookxml})
def booktaskDraftmode = booktask.flatMap({it.draftmode})
inputs.files(booktask).withPropertyName(booktask.name)
inputs.files(rasterizetask).withPropertyName(rasterizetask.name)
inputs.file(stylesheet).withPathSensitivity(PathSensitivity.RELATIVE).withPropertyName("stylesheet")
inputs.file(commonXSL).withPathSensitivity(PathSensitivity.RELATIVE).withPropertyName("commonXSL")
inputs.dir(htmlResources).withPathSensitivity(PathSensitivity.RELATIVE).withPropertyName("htmlResources")
inputs.dir(licensedResources).withPathSensitivity(PathSensitivity.RELATIVE).withPropertyName("licensedResources")
inputs.property("watermark", watermark)
inputs.property("release_version", release_version)
outputs.dir(destinationDirectory).withPropertyName("destinationDirectory")
def injected = objects.newInstance(Injected)
def outputFiles = objects.fileTree().from(destinationDirectory)
doFirst("clean") { t ->
injected.fs.delete {
delete(outputFiles)
}
}
doLast("xslt") { t ->
ant.xslt("style": stylesheet,
"in": booktaskXml.get().getAsFile(),
"out": new File(temporaryDir, "book.txt"),
"force": true) {
classpath("location": saxon)
factory("name": "com.icl.saxon.TransformerFactoryImpl")
param("name": "draft.mode", "expression": booktaskDraftmode.get())
if (booktaskDraftmode.get() != "no") {
param("name": "draft.watermark.image", "expression": "images/${watermark}.png")
}
param("name": "webhelp.base.dir", "expression": destinationDirectory.get().getAsFile())
param("name": "webhelp.default.topic", "expression": "index.html")
param("name": "release.version", "expression": release_version)
}
injected.fs.copy {
into(destinationDirectory)
from(htmlResources)
from(licensedResources) {
include("**/*.js")
into("js")
eachFile { fcd ->
fcd.path = "js/${fcd.name}"
}
}
from(licensedResources) {
include("**/*.css")
into("css")
eachFile { fcd ->
fcd.path = "css/${fcd.name}"
}
}
from(rasterizetask) {
into("images")
}
includeEmptyDirs = false
}
}
}
def ziptask = tasks.register("${book}.zip", Zip.class) {
description = "Generate a ZIP archive of the docbook html for the book ${book}."
group = "documentation"
destinationDirectory = layout.getBuildDirectory()
archiveBaseName = "osgi.${book}"
archiveClassifier = "html"
from(htmltask)
}
specifications.configure {
dependsOn(pdftask, ziptask)
}
}
private Closure fotaskConfiguration(bookName, xmltask) {
return {
description = "Generate the docbook fo file for the book ${bookName}."
group = "documentation"
ext.bookfo = layout.getBuildDirectory().file("fo/${name}")
def stylesheet = file("docbook/xsl/custom-fo.xsl")
def watermark = bnd.get("${bookName}.draft", "no")
def booktaskXml = xmltask.flatMap({it.bookxml})
def booktaskDraftmode = xmltask.flatMap({it.draftmode})
inputs.files(xmltask).withPropertyName(xmltask.name)
inputs.file(stylesheet).withPathSensitivity(PathSensitivity.RELATIVE).withPropertyName("stylesheet")
inputs.property("watermark", watermark)
outputs.file(bookfo).withPropertyName("bookfo")
doLast("xslt") { t ->
ant.xslt("style": stylesheet,
"in": booktaskXml.get().getAsFile(),
"out": bookfo.get().getAsFile(),
"force": true) {
classpath("location": bnd.get("saxon"))
factory("name": "com.icl.saxon.TransformerFactoryImpl")
param("name": "draft.mode", "expression": booktaskDraftmode.get())
if (booktaskDraftmode.get() != "no") {
param("name": "draft.watermark.image", "expression": "docbook/graphics/${watermark}.svg")
}
}
}
}
}
private Closure pdftaskConfiguration(basebook, bookName, fotask) {
return {
description = "Generate the docbook pdf file for the book ${bookName}."
group = "documentation"
def bookpdf = layout.getBuildDirectory().file("osgi.${bookName}-${version}.pdf")
def fontbasedir = file("fonts")
def basebookdir = file("docbook/${basebook}")
def fopxconf = file("docbook/fop/fop-osgi.xconf")
def log4jprops = file("docbook/fop/log4j.properties")
def svgFiles = objects.fileTree().from("docbook").include("**/*.svg")
def booktaskFo = fotask.flatMap({it.bookfo})
def classesDirectory = sourceSets.main.java.classesDirectory
inputs.files(fotask).withPropertyName(fotask.name)
inputs.file(fopxconf).withPathSensitivity(PathSensitivity.RELATIVE).withPropertyName("fopxconf")
inputs.file(log4jprops).withPathSensitivity(PathSensitivity.RELATIVE).withPropertyName("log4jprops")
inputs.dir(fontbasedir).withPathSensitivity(PathSensitivity.RELATIVE).withPropertyName("fontbasedir")
inputs.files(svgFiles).withPathSensitivity(PathSensitivity.RELATIVE).withPropertyName("svgFiles")
outputs.file(bookpdf).withPropertyName("bookpdf")
def injected = objects.newInstance(Injected)
doLast("exec") { t ->
injected.fs.copy {
from(fopxconf)
into(temporaryDir)
filter(ReplaceTokens,
"tokens": ["book.base.url": basebookdir.toURI().toString(),
"font.base.url": fontbasedir.toURI().toString(),
"font.base.dir": fontbasedir.absolutePath])
}
injected.exec.javaexec {
systemProperty("java.awt.headless", "true")
systemProperty("JAVA_FONTS", fontbasedir)
systemProperty("log4j.configuration", log4jprops.toURI())
classpath(classesDirectory.get().getAsFile())
classpath(bnd.get("log4j"))
classpath(fop_classpath)
mainClass = "org.osgi.tools.fop.FOPMain"
minHeapSize = "1g"
maxHeapSize = "3g"
args("-c", new File(temporaryDir, fopxconf.name))
args("-fo", booktaskFo.get().getAsFile())
args("-pdf", bookpdf.get().getAsFile())
}.assertNormalExitValue()
}
}
}
tasks.register("fontmetrics") {
description = "Build the font metrics."
group = "documentation"
def tffs = objects.fileTree().from("fonts").include("*.ttf")
def xmls = objects.fileCollection().from(tffs.getElements().map({ set ->
set.collect { it.getAsFile().getAbsolutePath().replaceAll(/\.ttf$/, /.xml/) }
}))
inputs.files(tffs).withPathSensitivity(PathSensitivity.RELATIVE).withPropertyName("tffs")
outputs.files(xmls).withPropertyName("xmls")
def injected = objects.newInstance(Injected)
doLast("exec") { t ->
tffs.forEach { ttf ->
injected.exec.javaexec {
classpath(fop_classpath)
mainClass = "org.apache.fop.fonts.apps.TTFReader"
args(ttf.getAbsolutePath())
args(ttf.getAbsolutePath().replaceAll(/\.ttf$/, /.xml/))
}.assertNormalExitValue()
}
}
}