-
Notifications
You must be signed in to change notification settings - Fork 1
/
scanner.scad
1333 lines (1077 loc) · 35.5 KB
/
scanner.scad
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
// LIDAR 3D scanner
// by dvoros
//
// TODO:
// - same words used with multiple meaning:
// - leg
// - plug
use <./lib/chrisspen_gears/gears.scad>;
use <./lib/mylib.scad>;
/* [part selection] */
// Which part to generate.
part="test_nuts_and_bolts"; // [test_nuts_and_bolts, pink, purple, orange, green, blue, x_driver_gear, y_driver_gear, y_gear, mount, idle_leg, driver_leg, y_gear_plug, y_bearing_plug, pcb_bottom_spacer]
//
// BEGINNING OF PARAMETER DEFINITIONS
//
/* [x-bearing] */
// Parameters of bearing responsible for horizontal rotation of the plate
// Inner diameter (bore diameter). [mm]
$xbearing_inner_d = 50;
// Outer diameter. [mm]
$xbearing_outer_d = 72;
// Width. [mm]
$xbearing_h = 12;
/* [y-bearing] */
// Parameters of bearing responsible for vertical rotation of the LIDAR mount
// Inner diameter (bore diameter). [mm]
$ybearing_inner_d = 6;
// Outer diameter. [mm]
$ybearing_outer_d = 13;
// Width. [mm]
$ybearing_h = 5;
/* [M2 nut+bolt parameters] */
// All these need at least a tight fit slack (0.2)
// on their diameter to make a socket
// Bolt nominal diameter. [mm]
$m2_body_d = 2.0;
// Head diameter. [mm]
$m2_head_d = 4;
// Head height. [mm]
$m2_head_h = 1.8;
// Nut diameter across flats. [mm]
$m2_nut_square = 4;
// Nut diameter across corners. [mm]
$m2_nut_d = 4.6; // ~= $m2_nut_square / cos(30)
// Nut height. [mm]
$m2_nut_h = 1.5;
/* [M3 nut+bolt parameters] */
// All these need at least a tight fit slack (0.2)
// on their diameter to make a socket
// Bolt nominal diameter. [mm]
$m3_body_d = 3.0;
// Head diameter. [mm]
$m3_head_d = 5.8;
// Head height. [mm]
$m3_head_h = 2.4;
// Nut diameter across flats. [mm]
$m3_nut_square = 5.4;
// Nut diameter across corners. [mm]
$m3_nut_d = 6.2; // ~= $m3_nut_square / cos(30)
// Nut height. [mm]
$m3_nut_h = 2.3;
/* [M4 nut+bolt parameters] */
// All these need at least a tight fit slack (0.2)
// on their diameter to make a socket
// Bolt nominal diameter. [mm]
$m4_body_d = 4.0;
// Head diameter. [mm]
$m4_head_d = 8.0;
// Head height. [mm]
$m4_head_h = 3.2;
// Nut diameter across flats. [mm]
$m4_nut_square = 6.8;
// Nut diameter across corners. [mm]
$m4_nut_d = 7.8; // ~= $m4_nut_square / cos(30)
// Nut height. [mm]
$m4_nut_h = 3.0;
// This module definition is here to stop OpenSCAD/Thingiverse
// customizer from picking up other parameters that require
// more care to change.
module dummy_to_stop_customizer() {}
$m2_body_after_nut_safety = $m2_nut_h + 2.0;
$m3_body_after_nut_safety = $m3_nut_h + 2.0;
$m4_body_after_nut_safety = $m4_nut_h + 2.0;
e=0.01 + 0;
color_orange=[255/255, 165/255, 0/255];
$fn=30 + 0;
//
// Slacks
//
// "no slack"
$s0 = 0;
// very tight fit
$s1 = 0.15;
// easy fit
$s2 = 0.3;
// tight fit
$s3 = 0.2;
// needs to be pulled together with a bolt to get a tight fit
$s4 = 0.4;
// can't touch
$s5 = 0.8;
// Tooth numbers for the horizontal gears
$base_tooth_num = 100;
$xdriver_tooth_num = 25;
// Tooth numbers for the vertical gears
$stand_tooth_num = 60;
$ydriver_tooth_num = 20;
$bolt_ygear_r = 16;
$gear_h = 10;
$motor_d = 54; // diameter of circle on plate for motor
$motor_h = 40;
$motor_w = 42;
$motor_shaft_h = 23;
$motor_shaft_d = 5;
// distance of y-shaft from the plate
$yshaft_z=70;
$stand_leg_foot_d = 15;
$main_pcb_x = 72;
$main_pcb_y = 72;
$main_pcb_hole_dist = 65;
$main_pcb_hole_offset_x = 4.2; // distance of top-left hole (center) from the left
$main_pcb_hole_offset_y = 3.5; // distance of top-left hole (center) from the top
$main_pcb_bottom_spacer_h = 6; // distance between plate and main PCB
$plug_pcb_x = 23;
$plug_pcb_y = 11;
$magnet_d=3;
$magnet_h=1.7;
$mount_y=($stand_tooth_num-2)/sqrt(2); // depth of mount
$mount_h=$ybearing_h; // wall width for mount (needs to fit bearing)
$mount_magnet_shaft_dist=$mount_y/2;
$slip_ring_small_d = 7.8;
$slip_ring_small_h = 8.5;
$slip_ring_plate_d = 43.8;
$slip_ring_plate_h = 2.5;
$slip_ring_large_d = 21.8;
$slip_ring_large_h = 28-$slip_ring_plate_h;
$slip_ring_hole_r = $slip_ring_plate_d/2-4.2; // radius of the circle that the holes lie on
$slip_ring_hole_d = 5.5; // diameter of holes
$slip_ring_wire_slack = 10; // necessary distance for wires to bend
$slip_ring_conduit_d = 8;
$lidar_bolts_x=28.6;
$lidar_bolts_y=27.4;
// Bolt lengths
$bolt_inner_body_len = 25;
$bolt_outer_body_len = 40;
//
// Voltage source PCB parameters
//
$plug_pcb_pcb_z = 1.6 + 2*$s3;
$plug_pcb_plug_z = 10.9 + 2*$s3;
$plug_pcb_plug_y = 10 + 2*$s3;
$plug_pcb_plug_dist = 3.7; // from the back of the PCB
$plug_pcb_leg_offset = 1; // from the sides of the PCB
$plug_pcb_leg_z = 4.5 + 2*$s3;
$plug_pcb_h = $plug_pcb_leg_z + $plug_pcb_plug_z;
//
// REST IS CALCULATED, DO NOT EDIT!
//
// width where nut is embeddable (horizontally)
$h1m3 = ($m3_nut_h + $s3) * 2; echo($h1m3=$h1m3);
$h1m4 = ($m4_nut_h + $s3) * 2; echo($h1m4=$h1m4);
// diameter where nut is embeddable in the center (vertically)
$h2m3 = ($m3_nut_d + $s3) * 2; echo($h2m3=$h2m3);
$h2m4 = ($m4_nut_d + $s3) * 2; echo($h2m4=$h2m4);
// rigid wall width
$h3 = 0.8;
// place for an M4 head that can't touch the ceiling
$h4 = $m4_head_h + 2*$s5;
$w1 = $xbearing_inner_d - $s2;
$w2 = $xbearing_inner_d + ($xbearing_outer_d - $xbearing_inner_d) / 3;
$w3 = $xbearing_outer_d - ($xbearing_outer_d - $xbearing_inner_d) / 3;
$w4 = $xbearing_outer_d + $s2;
$w5_min = $w4 + 2*$h2m4;
$w5 = $base_tooth_num + 2;
$leg_pcb_gap = 2*$s5;
$plate_d = $w5;
$plate_h = $h1m3;
$xmotor_x = ($base_tooth_num+$xdriver_tooth_num)/2;
$ymotor_z = ($stand_tooth_num+$ydriver_tooth_num)/2;
// distance of stand legs
$stand_legs_dist = $main_pcb_x+4*$s5;
// height of the bottom part of the stand legs
$stand_legs_bottom_width=$h1m4;
// outer width of the LIDAR mount
$mount_x=$stand_legs_dist-2*$leg_pcb_gap-$gear_h;
// TODO: re-enable!!!
// assert($w5 >= $w5_min, str("teeth number is too small to fit (",$w5,"<",$w5_min,")"));
// Radius of cirlce on which to place the bolts on
$bolt_inner_r = $w1/2 - $h2m3/2;
$bolt_outer_r = $w5/2 - $h2m4/2;
// Desired distrance of nuts from the heads
$bolt_inner_nut_z = $bolt_inner_body_len - $m4_body_after_nut_safety;
$bolt_outer_nut_z = $bolt_outer_body_len - $m4_body_after_nut_safety;
// Middle of bearing is positioned in the center
// relative positions follow
$orange_h = $h1m4;
// height of green part (added up from top to bottom)
$green_h =
$plate_h // plate height
+ $s5 + $orange_h // space for ORANGE
+ ($xbearing_h/2 - $s4); // within bearing
$plate_z = $green_h + $s4;
// height of blue part (added up from top to bottom)
$blue_h = ($xbearing_h/2 - $s4) + $h1m3;
// height of purple part (added up from top to bottom)
$purple_h_min = $slip_ring_small_h + $slip_ring_wire_slack - $h4;
$purple_h = 2*$h3 + $plug_pcb_h;
// height of pink part (added up from top to bottom)
$pink_h = ($xbearing_h - $s4) + $h4 + $h1m3;
// the very bottom when everything's in place
$bottom_z = -($purple_h+$pink_h + $s4 - $xbearing_h/2);
//
// END OF PARAMETERS
//
// Shows all parts of the base station cut in half.
// Useful when working on the base station.
if (part == "station_cut") {
cut_x()
{
base_station();
%cut_x() xbearing();
%cut_x() station_bolts();
%cut_x() pcb(in_place=true);
%cut_x() slip_ring(in_place=true);
};
}
// All the stand together (everything that atands on the plate).
if (part == "stand") {
// plate
% projection()
station_green();
stand();
}
if (part == "everything") {
base_station();
%station_bolts();
translate([0, 0, $plate_z])
stand();
}
if (part == "pink") station_pink();
if (part == "purple") station_purple();
if (part == "orange") station_orange();
if (part == "green") station_green();
if (part == "blue") station_blue();
if (part == "x_driver_gear") driver_gear(tooth_number=$xdriver_tooth_num, inverted=true);
if (part == "y_driver_gear") driver_gear(tooth_number=$ydriver_tooth_num, inverted=true);
if (part == "y_gear_plug") ygear_plug_m4();
if (part == "y_bearing_plug") ybearing_plug_m4();
if (part == "pcb_bottom_spacer") pcb_bottom_spacer();
if (part == "y_gear") y_gear();
if (part == "idle_leg") idle_leg();
if (part == "driver_leg") driver_leg();
if (part == "mount") mount();
// Test-fit parts
if (part == "test_voltage_plug") test_voltage_plug();
if (part == "test_nuts_and_bolts") test_nuts_and_bolts();
module base_station() {
color("blue")
station_blue(in_place=true);
color("green")
station_green(in_place=true);
color("purple")
station_purple(in_place=true);
color("pink")
station_pink(in_place=true);
color(color_orange)
station_orange(true);
}
module stand() {
// parts of the stand
idle_leg();
driver_leg();
ybearing_plug_m4(in_place=true);
ygear_plug_m4(in_place=true);
y_gear(in_place=true);
mount(in_place=true);
// other accessories
% pcb();
% xmotor();
% ymotor();
% lidar(in_place=true);
% ybearings();
}
module hall_hole() {
h=$h1m3;
hall_d=4.4;
hall_l=4;
hole_l=10;
entrance_deg=80;
translate([0, 0, 0.4 + hall_d/2-e])
union() {
translate([0, 0, -0.4/2])
cube([hall_d, hall_d, hall_d+0.4], center=true);
rotate([0, 90, 0])
translate([-hall_d/2, -hall_d/2, 0])
cube([hall_d, hall_d, hole_l]);
x=cos(entrance_deg)*hall_d;
y=sin(entrance_deg)*hall_d;
translate([hole_l-x/2, 0, -(hall_d-y)/2])
rotate([0, entrance_deg, 0])
translate([-hall_d/2, -hall_d/2, 0])
cube([hall_d, hall_d, 30]);
}
}
module magnet_slot() {
cylinder(d=$magnet_d+$s2, h=$magnet_h+$s1);
}
module y_gear(in_place = false) {
in_place_translate = in_place ? [-$stand_legs_dist/2 + $leg_pcb_gap, 0, $yshaft_z] : [0, 0, 0];
in_place_rotate = in_place ? [0, 90, 0] : [0, 0, 0];
translate(in_place_translate)
rotate(in_place_rotate)
rotate([0, 0, -45])
difference() {
gear(tooth_number=$stand_tooth_num, width=$gear_h, bore=0, angle=210, angle_offset=60);
// shaft
cylinder(d=$ybearing_outer_d+$s3, h=3*$gear_h, center=true);
// nuts
z_rot_copy(r=$bolt_ygear_r)
m3_nut_pocket(z=$gear_h/2);
}
}
module xmotor() {
translate([$xmotor_x, 0, 0])
mirror([0, 0, 1])
motor();
}
module ymotor() {
motor_plate_dist=$yshaft_z-$ymotor_z;
// motor body
translate([-$stand_legs_dist/2-$h1m3-$s2, 0, motor_plate_dist])
rotate([0, 90, 0])
motor();
// driver gear
translate([-$stand_legs_dist/2 + $gear_h/2 + $leg_pcb_gap, 0, motor_plate_dist])
rotate([0, 90, 0])
translate([0, 0, -$gear_h/2])
driver_gear(tooth_number=20, inverted=true);
}
module driver_leg() {
motor_plate_dist=$yshaft_z-$ymotor_z;
sz=$yshaft_z-$stand_legs_bottom_width; // y-shaft distance from the top of the bottom part
motor_sz=motor_plate_dist-$stand_legs_bottom_width; // motor's distance from the top of the bottom part
// bottom
translate([-$main_pcb_x/2-$leg_pcb_gap, 0, 0])
difference() {
union() {
// base
linear_extrude(height=$h1m4)
hull() {
mirror_y()
mirror([1, 0])
translate([0, $motor_w/2+$s5])
leg_zprojection();
}
// motor holder
translate([-1.5*$stand_leg_foot_d, -$motor_w/2, 0])
cube([1.5*$stand_leg_foot_d, $motor_w, motor_plate_dist - $motor_w/2 - $s2]);
// main wall
translate([0, 0, $stand_legs_bottom_width])
mirror([1, 0, 0])
rotate([90, 0, 90])
difference() {
linear_extrude(height=$h1m3)
hull() {
// half of depth of legs
y = $motor_w/2+$s5+$stand_leg_foot_d;
polygon([[-y, 0], [y, 0], [0, sz]]);
// round top arounf shaft
translate([0, sz])
circle(d=$h2m4);
}
// nut pocket and yshaft
translate([0, sz, 0])
mirror([0, 0, 1])
m4_nut_pocket(z=-$h1m3/2);
// holes for mounting the motor
translate([0, motor_sz, -e])
motor_holes();
}
}
// bolts on the bottom
mirror_y()
mirror([1, 0])
translate([0, $motor_w/2+$s5, 0])
leg_bottom_sockets();
}
}
module idle_leg() {
h=$yshaft_z+$h2m4/2;
mw = $motor_w+2*$s5; // motor width with gap
sz = $yshaft_z-$stand_legs_bottom_width; // y-shaft distance from the top of the bottom part
translate([$main_pcb_x/2+$leg_pcb_gap, 0, $stand_legs_bottom_width])
rotate([90, 0, 90])
difference() {
linear_extrude(height=$h1m3)
// triangular part above motor
difference() {
hull() {
// half of depth of legs
y = $motor_w/2+$s5+$stand_leg_foot_d;
polygon([[-y, 0], [y, 0], [0, sz]]);
// shaft rounding
translate([0, sz])
circle(d=$h2m4);
// motor rounding
mirror_x()
translate([mw/2, mw - $stand_legs_bottom_width])
circle(d=20);
}
// place for motor
translate([0, mw/2-$stand_legs_bottom_width])
square(mw, center=true);
}
// nut pocket and yshaft
translate([0, sz, 0])
mirror([0, 0, 1])
m4_nut_pocket(z=-$h1m3/2);
// hall hole
translate([0, sz-$mount_magnet_shaft_dist, 0])
mirror([1, 0, 0])
hall_hole();
}
// bottom
mirror_y()
translate([$main_pcb_x/2+$leg_pcb_gap, $motor_w/2+$s5])
difference() {
linear_extrude(height=$stand_legs_bottom_width)
leg_zprojection();
leg_bottom_sockets();
}
}
module leg_bottom_sockets() {
translate([$stand_leg_foot_d, $stand_leg_foot_d/2, 0])
m4_head_pocket();
}
module mount(in_place=false) {
in_place_translate = in_place ? [-$mount_x/2 + $stand_legs_dist/2 - $leg_pcb_gap, 0, $yshaft_z] : [0, 0, 0];
ledge=($ybearing_outer_d-$ybearing_inner_d)/2/3;
translate(in_place_translate)
difference() {
union () {
intersection() {
translate([-$mount_x/2, -$mount_y/2 , -$mount_y/2 - $mount_h])
difference() {
r = $mount_x/2 - ($bolt_ygear_r/sin(45));
rotate([0, 0, 90])
rotate([90, 0, 0])
linear_extrude(height=$mount_x)
hull() {
translate([r, $mount_y+$mount_h-r])
circle(r=r);
translate([$mount_y-r, $mount_y+$mount_h-r])
circle(r=r);
square([$mount_y, 1]);
}
translate([$mount_h, -$mount_y, $mount_h])
cube([$mount_x-2*$mount_h, 3*$mount_y, 3*$mount_y]);
}
// remove parts that would reach out from behind the gear
rotate([0, 90, 0])
cylinder(d=$stand_tooth_num, h=3*$mount_x, center=true);
}
translate([$mount_x/2-$mount_h-2, 0, 0])
rotate([0, 90, 0])
cylinder(d=$ybearing_outer_d+$s3+3, h=$mount_h);
}
// holes for mounting on gear
translate([-$mount_x/2+$mount_h+e, 0, 0])
rotate([0, -90, 0])
z_rot_copy(r=$bolt_ygear_r, offset_deg=45)
mirror([0, 0, 1])
m3_head_pocket(z=-$mount_h/2);
// hole for bolt on idle and gear side
translate([$mount_x/2-$mount_h, 0, 0])
rotate([0, 90, 0])
cylinder(d=$ybearing_outer_d+$s3, h=$mount_x);
rotate([0, 90, 0])
cylinder(d=$ybearing_outer_d-2*ledge, h=2*$mount_x, center=true);
// holes on the idle side to help assembly
translate([$mount_x, 0, 0])
rotate([0, -90, 0])
z_rot_copy(r=$bolt_ygear_r, offset_deg=45)
cylinder(d=$m4_head_d+2*$s2, h=$mount_x);
// bolts for mounting lidar
mirror_x()
mirror_y()
translate([$lidar_bolts_x/2, $lidar_bolts_y/2, 0])
m3_nut_pocket(z=-$mount_y/2 - $mount_h/2);
// magnet socket
translate([$mount_x/2+e, 0, -$mount_magnet_shaft_dist])
rotate([0, -90, 0])
magnet_slot();
}
}
module leg_zprojection() {
hull() {
translate([$stand_leg_foot_d, $stand_leg_foot_d/2, 0])
circle(d=$stand_leg_foot_d);
square([$stand_leg_foot_d/2, $stand_leg_foot_d]);
}
}
module station_orange(in_place=false) {
in_place_z = in_place ? $xbearing_h/2 : 0;
translate([0, 0, in_place_z])
difference() {
cylinder(d=$w5, h=$orange_h);
cylinder(d=$w3, h=3*$orange_h, center=true);
// bolt cutouts
z_rot_copy(r=$bolt_outer_r)
m4_head_pocket(z=$orange_h/2);
// magnet slot and notch
rotate([0, 0, 45]) {
translate([$bolt_outer_r, 0, $orange_h+e])
mirror([0, 0, 1])
magnet_slot();
translate([$w5/2, 0, 0])
cylinder(d=3, h=3*$orange_h, center=true);
}
}
}
module station_pink(in_place=false) {
base_h= $h4 + $h1m3 + ($xbearing_h-$gear_h) - $s4;
pink_h = base_h + $gear_h;
in_place_z = in_place ? $bottom_z + $purple_h : 0;
translate([0, 0, in_place_z])
difference() {
union() {
cylinder(d=$w5, h=base_h);
translate([0, 0, base_h])
gear(tooth_number=$base_tooth_num, width=$gear_h, bore=0);
}
// smaller dia, under bearing
cylinder(d=$w3, h=3*pink_h, center=true);
// larger dia, around bearing
translate([0, 0, $h4+$h1m3])
cylinder(d=$w4, h=$pink_h);
// bolt cutouts
z_rot_copy(r=$bolt_outer_r)
cylinder(d=$m4_body_d+2*$s2, h=3*pink_h, center=true);
}
}
module station_purple(in_place=false) {
in_place_z = in_place ? $bottom_z : 0;
translate([0, 0, in_place_z])
difference() {
union() {
cylinder(d=$w5, h=$purple_h);
// mounting holes on the bottom
difference() {
h=$h1m4;
r=$w5/2 + $h2m4/2;
linear_extrude(height=h)
rotz()
difference() {
hull()
mirror_y()
translate([0, r])
circle(d=$h2m4);
}
z_rot_copy(r=r, deg=90)
m4_head_pocket();
}
}
// bolt cutouts
z_rot_copy(r=$bolt_outer_r)
m4_nut_pocket(z=$purple_h + $pink_h - ($bolt_outer_nut_z - ($orange_h/2 + $s4)));
// assembly hole for slip ring bolts
translate([$slip_ring_hole_r, 0, 0])
cylinder(d=$m4_head_d+2*$s5, h=3*$purple_h, center=true);
// slip ring
cylinder(d=$slip_ring_small_d+$s2, h=3*$purple_h, center=true);
// conduit
rotate([0, 90, 45])
cylinder(d=$slip_ring_conduit_d, h=2*$w5);
sphere(d=2*$slip_ring_wire_slack);
// voltage plug
voltage_plug(in_place=true);
}
}
// plate
module station_green(in_place=false) {
mirror_z = in_place ? 1 : 0;
in_place_z = in_place ? $plate_z : 0;
translate([0, 0, in_place_z])
mirror([0, 0, mirror_z])
difference() {
union() {
// plate
linear_extrude(height=$plate_h)
hull() {
// main part above base
circle(d=$plate_d);
// motor holder
translate([$xmotor_x, 0, 0])
circle(d=$motor_d);
// legs
mirror_x()
mirror_y()
translate([$main_pcb_x/2+$leg_pcb_gap, $motor_w/2+$s5])
leg_zprojection();
}
// middle part that makes space for ORANGE
translate([0, 0, $plate_h])
cylinder(d=$w2, h=$orange_h+$s5);
// small disc inside the bearing
translate([0, 0, $plate_h + $s5 + $orange_h])
station_inside_bearing();
}
// middle bolt cutouts
translate([0, 0, -e])
z_rot_copy(r=$slip_ring_hole_r, deg=120)
union() {
// body of bolt
cylinder(d=$m4_body_d+2*$s2, h=2*$green_h);
// nut pocket
hexagon(
($m4_nut_d+2*$s2)/2,
$green_h + $s4 - ($bolt_inner_nut_z - ($blue_h + $s4))
);
}
// assembly hole for orange bolts
translate([0, $bolt_outer_r, -e])
cylinder(d=$m4_head_d+2*$s2, h=2*$green_h);
// hall sensor
translate([0, -$bolt_outer_r, $plate_h])
mirror([0, 0, 1])
hall_hole();
// motor bolt cutouts
translate([$xmotor_x, 0, $plate_h+e])
mirror([0, 0, 1])
motor_holes();
// slip ring
cylinder(d=$slip_ring_large_d + 2*$s2, h=3*$green_h, center=true);
// leg bolts with nut pocket
mirror_x()
mirror_y()
translate([$main_pcb_x/2+$leg_pcb_gap, $motor_w/2+$s5])
translate([$stand_leg_foot_d, $stand_leg_foot_d/2, 0])
union() {
cylinder(d=$m4_body_d+2*$s2, h=3*$h1m3, center=true);
// TODO: we're putting M4 nut into plate that's supposed to only hold M3...
translate([0, 0, $h1m3/2])
hexagon(
($m4_nut_d+2*$s2)/2,
$h1m3
);
}
// pcb bolts with nut pocket
pcb_holes();
}
}
module station_blue(in_place=false) {
in_place_z = in_place ? -$blue_h-$s4 : 0;
translate([0, 0, in_place_z])
difference() {
union() {
// larger outer part
cylinder(d=$w2, h=$h1m3);
// small disc inside the bearing
translate([0, 0, $h1m3])
station_inside_bearing();
}
// bolt cutouts
z_rot_copy(r=$slip_ring_hole_r, deg=120)
cylinder(d=$m4_body_d+2*$s2, h=2*$blue_h, center=true);
// slip ring plate
translate([0, 0, -e])
cylinder(d=$slip_ring_plate_d + 2*$s2, h=$slip_ring_plate_h+$s2);
// slip ring body
cylinder(d=$slip_ring_large_d + 2*$s2, h=3*$blue_h, center=true);
}
}
module station_bolts() {
z_rot_copy(r=$slip_ring_hole_r, deg=120)
translate([0, 0, $bolt_inner_body_len - $blue_h - $s4])
rotate([180, 0, 0])
m4_with_nut(l=$bolt_inner_body_len, nut_z=$bolt_inner_nut_z, center=false);
// outer
translate([0, 0, -$bolt_outer_body_len+$xbearing_h/2+$orange_h/2])
z_rot_copy(r=$bolt_outer_r)
m4_with_nut(l=$bolt_outer_body_len, nut_z=$bolt_outer_nut_z, center=false);
}
module m3_head_pocket(z=$h1m3-$m3_head_h-$s2) {
translate([0, 0, z])
union() {
cylinder(d=$m3_body_d+2*$s2, h=1000, center=true);
cylinder(d=$m3_head_d+2*$s2, h=500);
}
}
module m4_head_pocket(z=$h1m4-$m4_head_h-$s2) {
translate([0, 0, z])
union() {
cylinder(d=$m4_body_d+2*$s2, h=1000, center=true);
cylinder(d=$m4_head_d+2*$s2, h=500);
}
}
module m4_nut_pocket(z=0) {
translate([0, 0, z])
union() {
cylinder(d=$m4_body_d+2*$s2, h=1000, center=true);
translate([0, 0, -500])
hexagon(
($m4_nut_d+2*$s2)/2,
500
);
}
}
module m3_nut_pocket(z=0) {
translate([0, 0, z])
union() {
cylinder(d=$m3_body_d+2*$s2, h=1000, center=true);
translate([0, 0, -500])
hexagon(
($m3_nut_d+2*$s2)/2,
500
);
}
}
module m2_nut_pocket(z=0) {
translate([0, 0, z])
union() {
cylinder(d=$m2_body_d+2*$s2, h=1000, center=true);
translate([0, 0, -500])
hexagon(
($m2_nut_d+$s3)/2,
500
);
}
}
module xbearing() {
translate([0, 0, -e])
difference() {
cylinder(d=$xbearing_outer_d, h=$xbearing_h, center=true);
cylinder(d=$xbearing_inner_d, h=3*$xbearing_h, center=true);
}
}
module ybearings() {
translate([0, 0, $yshaft_z]) {
translate([$stand_legs_dist/2 - $ybearing_h/2 - $leg_pcb_gap, 0])
rotate([0, -90, 0])
{
%ybearing();
}
translate([-$stand_legs_dist/2 + $gear_h/2 + $leg_pcb_gap, 0, 0])
rotate([0, 90, 0])
{
translate([0, 0, $ybearing_h/2])
%ybearing();
translate([0, 0, -$ybearing_h/2])
%ybearing();
}
}
}
module ybearing() {
translate([0, 0, -e])
difference() {
cylinder(d=$ybearing_outer_d, h=$ybearing_h, center=true);
cylinder(d=$ybearing_inner_d, h=3*$ybearing_h, center=true);
}
}
// Part of green and blue that's inside the bearing.
// Doesn't include holes for the bolts.
module station_inside_bearing() {
h= $xbearing_h/2 - $s4;
union() {
// outer ring
difference() {
cylinder(d=$w1, h=h);
translate([0, 0, -h])
cylinder(d=$w1-2*$h3, h = 3*h);
}
// bolt supports
d=($w1/2-$slip_ring_hole_r)*2;
z_rot_copy(r=$slip_ring_hole_r, deg=120)
cylinder(d=d, h=h);
}
}
// l: body length
// nut_z: distance between head and nut
module bolt_with_nut(l, nut_z, head_d, head_h, body_d, nut_h, nut_d, center=true) {
c = center ? -l/2 : 0;
// head
translate([0, 0, l+c])
scale([head_d, head_d, 2*head_h])
cut_z()
sphere(d=1);
// body
translate([0, 0, c])
cylinder(d=body_d, h=l);
// nut
translate([0, 0, l - nut_z - nut_h + c])
hexagon(nut_d/2, nut_h);
}
// l: body length
// nut_z: distance between head and nut
module m3_with_nut(l, nut_z, center=true) {
bolt_with_nut(l, nut_z,
$m3_head_d,
$m3_head_h,
$m3_body_d,
$m3_nut_h,
$m3_nut_d,
center);
}
// l: body length
// nut_z: distance between head and nut
module m4_with_nut(l, nut_z, center=true) {
bolt_with_nut(l, nut_z,
$m4_head_d,