build.gradle

group 'venus'
version '0.1.0'

buildscript {
    ext.dokka_version = '0.10.1'
    ext.kotlin_version = '1.3.72'
    ext.ktlint_version = '0.33.0'

    repositories {
        mavenCentral()
    }

    dependencies {
        classpath "org.jetbrains.dokka:dokka-gradle-plugin:$dokka_version"
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
    }
}

apply plugin: 'kotlin2js'
apply plugin: 'kotlin-dce-js'
apply plugin: 'org.jetbrains.dokka'

runDceKotlinJs.keep 'venus.Driver.run', 'venusbackend.assembler.Linter', 'venus.api.API', "kotlin.Number"

runDceKotlinJs.dceOptions.devMode = true
runDceTestKotlinJs.dceOptions.devMode = true

configurations {
    ktlint
}

kotlin {
    experimental {
        coroutines 'enable'
    }
}

repositories {
    mavenCentral()
}

compileKotlin2Js {
    kotlinOptions.sourceMap = true
    kotlinOptions.sourceMapEmbedSources = "always"
    // remaining configuration options
}

task ktlint(type: JavaExec) {
    description = "Check Kotlin code style."
    main = "com.pinterest.ktlint.Main"
    classpath = configurations.ktlint
    args "--verbose", "src/**/*.kt"
}

check.dependsOn ktlint

task ktlintFormat(type: JavaExec) {
    description = "Fix Kotlin code style deviations."
    main = "com.pinterest.ktlint.Main"
    classpath = configurations.ktlint
    args "-F", "src/**/*.kt"
}

dokka {
    outputFormat = 'html'
    outputDirectory = "doc"
}

dependencies {
    ktlint "com.pinterest:ktlint:$ktlint_version"
    implementation "org.jetbrains.kotlin:kotlin-stdlib-js:$kotlin_version"
    testImplementation "org.jetbrains.kotlin:kotlin-test-js:$kotlin_version"
}