-
Notifications
You must be signed in to change notification settings - Fork 138
/
platform.pm
333 lines (272 loc) · 7.53 KB
/
platform.pm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
# Copyright (C) 2001-2010, Parrot Foundation.
=head1 NAME
config/gen/platform.pm - Platform Files
=head1 DESCRIPTION
Moves the various platform-specific files into place.
=cut
package gen::platform;
use strict;
use warnings;
use base qw(Parrot::Configure::Step);
use Parrot::Configure::Utils ':gen';
sub _init {
my $self = shift;
my %data;
$data{description} = q{Move platform files into place};
$data{result} = q{};
$data{coda} = <<'CODA';
/*
* Local variables:
* c-file-style: "parrot"
* End:
* vim: expandtab shiftwidth=4 cinoptions='\:2=2' :
*/
CODA
return \%data;
}
sub runstep {
my ( $self, $conf ) = @_;
my $generated = $self->_get_generated($conf);
# headers are merged into platform.h
$self->_set_headers($conf, $generated);
# implementation files are merged into platform.c
$self->_set_implementations($conf, $generated);
$self->_handle_asm($conf);
$self->_set_limits($conf);
return 1;
}
sub _get_generated {
my ($self, $conf) = @_;
my $generated = $conf->data->get('TEMP_generated');
$generated = '' unless defined $generated;
$conf->debug(" ($generated) \n");
return $generated;
}
sub _set_headers {
my $self = shift;
my ($conf, $generated) = @_;
my $platform = $conf->data->get('platform');
my @headers = qw/
io.h
math.h
misc.h
dl.h
signal.h
stat.h
threads.h
string.h
/;
my $plat_h = q{include/parrot/platform.h};
$conf->append_configure_log($plat_h);
open my $PLATFORM_H, ">", $plat_h
or die "Can't open $plat_h: $!";
print {$PLATFORM_H} <<"END_HERE";
/* ex: set ro:
** !!!!!!! DO NOT EDIT THIS FILE !!!!!!!
**
** This file is generated automatically by config/gen/platform.pm
*/
#ifndef PARROT_PLATFORM_H_GUARD
#define PARROT_PLATFORM_H_GUARD
/*
** platform.h [$platform version]
**
** DO NOT EDIT THIS FILE
**
** Generated by config/gen/platform.pm
*/
END_HERE
foreach (@headers) {
my $header_file = "config/gen/platform/generic/$_";
if ( -e "config/gen/platform/$platform/$_" ) {
$header_file = "config/gen/platform/$platform/$_";
}
if ( -e $header_file ) {
local $/ = undef;
$conf->debug("\t$header_file\n");
open my $IN_H, "<", "$header_file"
or die "Can't open $header_file: $!";
# slurp in the header file
my $in_h = <$IN_H>;
# remove the (in this case) superfluous coda
$in_h =~ s{\Q$self->{coda}\E\n*\z}{}xgs;
print {$PLATFORM_H} <<"END_HERE";
/*
** $header_file:
*/
#line 1 "$header_file"
END_HERE
print {$PLATFORM_H} $in_h, "\n\n";
close $IN_H;
}
# just fall through if file is missing; means neither this platform nor
# generic has anything to contribute for this feature. this might not
# be desirable if porters don't see the appropriate file in generic/ and
# shoehorn their function into the wrong file rather than creating the
# correct one from the above list in their $platform/ dir (e.g. misc.c).
}
# finally append generated
@headers = grep { /\.h$/ } split( m/,/, $generated );
for my $h (@headers) {
if ( -e $h ) {
local $/ = undef;
$conf->debug("\t$h\n");
open my $IN_H, "<", $h or die "Can't open $h: $!";
print {$PLATFORM_H} <<"END_HERE";
/*
** $h
*/
#line 1 "$h"
END_HERE
print {$PLATFORM_H} <$IN_H>, "\n\n";
close $IN_H;
}
else {
warn("Header file '$h' listed in TEMP_generated but not found\n");
}
}
# Add the C-coda
print $PLATFORM_H <<"END_HERE";
#endif /* PARROT_PLATFORM_H_GUARD */
$self->{coda}
END_HERE
close $PLATFORM_H;
return 1;
}
sub _set_limits {
my ($self, $conf) = @_;
my $platform = $conf->data->get('platform');
my $limits = "config/gen/platform/generic/platform_limits.h";
if ( -e "config/gen/platform/$platform/platform_limits.h" ) {
$limits = "config/gen/platform/$platform/platform_limits.h";
}
copy_if_diff( $limits, "include/parrot/platform_limits.h" );
return;
}
sub _set_implementations {
my $self = shift;
my ($conf, $generated) = @_;
my $platform = $conf->data->get('platform');
my @impls = qw/
time.c
encoding.c
env.c
dl.c
stat.c
math.c
signal.c
itimer.c
exec.c
misc.c
hires_timer.c
pid.c
sysmem.c
uid.c
/;
my $plat_c = q{src/platform.c};
$conf->append_configure_log($plat_c);
open my $PLATFORM_C, ">", $plat_c
or die "Can't open $plat_c: $!";
print {$PLATFORM_C} <<"END_HERE";
/*
** platform.c [$platform version]
**
** DO NOT EDIT THIS FILE
**
** Generated by config/gen/platform.pm
*/
/* HEADERIZER HFILE: none */
/* HEADERIZER STOP */
END_HERE
# We need to put things from begin.c before the parrot.h include.
$self->_handle_begin_c($platform, $PLATFORM_C);
# Copy the rest.
print {$PLATFORM_C} <<'END_HERE';
#include "parrot/parrot.h"
END_HERE
for my $im (@impls) {
my $impl_file = "config/gen/platform/generic/$im";
if ( -e "config/gen/platform/$platform/$im" ) {
$impl_file = "config/gen/platform/$platform/$im";
}
if ( -e $impl_file ) {
local $/ = undef;
$conf->debug("\t$impl_file\n");
open my $IN_C, "<", $impl_file or die "Can't open $impl_file: $!";
# slurp in the C file
my $in_c = <$IN_C>;
# remove the (in this case) superfluous coda
$in_c =~ s{\Q$self->{coda}\E\n*\z}{}xgs;
print {$PLATFORM_C} <<"END_HERE";
/*
** $impl_file:
*/
#line 1 "$impl_file"
END_HERE
print {$PLATFORM_C} $in_c, "\n\n";
close $IN_C;
}
}
# append generated c files
@impls = grep { /\.c$/ } split( m/,/, $generated );
for my $im (@impls) {
if ( -e $im ) {
local $/ = undef;
$conf->debug("\t$im\n");
open my $IN_C, "<", $im or die "Can't open $im: $!";
print {$PLATFORM_C} <<"END_HERE";
/*
** $im:
*/
#line 1 "$im"
END_HERE
print {$PLATFORM_C} <$IN_C>, "\n\n";
close $IN_C;
}
}
# append the C code coda to the generated file
print {$PLATFORM_C} <<"END_HERE";
$self->{coda}
END_HERE
close $PLATFORM_C;
return 1;
}
sub _handle_begin_c {
my $self = shift;
my ($platform, $PLATFORM_C) = @_;
if ( -e "config/gen/platform/$platform/begin.c" ) {
local $/ = undef;
open my $IN_C, "<", "config/gen/platform/$platform/begin.c" or die "Can't open begin.c: $!";
# slurp in the C file
my $in_c = <$IN_C>;
# remove the (in this case) superfluous coda
$in_c =~ s{\Q$self->{coda}\E\n*\z}{}xgs;
print {$PLATFORM_C} <<"END_HERE";
/*
** begin.c
*/
#line 1 "config/gen/platform/$platform/begin.c"
END_HERE
print {$PLATFORM_C} $in_c, "\n\n";
close $IN_C;
}
return;
}
sub _handle_asm {
my ($self, $conf) = @_;
my $platform = $conf->data->get('platform');
if ( $conf->data->get('platform_asm') ) {
my $asm_file = "config/gen/platform/$platform/asm.s";
if ( -e $asm_file ) {
copy_if_diff( $asm_file, "src/platform_asm.s" );
}
}
return;
}
1;
# Local Variables:
# mode: cperl
# cperl-indent-level: 4
# fill-column: 100
# End:
# vim: expandtab shiftwidth=4: