-
-
Notifications
You must be signed in to change notification settings - Fork 2k
/
Logger.zep
429 lines (369 loc) · 10.2 KB
/
Logger.zep
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
/**
* This file is part of the Phalcon Framework.
*
* (c) Phalcon Team <team@phalcon.io>
*
* For the full copyright and license information, please view the LICENSE.txt
* file that was distributed with this source code.
*/
namespace Phalcon;
use Psr\Log\LoggerInterface;
use Phalcon\Logger\Adapter\AdapterInterface;
use Phalcon\Logger\Item;
use Phalcon\Logger\Exception;
/**
* Phalcon\Logger
*
* This component offers logging capabilities for your application. The
* component accepts multiple adapters, working also as a multiple logger.
* Phalcon\Logger implements PSR-3.
*
*```php
* use Phalcon\Logger;
* use Phalcon\Logger\Adapter\Stream;
*
* $adapter1 = new Stream('/logs/first-log.log');
* $adapter2 = new Stream('/remote/second-log.log');
* $adapter3 = new Stream('/manager/third-log.log');
*
* $logger = new Logger(
* 'messages',
* [
* 'local' => $adapter1,
* 'remote' => $adapter2,
* 'manager' => $adapter3,
* ]
* );
*
* // Log to all adapters
* $logger->error('Something went wrong');
*
* // Log to specific adapters
* $logger
* ->excludeAdapters(['manager'])
* ->info('This does not go to the "manager" logger);
*```
*/
class Logger implements LoggerInterface
{
const ALERT = 2;
const CRITICAL = 1;
const CUSTOM = 8;
const DEBUG = 7;
const EMERGENCY = 0;
const ERROR = 3;
const INFO = 6;
const NOTICE = 5;
const WARNING = 4;
/**
* The adapter stack
*
* @var AdapterInterface[]
*/
protected adapters = [];
/**
* Minimum log level for the logger
*
* @var int
*/
protected logLevel = 8 { get };
/**
* @var string
*/
protected name = "";
/**
* The excluded adapters for this log process
*
* @var AdapterInterface[]
*/
protected excluded = [];
/**
* Constructor.
*
* @param string name The name of the logger
* @param array adapters The collection of adapters to be used for logging (default [])
*/
public function __construct(string! name, array! adapters = [])
{
let this->name = name;
this->setAdapters(adapters);
}
/**
* Add an adapter to the stack. For processing we use FIFO
*
* @param string name The name of the adapter
* @param AdapterInterface adapter The adapter to add to the stack
*/
public function addAdapter(string name, <AdapterInterface> adapter) -> <Logger>
{
let this->adapters[name] = adapter;
return this;
}
/**
* Action must be taken immediately.
*
* Example: Entire website down, database unavailable, etc. This should
* trigger the SMS alerts and wake you up.
*
* @param string message
*/
public function alert(message, array context = []) -> void
{
this->addMessage(self::ALERT, (string) message, context);
}
/**
* Critical conditions.
*
* Example: Application component unavailable, unexpected exception.
*
* @param string message
*/
public function critical(message, array context = []) -> void
{
this->addMessage(self::CRITICAL, (string) message, context);
}
/**
* Detailed debug information.
*
* @param string message
*/
public function debug(message, array context = []) -> void
{
this->addMessage(self::DEBUG, (string) message, context);
}
/**
* Runtime errors that do not require immediate action but should typically
* be logged and monitored.
*
* @param string message
*/
public function error(message, array context = []) -> void
{
this->addMessage(self::ERROR, (string) message, context);
}
/**
* System is unusable.
*
* @param string message
*/
public function emergency(message, array context = []) -> void
{
this->addMessage(self::EMERGENCY, (string) message, context);
}
/**
* Exclude certain adapters.
*/
public function excludeAdapters(array adapters = []) -> <Logger>
{
var name, registered;
let registered = this->adapters;
/**
* Loop through what has been passed. Check these names with
* the registered adapters. If they match, add them to the
* this->excluded array
*/
for name in adapters {
if isset registered[name] {
let this->excluded[name] = true;
}
}
return this;
}
/**
* Returns an adapter from the stack
*
* @param string name The name of the adapter
*
* @throws Exception
*/
public function getAdapter(string name) -> <AdapterInterface>
{
var adapter, adapters;
let adapters = this->adapters;
if !fetch adapter, adapters[name] {
throw new Exception("Adapter does not exist for this logger");
}
return adapter;
}
/**
* Returns the adapter stack array
*
* @return AdapterInterface[]
*/
public function getAdapters() -> array
{
return this->adapters;
}
/**
* Returns the name of the logger
*/
public function getName() -> string
{
return this->name;
}
/**
* Interesting events.
*
* Example: User logs in, SQL logs.
*
* @param string message
*/
public function info(message, array context = []) -> void
{
this->addMessage(self::INFO, (string) message, context);
}
/**
* Logs with an arbitrary level.
*
* @param mixed level
* @param string message
*/
public function log(level, message, array context = []) -> void
{
var intLevel;
let intLevel = this->getLevelNumber(level);
this->addMessage(level, (string) message, context);
}
/**
* Normal but significant events.
*
* @param string message
*/
public function notice(message, array context = []) -> void
{
this->addMessage(self::NOTICE, (string) message, context);
}
/**
* Removes an adapter from the stack
*
* @param string name The name of the adapter
*
* @throws Logger\Exception
*/
public function removeAdapter(string name) -> <Logger>
{
var adapters;
let adapters = this->adapters;
if true !== isset(adapters[name]) {
throw new Exception("Adapter does not exist for this logger");
}
unset adapters[name];
let this->adapters = adapters;
return this;
}
/**
* Sets the adapters stack overriding what is already there
*
* @param array adapters An array of adapters
*/
public function setAdapters(array! adapters) -> <Logger>
{
let this->adapters = adapters;
return this;
}
/**
* Sets the log level above which we can log
*/
public function setLogLevel(int level) -> <Logger>
{
var levels;
let levels = this->getLevels();
if !isset levels[level] {
let level = self::CUSTOM;
}
let this->logLevel = level;
return this;
}
/**
* Exceptional occurrences that are not errors.
*
* Example: Use of deprecated APIs, poor use of an API, undesirable things
* that are not necessarily wrong.
*
* @param string message
*/
public function warning(message, array context = []) -> void
{
this->addMessage(self::WARNING, (string) message, context);
}
/**
* Adds a message to each handler for processing
*
* @param int level
* @param string message
*
* @throws Logger\Exception
*/
protected function addMessage(int level, string message, array context = []) -> bool
{
var adapter, key, excluded, levelName, levels, item, registered;
if this->logLevel >= level {
let registered = this->adapters,
excluded = this->excluded;
if count(registered) === 0 {
throw new Exception("No adapters specified");
}
let levels = this->getLevels();
if !fetch levelName, levels[level] {
let levelName = levels[self::CUSTOM];
}
let item = new Item(message, levelName, level, time(), context);
/**
* Log only if the key does not exist in the excluded ones
*/
for key, adapter in registered {
if !isset excluded[key] {
if unlikely adapter->inTransaction() {
adapter->add(item);
} else {
adapter->process(item);
}
}
}
/**
* Clear the excluded array since we made the call now
*/
let this->excluded = [];
}
return true;
}
/**
* Returns an array of log levels with integer to string conversion
*/
protected function getLevels() -> array
{
return [
self::ALERT : "alert",
self::CRITICAL : "critical",
self::DEBUG : "debug",
self::EMERGENCY : "emergency",
self::ERROR : "error",
self::INFO : "info",
self::NOTICE : "notice",
self::WARNING : "warning",
self::CUSTOM : "custom"
];
}
/**
* Converts the level from string/word to an integer
*
* @param string|int level
*/
private function getLevelNumber(level) -> int
{
var levelName, numberLevel, levels;
if typeof level === "string" {
let levelName = strtolower(level),
levels = array_flip(this->getLevels());
if fetch numberLevel, levels[levelName] {
return numberLevel;
}
} elseif is_numeric(level) {
let levels = this->getLevels();
if fetch numberLevel, levels[level] {
return numberLevel;
}
}
return self::CUSTOM;
}
}