mingw-w64-arm-none-eabi-binutils: Added

mingw-w64-arm-none-eabi-binutils/PKGBUILD

@@ -0,0 +1,48 @@
+# Maintainer: Carlos Antunes <cmantunes@gmail.com>
+# Contributed by: nanodude
+
+_realname=binutils
+_target=arm-none-eabi
+
+pkgname=("${MINGW_PACKAGE_PREFIX}-${_target}-${_realname}")
+pkgver=2.24
+pkgrel=1
+pkgdesc="GNU Tools for ARM Embedded Processors - Binutils (mingw-w64)"
+arch=('any')
+url="http://www.gnu.org/software/binutils/"
+license=('GPL')
+groups=("${MINGW_PACKAGE_PREFIX}-${_target}-toolchain")
+makedepends=("${MINGW_PACKAGE_PREFIX}-gcc")
+options=('staticlibs')
+source=("ftp://mirrors.kernel.org/sources.redhat.com/${_realname}/releases/${_realname}-${pkgver}.tar.bz2")
+md5sums=('e0f71a7b2ddab0f8612336ac81d9636b')
+
+build() {
+  if check_option "debug" "y"; then
+    CFLAGS+=" -g -O0"
+  fi
+  cd $srcdir
+  rm -rf build-${MINGW_CHOST}
+  mkdir -p build-${MINGW_CHOST} && cd build-${MINGW_CHOST}
+  ../${_realname}-${pkgver}/configure \
+    --build="${MINGW_CHOST}" \
+    --host="${MINGW_CHOST}" \
+    --target="${_target}" \
+    --prefix="${MINGW_PREFIX}" \
+    --disable-werror \
+    --disable-lto \
+    --with-sysroot="${MINGW_PREFIX}" \
+    --disable-nls \
+    --disable-rpath \
+    --enable-multilib \
+    --enable-interwork
+  make
+}
+
+package() {
+  cd ${srcdir}/build-${MINGW_CHOST}
+  make DESTDIR=${pkgdir} install
+
+  # Remove unwanted files
+  rm -rf ${pkgdir}${MINGW_PREFIX}/share/info
+}