app-arch/wimlib: bump to 1.13.4

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Marco Scardovi <marco@scardovi.com>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

app-arch/wimlib/Manifest

@@ -1 +1,2 @@
 DIST wimlib-1.13.3.tar.gz 1030667 BLAKE2B 2b897392bed3c4a390479f34925474c229ee835ab624c81a0baa7ebb8f3484f27aa4efb2a440debdcafe23b152b385bbe0f198d6f0560e8f88a34c7328a74edd SHA512 5c6e3bd1d7bda55812c818cc527cd241ac8a15276648f2a307db1f2a858de0b322e9f2beffda5bab991811aee3f4a953c3e31847bfa76a7d32ad5850595a15d4
+DIST wimlib-1.13.4.tar.gz 1040411 BLAKE2B 4563429d42be39b959a15ef66ac4c173531ff0c0b0f1a341812a4f870c9f189478f3ce78bf6240544f71b1746d98c9eae3f7182d646355343e26526559384f07 SHA512 480fe6fa6c6e8f1bf9c3960f5e1671f3266535b18dc72e9d7c4c05c7fb833d9b00db5ae9fb49154da6e71e536cae8b562cbf81ab5a124e2a79326927e2cf7344

app-arch/wimlib/wimlib-1.13.4.ebuild

@@ -0,0 +1,65 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools pax-utils
+
+DESCRIPTION="The open source Windows Imaging (WIM) library"
+HOMEPAGE="https://wimlib.net"
+SRC_URI="https://wimlib.net/downloads/${P}.tar.gz"
+
+KEYWORDS="~amd64 ~x86"
+LICENSE="|| ( GPL-3+ LGPL-3+ ) CC0-1.0"
+SLOT="0"
+IUSE="cpu_flags_x86_ssse3 fuse iso ntfs openssl test threads yasm"
+REQUIRED_USE="cpu_flags_x86_ssse3? ( !openssl )"
+
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	virtual/pkgconfig
+	cpu_flags_x86_ssse3? (
+		yasm? ( dev-lang/yasm )
+		!yasm? ( dev-lang/nasm )
+	)
+"
+RDEPEND="
+	dev-libs/libxml2:2
+	fuse? ( sys-fs/fuse:0 )
+	iso? (
+		app-arch/cabextract
+		app-cdr/cdrtools
+	)
+	ntfs? ( sys-fs/ntfs3g )
+	openssl? ( dev-libs/openssl:0= )
+"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_with ntfs ntfs-3g)
+		$(use_with fuse)
+		$(use_enable cpu_flags_x86_ssse3 ssse3-sha1)
+		$(use_with openssl libcrypto)
+		$(use_enable threads multithreaded-compression)
+		$(use_enable test test-support)
+		--disable-static
+	)
+	ac_cv_prog_NASM="$(usex yasm yasm nasm)" \
+		econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	default
+	pax-mark m "${S}"/.libs/wimlib-imagex
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+}