-
Notifications
You must be signed in to change notification settings - Fork 745
/
analog-drum-tuner.scd
270 lines (236 loc) · 7.84 KB
/
analog-drum-tuner.scd
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
// Ringz tuner - h. james harkins, http://www.dewdrop-world.net
// Makes analog-style drum sounds with a bank of tunable Ringz filters
// code is released under the LGPL, http://creativecommons.org/licenses/LGPL/2.1/
// optional
// Server.default = s = Server.internal;
// double-click inside the parenthesis, then hit enter to evaluate
(
var percBus, percGroup, ringzBus, ringzGroup, trigbus, trigsynth, src, toStereo,
levelBus, levelEditor, toStereoOut,
nodes, ffreqs, rqs, decays, amps,
log001, sr, dt,
freqspec, rqspec, ampspec,
noiseString = "PinkNoise.ar", envString = "Env.perc(0.01, 0.2)",
post, buildSynthDef, currentDef, g, stop,
window, leftview, rightview, ffreqview, rqview, ampview, rateEdit, newButton,
funcedit, envedit, helpview;
var s = Server.default;
s.waitForBoot {
{
// preparation
percBus = Bus.audio(s, 1);
ringzBus = Bus.audio(s, 1);
percGroup = Group.new;
ringzGroup = Group.after(percGroup);
levelBus = Bus.control(s, 1).set(0.75);
toStereoOut = SynthDef('1to2', { |bus, level|
Out.ar(0, (In.ar(bus, 1) * level) ! 2)
}).play(ringzGroup, [bus: ringzBus, level: levelBus.asMap], addAction: \addAfter);
SynthDef(\ringz, { |ffreq = 20, decay = 0.01, in, out, amp = 0|
Out.ar(out, Ringz.ar(In.ar(in, 1), ffreq, decay, amp))
}).send(s);
nodes = Array.new(10);
ffreqs = [];
rqs = [];
amps = [];
decays = dt.(ffreqs, rqs);
log001 = log(0.001); // constant, will be used repeatedly
// func to calc decay time from freq and rq
sr = s.sampleRate;
dt = { |ffreq, rq|
(log001 / log(1 - (pi/sr * ffreq * rq))) / sr;
};
freqspec = \freq.asSpec;
rqspec = [1, 0.001, \exp].asSpec;
ampspec = \amp.asSpec;
// gui building
window = PageLayout("Ringz tuner", Rect(150, 5, 800, 570));
leftview = FlowView(window, 470@490);
rightview = FlowView(window, 280@490);
// left-hand side: filters
GUI.staticText.new(leftview, 150@20).string_("frequencies");
GUI.staticText.new(leftview, 150@20).string_("resonances");
GUI.staticText.new(leftview, 150@20).string_("amplitudes");
ffreqview = GUI.multiSliderView.new(leftview, 150@200)
.value_(freqspec.unmap(ffreqs))
.thumbSize_(14)
.action_({ |v|
ffreqs = freqspec.map(v.value);
decays = dt.(ffreqs, rqs);
nodes.do({ |n, i|
n.set(\ffreq, ffreqs[i], \decay, decays[i])
})
});
rqview = GUI.multiSliderView.new(leftview, 150@200)
.value_(rqspec.unmap(rqs))
.thumbSize_(14)
.action_({ |v|
rqs = rqspec.map(v.value);
decays = dt.(ffreqs, rqs);
nodes.do({ |n, i|
n.set(\decay, decays[i]);
})
});
ampview = GUI.multiSliderView.new(leftview, 150@200)
.value_(ampspec.unmap(amps))
.thumbSize_(14)
.action_({ |v|
amps = ampspec.map(v.value);
nodes.do({ |n, i| n.set(\amp, amps[i]) })
});
leftview.startRow;
rateEdit = EZSlider(leftview, 220@20, "trigrate", #[0.5, 10], { |view| trigsynth.set(\trigrate, view.value) }, 2);
levelEditor = EZSlider(leftview, 220@20, "volume", \amp, { |view| levelBus.set(view.value) }, 0.75);
// ActionButtons -- add filter, post parameters, stop, save, load
post = {
(nodes.size > 0).if({
postf("\nKlank array:\n`[ %,\n %,\n % ]\n\n",
ffreqs, //[..nodes.size-1],
amps, // \amp.asSpec.map(ampview.value[..nodes.size-1]),
decays); // [..nodes.size-1];
[ffreqs, decays, amps]
.flop/*[..nodes.size-1]*/.do({ |item|
postf("[\\ffreq, %, \\decay, %, \\amp, %]\n", *item);
});
});
};
leftview.startRow;
newButton = Button(leftview, 100@20)
.states_([["new resonz"]])
.action_({
if(nodes.size < 10) {
ffreqs = ffreqs.add(20);
rqs = rqs.add(1);
decays = dt.(ffreqs, rqs);
amps = amps.add(0);
ffreqview.value = freqspec.unmap(ffreqs);
rqview.value = rqspec.unmap(rqs);
ampview.value = ampspec.unmap(amps);
// nodes.add(ringzMixer.play(\ringz, [\in, percMixer.inbus.index]));
nodes.add(Synth(\ringz, [\in, percBus, \out, ringzBus], ringzGroup,
addAction: \addToTail));
};
});
Button(leftview, 140@20)
.states_([["post parameters"]])
.action_(post);
stop = {
post.value;
toStereoOut.free;
src.free;
nodes.do(_.free);
trigbus.free;
percBus.free; percGroup.free;
ringzBus.free; ringzGroup.free;
levelBus.free;
// percMixer.free; ringzMixer.free;
if(window.isClosed.not) { window.onClose_(nil).close };
};
Button(leftview, 80@20)
.states_([["stop"]])
.action_(stop);
leftview.startRow;
Button(leftview, 80@20)
.states_([["save"]])
.action_({
GUI.dialog.savePanel({ |path|
[ffreqview.value, rqview.value, ampview.value,
noiseString, envString, nodes.size]
.writeTextArchive(path)
});
});
Button(leftview, 80@20)
.states_([["load"]])
.action_({
var values;
File.openDialog("", { |path|
values = Object.readTextArchive(path[0]);
(values.size != 6).if({
Error("File does not contain a ringz spec.").throw;
}, {
noiseString = values[3];
funcedit.setString(noiseString, 0, funcedit.string.size);
envString = values[4];
envedit.setString(envString, 0, envedit.string.size);
buildSynthDef.value;
ffreqview.value = values[0];
rqview.value = values[1];
ampview.value = values[2];
nodes.do(_.free);
nodes = { |i|
Synth(\ringz, [\in, percBus, \out, ringzBus], ringzGroup,
addAction: \addToTail);
// ringzMixer.play(\ringz, [\in, percMixer.inbus.index]);
} ! values[5]; // make the nodes
{ ffreqview.doAction;
rqview.doAction;
ampview.doAction;
}.defer(0.2);
});
});
});
// dynamic synthdef construction based on user input
GUI.staticText.new(rightview, 100@20).string_("Noise function:");
Button(rightview, 80@20)
.states_([["evaluate"]])
.action_({ |view|
noiseString = funcedit.string;
buildSynthDef.value;
});
rightview.startRow;
funcedit = GUI.textView.new(rightview, 275@200)
.string_(noiseString);
rightview.startRow;
GUI.staticText.new(rightview, 100@20).string_("Envelope:");
Button(rightview, 80@20)
.states_([["evaluate"]])
.action_({ |view|
envString = envedit.string;
src.setn(\env, envString.interpret.asArray);
});
rightview.startRow;
envedit = GUI.textView.new(rightview, 275@200)
.string_("Env.perc(0.01, 0.2)");
trigbus = Bus.control(s, 1);
{ trigsynth = SynthDef(\percTrig, { |trigrate, out|
Out.kr(out, Impulse.kr(trigrate))
}).play(percGroup, [\trigrate, rateEdit.value, \out, trigbus], addAction: \addToHead);
}.defer(0.2);
buildSynthDef = {
var func, env;
currentDef.notNil.if({
s.sendMsg(\d_free, currentDef.name);
});
func = ("{ " ++ noiseString ++ " }").interpret;
env = envString.interpret;
currentDef = SynthDef(\source, { |trigbus, outbus|
var trig, sig, envCtl;
trig = In.kr(trigbus, 1);
// Out.kr(trigbus, trig);
envCtl = Control.names(\env).kr(0 ! 100); // allow 25 env nodes maximum
sig = SynthDef.wrap(func, nil, [trig]) * EnvGen.ar(envCtl, trig);
Out.ar(outbus, sig)
}).send(s);
{ src.free;
src = Synth(\source, [\trigbus, trigbus, \outbus, percBus], percGroup,
addAction: \addToTail);
src.setn(\env, env.asArray);
}.defer(0.1);
};
helpview = GUI.textView.new(leftview, 458@161);
if(GUI.scheme.name == 'CocoaGUI') {
helpview.font = GUI.font.new("Helvetica", 12);
};
helpview.string = "Analog percussion tuner by James Harkins
Move the black knobs up and down to change the resonator characteristics.
The noise function and envelope control the exciter -- change the code and click 'evaluate' to hear it. Click 'new resonz' to add another filter (up to 10). Filters run in parallel, not in series.
The 'save' button stores the specs into a file; 'load' returns the editor to a saved state. 'stop' closes the window and removes all synths.";
helpview.editable = false;
window.onClose = stop;
0.5.wait;
buildSynthDef.value;
newButton.doAction;
window.front;
}.fork(AppClock);
};
)