Added toggle function for dimmers

[sweebee]

No description provided.

[sweetpi]

Sorry for the late response.

@sweebee Could you use getState instead (see the toggle function of thw switch device)?

[sweebee]

I can't get it working.

Error on evaluation of rule condition of rule test: Function "changeStateTo" is not implemented!

Dimmer:

class DimmerActuator extends SwitchActuator
    _dimlevel: null

    actions:
      changeDimlevelTo:
        description: "Sets the level of the dimmer"
        params:
          dimlevel:
            type: t.number
      changeStateTo:
        description: "Changes the switch to on or off"
        params:
          state:
            type: t.boolean
      turnOn:
        description: "Turns the dim level to 100%"
      turnOff:
        description: "Turns the dim level to 0%"
      toggle:
        description: "Toggle the state of the dimmer"
      getState:
        description: "Returns the current state of the dimmer"
        returns:
          state:
            type: t.boolean

    attributes:
      dimlevel:
        description: "The current dim level"
        type: t.number
        unit: "%"
      state:
        description: "The current state of the switch"
        type: t.boolean
        labels: ['on', 'off']


    template: "dimmer"

    # Returns a promise
    turnOn: -> @changeDimlevelTo 100

    # Retuns a promise
    turnOff: -> @changeDimlevelTo 0

    toggle: ->
      @getState().then( (state) => @changeStateTo(!state) )

    # Retuns a promise that is fulfilled when done.
    changeStateTo: (state) ->
      throw new Error "Function \"changeStateTo\" is not implemented!"

    # Retuns a promise that is fulfilled when done.
    changeDimlevelTo: (state) ->
      throw new Error "Function \"changeDimlevelTo\" is not implemented!"

    _setDimlevel: (level) =>
      level = parseFloat(level)
      assert(not isNaN(level))
      cassert level >= 0
      cassert level <= 100
      if @_dimlevel is level then return
      @_dimlevel = level
      @emit "dimlevel", level
      @_setState(level > 0)

    # Returns a promise that will be fulfilled with the dim level
    getDimlevel: -> Promise.resolve(@_dimlevel)

    # Returns a promise that will be fulfilled with the state
    getState: -> Promise.resolve(@_state)

[ds2216]

what about changing

changeStateTo: (state) ->
  throw new Error "Function \"changeStateTo\" is not implemented!"

to

changeStateTo: (state) ->
  @_setState(state)
  return Promise.resolve()

?

[Icesory]

This is the dimmer prototype so it isn't good to implement per device functions in the parent.

_setState() dose not run any code for the real device. So you can change the device in pimatic but no Logik to send this information to its target runs. This will not work.

Every dimmer device must implement the changeStateTo function. @sweebee for which device did you try to implement it? You must create a pull request for this dimmer and implement the changeStateTo function.

[sweetpi]

I merged it but removed the toggle function because it is already in the SwitchActuator. I also added a default changeStateTo dunction to the dimmer device.

The addition will be released with the next version. Sorry for the long delay on this issue.