-
-
Notifications
You must be signed in to change notification settings - Fork 657
/
stacktrace.rkt
592 lines (535 loc) · 21.1 KB
/
stacktrace.rkt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
#lang racket/base
(require racket/unit
syntax/kerncase
syntax/stx
(for-template racket/base)
(for-syntax racket/base)) ; for matching
(provide stacktrace@ stacktrace^ stacktrace-imports^)
(define-signature stacktrace-imports^
(with-mark
test-coverage-enabled
test-covered
initialize-test-coverage-point
profile-key
profiling-enabled
initialize-profile-point
register-profile-start
register-profile-done))
(define-signature stacktrace^
(annotate-top
annotate
make-st-mark
st-mark-source
st-mark-bindings))
(define base-phase
(variable-reference->module-base-phase (#%variable-reference)))
(define-unit stacktrace@
(import stacktrace-imports^)
(export stacktrace^)
(define (short-version v depth)
(cond
[(identifier? v) (syntax-e v)]
[(null? v) null]
[(vector? v) (if (zero? depth)
#(....)
(list->vector
(short-version (vector->list v) (sub1 depth))))]
[(box? v) (if (zero? depth)
#&(....)
(box (short-version (unbox v) (sub1 depth))))]
[(pair? v)
(cond
[(zero? depth) '(....)]
[(memq (syntax-e (car v)) '(#%app #%top))
(short-version (cdr v) depth)]
[else
(cons (short-version (car v) (sub1 depth))
(short-version (cdr v) (sub1 depth)))])]
[(syntax? v) (short-version (syntax-e v) depth)]
[else v]))
(define (make-st-mark stx phase)
(unless (syntax? stx)
(error 'make-st-mark
"expected syntax object as argument, got ~e" stx))
(cond
[(syntax-source stx)
(with-syntax ([quote (syntax-shift-phase-level #'quote phase)])
#`(quote (#,(short-version stx 10)
#,(syntax-source stx)
#,(syntax-line stx)
#,(syntax-column stx)
#,(syntax-position stx)
#,(syntax-span stx))))]
[else #f]))
(define (st-mark-source src)
(and src
(datum->syntax #f (car src) (cdr src) #f)))
(define (st-mark-bindings x) null)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Test case coverage instrumenter
;; The next procedure is called by `annotate' and `annotate-top' to wrap
;; expressions with test suite coverage information. Returning the
;; first argument means no tests coverage information is collected.
;; test-coverage-point : syntax syntax phase -> syntax
;; sets a test coverage point for a single expression
(define (test-coverage-point body expr phase)
(if (and (test-coverage-enabled)
(zero? phase)
(syntax-position expr))
(begin (initialize-test-coverage-point expr)
(let ([thunk (test-covered expr)])
(cond [(procedure? thunk)
(with-syntax ([body body] [thunk thunk])
#'(begin (#%plain-app thunk) body))]
[(syntax? thunk)
(with-syntax ([body body] [thunk thunk])
#'(begin thunk body))]
[else body])))
body))
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Profiling instrumenter
;; profile-point :
;; (syntax[list of exprs] symbol-or-#f syntax boolean
;; -> syntax[list of exprs])
;; This procedure is called by `annotate' and `annotate-top' to wrap
;; expressions with profile collecting information. Returning the
;; first argument means no profiling information is collected.
;; The second argument is the point's inferred name, if any, the third
;; argument is the source expression, and the fourth argument is #t for
;; a transformer expression and #f for a normal expression.
(define (profile-point bodies name expr phase)
(let ([key (gensym 'profile-point)])
(initialize-profile-point key name expr)
(with-syntax ([key (datum->syntax #f key (quote-syntax here))]
[start (datum->syntax
#f (gensym) (quote-syntax here))]
[profile-key (datum->syntax
#f profile-key (quote-syntax here))]
[register-profile-start register-profile-start]
[register-profile-done register-profile-done])
(with-syntax ([rest
(insert-at-tail*
(syntax (#%plain-app register-profile-done 'key start))
bodies
phase)])
(syntax
(let ([start (#%plain-app register-profile-start 'key)])
(with-continuation-mark 'profile-key 'key
(begin . rest))))))))
(define (insert-at-tail* e exprs phase)
(let ([new
(rebuild exprs
(let loop ([exprs exprs])
(if (stx-null? (stx-cdr exprs))
(list (cons (stx-car exprs)
(insert-at-tail
e (stx-car exprs) phase)))
(loop (stx-cdr exprs)))))])
(if (syntax? exprs)
(rearm exprs new)
new)))
(define (insert-at-tail se sexpr phase)
(with-syntax ([expr sexpr]
[e se])
(kernel-syntax-case/phase sexpr phase
;; negligible time to eval
[id
(identifier? sexpr)
(syntax (begin e expr))]
[(quote _) (syntax (begin e expr))]
[(quote-syntax _) (syntax (begin e expr))]
[(#%top . d) (syntax (begin e expr))]
[(#%variable-reference . d) (syntax (begin e expr))]
;; No tail effect, and we want to account for the time
[(#%plain-lambda . _) (syntax (begin0 expr e))]
[(case-lambda . _) (syntax (begin0 expr e))]
[(set! . _) (syntax (begin0 expr e))]
[(let-values bindings . body)
(insert-at-tail* se sexpr phase)]
[(letrec-values bindings . body)
(insert-at-tail* se sexpr phase)]
[(letrec-syntaxes+values sbindings bindings . body)
(insert-at-tail* se sexpr phase)]
[(begin . _)
(insert-at-tail* se sexpr phase)]
[(with-continuation-mark . _)
(insert-at-tail* se sexpr phase)]
[(begin0 body ...)
(rearm sexpr (syntax (begin0 body ... e)))]
[(if test then else)
;; WARNING: se inserted twice!
(rearm
sexpr
(rebuild
sexpr
(list
(cons #'then (insert-at-tail se (syntax then) phase))
(cons #'else (insert-at-tail se (syntax else) phase)))))]
[(#%plain-app . rest)
(if (stx-null? (syntax rest))
;; null constant
(syntax (begin e expr))
;; application; exploit guaranteed left-to-right evaluation
(insert-at-tail* se sexpr phase))]
[_else
(error 'errortrace
"unrecognized (non-top-level) expression form: ~.s"
(syntax->datum sexpr))])))
(define (profile-annotate-lambda name expr clause bodys-stx phase)
(let* ([bodys (stx->list bodys-stx)]
[bodyl (map (lambda (e) (annotate e phase))
bodys)])
(rebuild clause
(if (profiling-enabled)
(let ([prof-expr
(profile-point bodyl name expr phase)])
;; Tell rebuild to replace first expressions with
;; (void), and replace the last expression with
;; prof-expr:
(let loop ([bodys bodys])
(if (null? (cdr bodys))
(list (cons (car bodys) prof-expr))
(cons (cons (car bodys) #'(#%plain-app void))
(loop (cdr bodys))))))
;; Map 1-to-1:
(map cons bodys bodyl)))))
(define (keep-lambda-properties orig new)
(let ([p (syntax-property orig 'method-arity-error)]
[p2 (syntax-property orig 'inferred-name)])
(let ([new (if p
(syntax-property new 'method-arity-error p)
new)])
(if p2
(syntax-property new 'inferred-name p2)
new))))
(define (annotate-let expr phase varss-stx rhss-stx bodys-stx)
(let ([varss (syntax->list varss-stx)]
[rhss (syntax->list rhss-stx)]
[bodys (syntax->list bodys-stx)])
(let ([rhsl (map
(lambda (vars rhs)
(annotate-named
(syntax-case vars () [(id) (syntax id)] [_else #f])
rhs
phase))
varss
rhss)]
[bodyl (map (lambda (body) (annotate body phase))
bodys)])
(rebuild expr (append (map cons bodys bodyl)
(map cons rhss rhsl))))))
(define (annotate-seq expr bodys-stx annotate phase)
(let* ([bodys (syntax->list bodys-stx)]
[bodyl (map (lambda (b) (annotate b phase)) bodys)])
(rebuild expr (map cons bodys bodyl))))
(define orig-inspector (variable-reference->module-declaration-inspector
(#%variable-reference)))
(define (rearm orig new)
(syntax-rearm new orig))
(define (disarm orig)
(syntax-disarm orig orig-inspector))
(define (rebuild expr replacements)
(let loop ([expr expr] [same-k (lambda () expr)] [diff-k (lambda (x) x)])
(let ([a (assq expr replacements)])
(cond
[a (diff-k (cdr a))]
[(pair? expr)
(loop (car expr)
(lambda ()
(loop (cdr expr) same-k
(lambda (y) (diff-k (cons (car expr) y)))))
(lambda (x)
(loop (cdr expr)
(lambda () (diff-k (cons x (cdr expr))))
(lambda (y) (diff-k (cons x y))))))]
[(vector? expr)
(loop (vector->list expr) same-k
(lambda (x) (diff-k (list->vector x))))]
[(box? expr)
(loop (unbox expr) same-k (lambda (x) (diff-k (box x))))]
[(syntax? expr)
(if (identifier? expr)
(same-k)
(loop (syntax-e expr) same-k
(lambda (x) (diff-k (datum->syntax expr x expr expr)))))]
[else (same-k)]))))
(define (append-rebuild expr end)
(cond
[(syntax? expr)
(datum->syntax expr
(append-rebuild (syntax-e expr) end)
expr
expr)]
[(pair? expr)
(cons (car expr) (append-rebuild (cdr expr) end))]
[(null? expr)
(list end)]
[else
(error 'append-rebuild "shouldn't get here")]))
(define (one-name names-stx)
(let ([l (syntax->list names-stx)])
(and (pair? l)
(null? (cdr l))
(car l))))
(define (make-annotate top? name)
(lambda (expr phase)
(define disarmed-expr (disarm expr))
(define (with-mrk* mark expr)
(with-mark mark expr phase))
(test-coverage-point
(kernel-syntax-case/phase disarmed-expr phase
[_
(identifier? expr)
(let ([b (identifier-binding expr phase)])
(cond
[(eq? 'lexical b)
;; lexical variable - no error possile
expr]
[(and (pair? b) (let-values ([(base rel) (module-path-index-split (car b))])
(equal? '(quote #%kernel) base)))
;; built-in - no error possible
expr]
[else
;; might be undefined/uninitialized
(with-mrk* expr expr)]))]
[(#%top . id)
;; might be undefined/uninitialized
(with-mrk* expr expr)]
[(#%variable-reference . _)
;; no error possible
expr]
[(define-values names rhs)
top?
;; Can't put annotation on the outside
(let* ([marked
(with-mrk* expr
(annotate-named
(one-name #'names)
(syntax rhs)
phase))]
[with-coverage
(let loop ([stx #'names]
[obj marked])
(cond
[(not (syntax? stx)) obj]
[(identifier? stx)
(test-coverage-point obj stx phase)]
[(pair? (syntax-e stx))
(loop (car (syntax-e stx))
(loop (cdr (syntax-e stx))
obj))]
[else obj]))])
(rearm
expr
(rebuild
disarmed-expr
(list (cons #'rhs with-coverage)))))]
[(begin . exprs)
top?
(rearm
expr
(annotate-seq disarmed-expr
(syntax exprs)
annotate-top phase))]
[(define-syntaxes (name ...) rhs)
top?
(let ([marked (with-mark expr
(annotate-named
(one-name #'(name ...))
(syntax rhs)
(add1 phase))
(add1 phase))])
(rearm
expr
(rebuild disarmed-expr (list (cons #'rhs marked)))))]
[(begin-for-syntax . exprs)
top?
(rearm
expr
(annotate-seq disarmed-expr
(syntax exprs)
annotate-top
(add1 phase)))]
[(module name init-import mb)
(annotate-module expr disarmed-expr)]
[(module* name init-import mb)
(annotate-module expr disarmed-expr)]
[(#%expression e)
(rearm expr #`(#%expression #,(annotate (syntax e) phase)))]
;; No way to wrap
[(#%require i ...) expr]
;; No error possible (and no way to wrap)
[(#%provide i ...) expr]
;; No error possible
[(quote _)
expr]
[(quote-syntax _)
expr]
;; Wrap body, also a profile point
[(#%plain-lambda args . body)
(rearm
expr
(keep-lambda-properties
expr
(profile-annotate-lambda name expr disarmed-expr (syntax body)
phase)))]
[(case-lambda clause ...)
(with-syntax ([([args . body] ...)
(syntax (clause ...))])
(let* ([clauses (syntax->list (syntax (clause ...)))]
[clausel (map
(lambda (body clause)
(profile-annotate-lambda
name expr clause body phase))
(syntax->list (syntax (body ...)))
clauses)])
(rearm
expr
(keep-lambda-properties
expr
(rebuild disarmed-expr (map cons clauses clausel))))))]
;; Wrap RHSs and body
[(let-values ([vars rhs] ...) . body)
(with-mrk* expr
(rearm
expr
(annotate-let disarmed-expr phase
(syntax (vars ...))
(syntax (rhs ...))
(syntax body))))]
[(letrec-values ([vars rhs] ...) . body)
(let ([fm (rearm
expr
(annotate-let disarmed-expr phase
(syntax (vars ...))
(syntax (rhs ...))
(syntax body)))])
(kernel-syntax-case/phase expr phase
[(lv ([(var1) (#%plain-lambda . _)]) var2)
(and (identifier? #'var2)
(free-identifier=? #'var1 #'var2))
fm]
[_
(with-mrk* expr fm)]))]
;; This case is needed for `#lang errortrace ...', which uses
;; `local-expand' on the module body.
[(letrec-syntaxes+values sbindings ([vars rhs] ...) . body)
(let ([fm (rearm
expr
(annotate-let disarmed-expr phase
(syntax (vars ...))
(syntax (rhs ...))
(syntax body)))])
(with-mrk* expr fm))]
;; Wrap RHS
[(set! var rhs)
(let ([new-rhs (annotate-named
(syntax var)
(syntax rhs)
phase)])
;; set! might fail on undefined variable, or too many values:
(with-mrk* expr
(rearm
expr
(rebuild disarmed-expr (list (cons #'rhs new-rhs))))))]
;; Wrap subexpressions only
[(begin e)
;; Single expression: no mark
(rearm
expr
#`(begin #,(annotate (syntax e) phase)))]
[(begin . body)
(with-mrk* expr
(rearm
expr
(annotate-seq disarmed-expr #'body annotate phase)))]
[(begin0 . body)
(with-mrk* expr
(rearm
expr
(annotate-seq disarmed-expr #'body annotate phase)))]
[(if tst thn els)
(let ([w-tst (annotate (syntax tst) phase)]
[w-thn (annotate (syntax thn) phase)]
[w-els (annotate (syntax els) phase)])
(with-mrk* expr
(rearm
expr
(rebuild disarmed-expr (list (cons #'tst w-tst)
(cons #'thn w-thn)
(cons #'els w-els))))))]
[(if tst thn)
(let ([w-tst (annotate (syntax tst) phase)]
[w-thn (annotate (syntax thn) phase)])
(with-mrk* expr
(rearm
expr
(rebuild disarmed-expr (list (cons #'tst w-tst)
(cons #'thn w-thn))))))]
[(with-continuation-mark . body)
(with-mrk* expr
(rearm
expr
(annotate-seq disarmed-expr (syntax body)
annotate phase)))]
;; Wrap whole application, plus subexpressions
[(#%plain-app . body)
(cond
[(stx-null? (syntax body))
;; It's a null:
expr]
;; check for functions that are known to always succeed,
;; in which case we can skip the wrapper:
[(syntax-case* expr (void cons mcons list list* vector box
vector-immutable)
(lambda (a b)
(free-identifier=? a b phase base-phase))
[(_ void . _) #t]
[(_ cons _ _) #t]
[(_ mcons _ _) #t]
[(_ list . _) #t]
[(_ list* _ . _) #t]
[(_ vector . _) #t]
[(_ vector-immutable . _) #t]
[(_ box _) #t]
[_else #f])
(rearm
expr
(annotate-seq disarmed-expr (syntax body)
annotate phase))]
;; general case:
[else
(with-mrk* expr (rearm
expr
(annotate-seq disarmed-expr (syntax body)
annotate phase)))])]
[_else
(error 'errortrace "unrecognized expression form~a: ~.s"
(if top? " at top-level" "")
(syntax->datum expr))])
expr
phase)))
(define (annotate-module expr disarmed-expr)
(syntax-case disarmed-expr ()
[(mod name init-import mb)
(syntax-case (disarm #'mb) ()
[(__plain-module-begin body ...)
;; Just wrap body expressions
(let ([bodys (syntax->list (syntax (body ...)))])
(let ([bodyl (map (lambda (b)
(annotate-top b 0))
bodys)]
[mb #'mb])
(rearm
expr
(rebuild
disarmed-expr
(list (cons
mb
(rearm
mb
(rebuild mb (map cons bodys bodyl)))))))))])]))
(define annotate (make-annotate #f #f))
(define annotate-top (make-annotate #t #f))
(define (annotate-named name expr phase)
((make-annotate #t name) expr phase)))