Add allequal

[CameronBieganek]

Since we already have allunique, it might make sense to also add allequal. One reason to add allequal is that a proper implementation is much faster than the naive length(unique(itr)) == 1.

function allequal(x)
    first, rest = Iterators.peel(x)

    for v in rest
        if v == first
            continue
        else
            return false
        end
    end

    true
end

slow_allequal(x) = length(unique(x)) == 1

julia> using BenchmarkTools

julia> x = randn(1000); y = fill(1, 1000);

julia> @btime allequal($x);
  3.288 ns (0 allocations: 0 bytes)

julia> @btime slow_allequal($x);
  36.791 μs (27 allocations: 65.95 KiB)

julia> @btime allequal($y);
  475.082 ns (0 allocations: 0 bytes)

julia> @btime slow_allequal($y);
  3.816 μs (6 allocations: 608 bytes)

[oscardssmith]

I think the idiom to use isn't length(unique(x)), but all(isequal(first(x)), x) which is roughly 10% faster than the version you proposed (not sure why).

[CameronBieganek]

Interesting! I wonder why that's faster...

I suspect that beginners are more likely to try length(unique(x)) == 1 than all(isequal(first(x)), x). Coming from R, length(unique(x)) == 1 was the first thing that I reached for.

[oscardssmith]

That's fair, I personally don't like this getting it's own name, but make a PR and triage can decide.

[CameronBieganek]

Yeah, I wouldn't necessarily argue for it getting its own name, but since we already have allunique, it seems sensible to also have allequal.

[goretkin]

We would want allequal([]) == true, the same way all([]) [1]. None of the two idioms mentioned have that behavior, but it is easier to do with length(unique(x)) <= 1

It would be nice if there was an all_transitive (this is not a good name) method that could work for any transitive relation, then allequal(x) could be defined in terms of a more general all_transitive(isequal, x).

[1] imagine a definition like all(Base.splat(isequal), all_pairs(x))

[CameronBieganek]

We would want allequal([]) == true, the same way all([])

Yeah, I just did the simple thing in my PR and made it

allequal(itr) = isempty(itr) ? true : all(isequal(first(itr)), itr)

[GregPlowman]

Like some other functions, e.g. all, findall, I sometimes want the predicate version of allequal:

allequal(f, itr) = isempty(itr) ? true : all(x -> isequal(f(x), f(first(itr))), itr)

[CameronBieganek]

@GregPlowman That might be nice. Want to open a new issue for that?