refactor: io.timemates -> org.timemates

README.md

@@ -71,8 +71,8 @@ repositories {
 }
 
 dependencies {
-    implementation("io.timemates:sdk:$version")
-    implementation("io.timemates:rsocket-engine:$version")
+    implementation("org.timemates:sdk:$version")
+    implementation("org.timemates:rsocket-engine:$version")
 }
 ```
 

build-conventions/build.gradle.kts

@@ -0,0 +1,18 @@
+plugins {
+    `kotlin-dsl`
+}
+
+repositories {
+    mavenCentral()
+    google()
+    gradlePluginPortal()
+}
+
+kotlin {
+    jvmToolchain(11)
+}
+
+dependencies {
+    api(libs.kotlin.plugin)
+    api(libs.vanniktech.maven.publish)
+}

build-conventions/settings.gradle.kts

@@ -0,0 +1,14 @@
+dependencyResolutionManagement {
+    repositories {
+        mavenCentral()
+        google()
+    }
+
+    versionCatalogs {
+        create("libs") {
+            from(files("../gradle/libs.versions.toml"))
+        }
+    }
+}
+
+rootProject.name = "conventions"

build-conventions/src/main/kotlin/jvm-convention.gradle.kts

@@ -0,0 +1,7 @@
+plugins {
+    kotlin("jvm")
+}
+
+kotlin {
+    jvmToolchain(11)
+}

build-conventions/src/main/kotlin/jvm-library-convention.gradle.kts

@@ -0,0 +1,4 @@
+plugins {
+    id("jvm-convention")
+    id("library-convention")
+}

build-conventions/src/main/kotlin/library-convention.gradle.kts

@@ -0,0 +1,54 @@
+plugins {
+    id("com.vanniktech.maven.publish")
+}
+
+mavenPublishing {
+    pom {
+        url.set("https://github.com/timemates/sdk")
+        inceptionYear.set("2023")
+
+        licenses {
+            license {
+                name.set("The MIT License")
+                url.set("https://opensource.org/licenses/MIT")
+                distribution.set("https://opensource.org/licenses/MIT")
+            }
+        }
+
+        developers {
+            developer {
+                id.set("y9vad9")
+                name.set("Vadym Yaroshchuk")
+                url.set("https://github.com/y9vad9/")
+            }
+        }
+
+        scm {
+            url.set("https://github.com/timemates/sdk")
+            connection.set("scm:git:git://github.com/timemates/sdk.git")
+            developerConnection.set("scm:git:ssh://git@github.com/timemates/sdk.git")
+        }
+
+        issueManagement {
+            system.set("GitHub Issues")
+            url.set("https://github.com/timemates/sdk/issues")
+        }
+    }
+}
+
+publishing {
+    repositories {
+        maven {
+            name = "TimeMates"
+
+            url = uri(
+                "sftp://${System.getenv("SSH_HOST")}:22/${System.getenv("SSH_DEPLOY_PATH")}"
+            )
+
+            credentials {
+                username = System.getenv("SSH_USER")
+                password = System.getenv("SSH_PASSWORD")
+            }
+        }
+    }
+}

build-conventions/src/main/kotlin/multiplatform-convention.gradle.kts

@@ -0,0 +1,12 @@
+plugins {
+    kotlin("multiplatform")
+}
+
+kotlin {
+    jvm {
+        jvmToolchain(11)
+    }
+    js {
+        browser()
+    }
+}

build-conventions/src/main/kotlin/multiplatform-library-convention.gradle.kts

@@ -0,0 +1,10 @@
+import org.jetbrains.kotlin.gradle.dsl.ExplicitApiMode
+
+plugins {
+    id("multiplatform-convention")
+    id("library-convention")
+}
+
+kotlin {
+    explicitApi = ExplicitApiMode.Strict
+}

build.gradle.kts

@@ -1,6 +1,5 @@
 plugins {
     alias(libs.plugins.kotlin.multiplatform) apply false
     alias(libs.plugins.kotlin.jvm) apply false
-    alias(libs.plugins.android.library) apply false
-    alias(libs.plugins.kotlin.android) apply false
+    alias(libs.plugins.kotlin.js) apply false
 }