-
Notifications
You must be signed in to change notification settings - Fork 135
/
default.nix
65 lines (58 loc) · 1.97 KB
/
default.nix
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
{ overlays ? []
, config ? {}
, pkgs ? import ./nix { inherit config overlays; }
}:
with (import ./lib/directory.nix { inherit pkgs; });
with (import ./lib/docker.nix { inherit pkgs; });
let
# Kernel generators.
kernels = pkgs.callPackage ./kernels {};
kernelsString = pkgs.lib.concatMapStringsSep ":" (k: "${k.spec}");
# Python version setup.
python3 = pkgs.python3Packages;
# Default configuration.
defaultDirectory = "${python3.jupyterlab}/share/jupyter/lab";
defaultKernels = [ (kernels.iPythonWith {}) ];
defaultExtraPackages = p: [];
# JupyterLab with the appropriate kernel and directory setup.
jupyterlabWith = {
directory ? defaultDirectory,
kernels ? defaultKernels,
extraPackages ? defaultExtraPackages
}:
let
# PYTHONPATH setup for JupyterLab
pythonPath = python3.makePythonPath [
python3.ipykernel
python3.jupyter_contrib_core
python3.jupyter_nbextensions_configurator
python3.tornado
];
# JupyterLab executable wrapped with suitable environment variables.
jupyterlab = python3.toPythonModule (
python3.jupyterlab.overridePythonAttrs (oldAttrs: {
makeWrapperArgs = [
"--set JUPYTERLAB_DIR ${directory}"
"--set JUPYTER_PATH ${kernelsString kernels}"
"--set PYTHONPATH ${pythonPath}"
];
})
);
# Shell with the appropriate JupyterLab, launching it at startup.
env = pkgs.mkShell {
name = "jupyterlab-shell";
buildInputs =
[ jupyterlab generateDirectory pkgs.nodejs ] ++
(map (k: k.runtimePackages) kernels) ++
(extraPackages pkgs);
shellHook = ''
export JUPYTER_PATH=${kernelsString kernels}
export JUPYTERLAB=${jupyterlab}
'';
};
in
jupyterlab.override (oldAttrs: {
passthru = oldAttrs.passthru or {} // { inherit env; };
});
in
{ inherit jupyterlabWith kernels mkDirectoryWith mkDockerImage; }