Verify outputs of varnishncsa when UDS addresses are in use.

bin/varnishtest/tests/u00008.vtc

@@ -0,0 +1,71 @@
+varnishtest "varnishncsa outputs when UDS addresses are in use"
+
+# The %h formatter gets its value from ReqStart or BackendStart,
+# which now may be a UDS address.
+
+# For UDS backends without a .hosthdr setting, the Host header is
+# set to "localhost", which may appear in %r output.
+
+server s1 {
+	rxreq
+	txresp
+} -start
+
+server s2 -listen "${tmpdir}/s2.sock" {
+	rxreq
+	txresp
+} -start
+
+varnish v1 -arg "-a ${tmpdir}/v1.sock" -vcl+backend {
+	sub vcl_recv {
+		if (req.url == "/s1") {
+			set req.backend_hint = s1;
+		}
+		else {
+			set req.backend_hint = s2;
+		}
+	}
+} -start
+
+client c1 {
+	txreq -url "/s1"
+	rxresp
+} -run
+
+shell -expect "${s1_addr}" {
+      varnishncsa -n ${v1_name} -d -b -F "%h"
+}
+
+shell -expect "${localhost}" {
+      varnishncsa -n ${v1_name} -d -c -F "%h"
+}
+
+shell -expect "http://${s1_addr}/s1" {
+      varnishncsa -n ${v1_name} -d -b -F "%r"
+}
+
+shell -expect "http://localhost/s1 " {
+      varnishncsa -n ${v1_name} -d -c -F "%r"
+}
+
+client c2 -connect "${tmpdir}/v1.sock" {
+	txreq -url "/s2"
+	rxresp
+} -run
+
+# Socket path
+shell -expect "${s2_addr}" {
+      varnishncsa -n ${v1_name} -d -b -F "%h"
+}
+
+shell -expect "${tmpdir}/v1.sock" {
+      varnishncsa -n ${v1_name} -d -c -F "%h"
+}
+
+shell -expect "http://localhost/s2" {
+      varnishncsa -n ${v1_name} -d -b -F "%r"
+}
+
+shell -expect "http://localhost/s2" {
+      varnishncsa -n ${v1_name} -d -c -F "%r"
+}