-
Notifications
You must be signed in to change notification settings - Fork 138
/
Item.pm
283 lines (186 loc) · 6.34 KB
/
Item.pm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
# Copyright (C) 2004, Parrot Foundation.
=head1 NAME
Parrot::Docs::Item - Documentation item
=head1 SYNOPSIS
use Parrot::Docs::Item;
=head1 DESCRIPTION
A documentation I<item> is one or more related paths with some optional
descriptive text.
Directory paths will be expanded to all the file paths within the
directory and any subdirectories recursively (see the C<files()> method
in C<Parrot::IO::Directory>).
If an item has more than one file associated with it, and has no text,
then an attempt will be made to extract short descriptions from each
file to place under the file path in the index HTML.
=head2 Class Methods
=over
=cut
package Parrot::Docs::Item;
use strict;
use warnings;
use Parrot::Docs::Directory;
use Parrot::Docs::POD2HTML;
use Parrot::Docs::Text2HTML;
=item C<new_item($text, @paths)>
Returns a new item.
Use this when creating items within a C<Parrot::Docs::Section>
subclass's C<new()> method.
=cut
sub new_item {
my $self = shift;
return Parrot::Docs::Item->new(@_);
}
=item C<new($text, @contents)>
Returns a new item. If there is no descriptive text then C<$text> should
be an empty string.
The paths in C<@contents> will be interpreted as being relative to the
C<$target> argument in C<write_html()>. There should be at least one
path otherwise an exception is raised.
=cut
sub new {
my $self = ref $_[0] ? ref shift : shift;
my $text = shift;
my @contents = @_;
die "No contents ($text).\n" unless @contents;
$self = bless {
TEXT => $text,
TITLE => $text,
CONTENTS => \@contents,
}, $self;
return $self;
}
=back
=head2 Instance Methods
=over 4
=item C<set_parent($parent)>
=item C<parent()>
Accessors for the containing section/group for the item.
=cut
sub set_parent {
my $self = shift;
$self->{PARENT} = shift;
}
sub parent {
my $self = shift;
return $self->{PARENT};
}
=item C<html_navigation($path)>
Returns the HTML navigation bar.
=cut
sub html_navigation {
my $self = shift;
my $path = shift;
my $parent = $self->parent || return '';
return join ' » ', grep { length } $parent->html_navigation($path), $parent->html_link($path);
}
=item C<write_html($source, $target, $silent)>
C<$source> is the directory in which the section's contents will be
looked for.
C<$target> is directory into which the section's output will be written.
If C<$silent> is true then progress is not reported.
Any POD-formatted text in the item's files is converted to HTML and
written to a file in C<$target> and an HTML link is created to it.
Alternatively, if a file responds true to C<is_docs_link()> then an HTML
link is created to the file itself.
Some HTML-formatted text describing the files linked to is returned.
=cut
sub write_html {
my $self = shift;
my $source = shift || die "No source\n";
my $target = shift || die "No target\n";
my $silent = shift || 0;
my $index_html = '';
my @rel_paths = $self->contents_relative_to_source($source);
my @short_desc = ();
foreach my $rel_path (@rel_paths) {
my $file = $source->file_with_relative_path($rel_path);
if ( $file->contains_pod ) {
print "\n", $rel_path unless $silent;
my $formatter = Parrot::Docs::POD2HTML->new;
$formatter->no_errata_section(1); # don't dump errors into HTML output
$formatter->write_html( $source, $target, $rel_path, $self );
my $title = $self->{TITLE} || $file->short_description;
if ($title) {
$index_html .= $formatter->html_link( $formatter->append_html_suffix($rel_path),
$title );
}
else {
$index_html .= $formatter->html_link( $formatter->append_html_suffix($rel_path),
$source->relative_path( $file->path ) );
}
$index_html .= "<br>\n";
next if $self->{TEXT};
my $short_desc = $file->short_description;
next unless $short_desc;
next if grep { $_ eq $short_desc } @short_desc;
push @short_desc, $short_desc;
}
elsif ( $file->is_docs_link ) {
print "\n", $rel_path unless $silent;
my $formatter = Parrot::Docs::Text2HTML->new;
$formatter->write_html( $source, $target, $rel_path, $self );
$index_html .= $formatter->html_link( $formatter->append_html_suffix($rel_path),
$source->relative_path( $file->path ) );
}
}
return '' unless $index_html;
if ( $self->{DESCRIPTION} ) {
$index_html .= "<br>$self->{DESCRIPTION}\n";
}
$index_html = '<li>' . $index_html . "</li>\n";
return $index_html;
}
=item C<contents_relative_to_source($source)>
Returns the contents of the item interpreted relative to the source
directory.
=cut
sub contents_relative_to_source {
my $self = shift;
my $source = shift;
my @contents = ();
foreach my $content ( @{ $self->{CONTENTS} } ) {
push @contents, $self->file_paths_relative_to_source( $source, $content );
}
return @contents;
}
=item C<file_paths_relative_to_source($source, $path)>
If C<$path> is an immediate subdirectory of C<$source>, then this method
returns all the file paths within the directory and any subdirectories
recursively, relative to C<$source>.
If C<$path> is a file in C<$source> then C<$path> is returned.
If C<$path> cannot be found then a warning is printed.
=cut
sub file_paths_relative_to_source {
my $self = shift;
my $source = shift;
my $rel_path = shift;
my @rel_paths = ();
if ( $source->relative_path_is_directory($rel_path) ) {
my $dir = $source->directory_with_relative_path($rel_path);
# There may be editor scratch files to ignore.
foreach my $file ( $dir->files( 1, '^\.' ) ) {
push @rel_paths, $source->relative_path( $file->path );
}
}
elsif ( $source->relative_path_is_file($rel_path) ) {
push @rel_paths, $rel_path;
}
else {
warn "Failed to process $rel_path.\n";
}
return @rel_paths;
}
=back
=head1 SEE ALSO
=over 4
=item C<Parrot::Docs::Section>
=item C<Parrot::Docs::Group>
=back
=cut
1;
# Local Variables:
# mode: cperl
# cperl-indent-level: 4
# fill-column: 100
# End:
# vim: expandtab shiftwidth=4: