m_dog.qc

/*
==============================================================================

DOG

==============================================================================
*/
$cd id1/models/dog
$origin 0 0 24
$base base
$skin skin

$frame attack1 attack2 attack3 attack4 attack5 attack6 attack7 attack8

$frame death1 death2 death3 death4 death5 death6 death7 death8 death9

$frame deathb1 deathb2 deathb3 deathb4 deathb5 deathb6 deathb7 deathb8
$frame deathb9

$frame pain1 pain2 pain3 pain4 pain5 pain6

$frame painb1 painb2 painb3 painb4 painb5 painb6 painb7 painb8 painb9 painb10
$frame painb11 painb12 painb13 painb14 painb15 painb16

$frame run1 run2 run3 run4 run5 run6 run7 run8 run9 run10 run11 run12

$frame leap1 leap2 leap3 leap4 leap5 leap6 leap7 leap8 leap9

$frame stand1 stand2 stand3 stand4 stand5 stand6 stand7 stand8 stand9

$frame walk1 walk2 walk3 walk4 walk5 walk6 walk7 walk8

/*
================
dog_bite

================
*/
void() dog_bite =
{
	vector	delta;

	if (!self.enemy)
		return;

	ai_charge(10);

	if (!CanDamage (self.enemy, self.origin))
		return;

	delta = self.enemy.origin - self.origin;

	if (vlen(delta) > 100)
		return;
		
	T_Damage(self.enemy, self, self, 8 + random() * 8, DMGTYPE_MELEE);
}

void()	Dog_JumpTouchGround =
{
	if (!checkbottom(self))
	{
		if (self.flags & FL_ONGROUND)
		{	// jump randomly to not get hung up
			self.touch = SUB_Null;
			self.think = dog_leap1;
			self.nextthink = time + 0.1;
		}
		return;	// not on ground yet
	}

	self.touch = SUB_Null;
	self.think = dog_run1;
	self.nextthink = time + 0.1;
}

void()	Dog_JumpTouch =
{
	if (self.health <= 0)
		return;
		
	if (other.classname != "monster_dog" &&	// pack dogs whose bboxes brush each other during leaps wind up killing each other
		other.takedamage)
	{	
		if ( vlen(self.velocity) > 300 )
		{
			if (other.classname != "player" || time > self.touch_time)	// fix for landing on the player's head
			{
				if (other.classname == "player")
				{
					self.touch_time = time + 0.2;
				}
				T_Damage(other, self, self, 10 + 10*random(), DMGTYPE_MELEE);	
			}
		}
	}
	Dog_JumpTouchGround();
}

void() dog_airthink =
{
	self.think = dog_airthink;
	self.nextthink = time + 0.1;
	
	// if three seconds pass, assume dog is stuck and jump again
	if (time >= self.lifetime_finished)
	{
		dog_leap1();
		return;
	}
	// we aren't moving, assume leap is over so we don't get stuck
	if (self.origin == self.oldorigin && self.flags & FL_ONGROUND)
	{
		dog_run1();
		return;
	}
	self.oldorigin = self.origin;
}

void() dog_stand1	=[	$stand1,	dog_stand2	] {ai_stand();}
void() dog_stand2	=[	$stand2,	dog_stand3	] {ai_stand();}
void() dog_stand3	=[	$stand3,	dog_stand4	] {ai_stand();}
void() dog_stand4	=[	$stand4,	dog_stand5	] {ai_stand();}
void() dog_stand5	=[	$stand5,	dog_stand6	] {ai_stand();}
void() dog_stand6	=[	$stand6,	dog_stand7	] {ai_stand();}
void() dog_stand7	=[	$stand7,	dog_stand8	] {ai_stand();}
void() dog_stand8	=[	$stand8,	dog_stand9	] {ai_stand();}
void() dog_stand9	=[	$stand9,	dog_stand1	] {ai_stand();}

void() dog_walk1	=[	$walk1 ,	dog_walk2	] {
if (random() < 0.2)
	sound (self, CHAN_VOICE, "dog/idle.wav", 1, ATTN_IDLE);
ai_walk(8);}
void() dog_walk2	=[	$walk2 ,	dog_walk3	] {ai_walk(8);}
void() dog_walk3	=[	$walk3 ,	dog_walk4	] {ai_walk(8);}
void() dog_walk4	=[	$walk4 ,	dog_walk5	] {ai_walk(8);}
void() dog_walk5	=[	$walk5 ,	dog_walk6	] {ai_walk(8);}
void() dog_walk6	=[	$walk6 ,	dog_walk7	] {ai_walk(8);}
void() dog_walk7	=[	$walk7 ,	dog_walk8	] {ai_walk(8);}
void() dog_walk8	=[	$walk8 ,	dog_walk1	] {ai_walk(8);}

void() dog_run1		=[	$run1  ,	dog_run2	] {ai_run(16);nmfast();
	if (random() < 0.2 && time > self.show_hostile)
		sound (self, CHAN_VOICE, "dog/idle.wav", 1, ATTN_IDLE);
}
void() dog_run2		=[	$run2  ,	dog_run3	] {ai_run(32);nmfast();}
void() dog_run3		=[	$run3  ,	dog_run4	] {ai_run(32);nmfast();}
void() dog_run4		=[	$run4  ,	dog_run5	] {ai_run(20);nmfast();}
void() dog_run5		=[	$run5  ,	dog_run6	] {ai_run(64);nmfast();}
void() dog_run6		=[	$run6  ,	dog_run7	] {ai_run(32);nmfast();}
void() dog_run7		=[	$run7  ,	dog_run8	] {ai_run(16);nmfast();}
void() dog_run8		=[	$run8  ,	dog_run9	] {ai_run(32);nmfast();}
void() dog_run9		=[	$run9  ,	dog_run10	] {ai_run(32);nmfast();}
void() dog_run10	=[	$run10  ,	dog_run11	] {ai_run(20);nmfast();}
void() dog_run11	=[	$run11  ,	dog_run12	] {ai_run(64);nmfast();}
void() dog_run12	=[	$run12  ,	dog_run1	] {ai_run(32);nmfast();}

void() dog_atta1	=[	$attack1,	dog_atta2	] {nmfast();ai_charge(10);}
void() dog_atta2	=[	$attack2,	dog_atta3	] {nmfast();ai_charge(10);}
void() dog_atta3	=[	$attack3,	dog_atta4	] {nmfast();ai_charge(10);}
void() dog_atta4	=[	$attack4,	dog_atta5	] {nmfast();
sound (self, CHAN_VOICE, "dog/dattack1.wav", 1, ATTN_NORM);
dog_bite();}
void() dog_atta5	=[	$attack5,	dog_atta6	] {nmfast();ai_charge(10);}
void() dog_atta6	=[	$attack6,	dog_atta7	] {nmfast();ai_charge(10);}
void() dog_atta7	=[	$attack7,	dog_atta8	] {nmfast();ai_charge(10);}
void() dog_atta8	=[	$attack8,	dog_run1	] {nmfast();ai_charge(10);}

void() dog_leap1	=[	$leap1,		dog_leap2	] {nmfast();ai_face();}
void() dog_leap2	=[	$leap2,		dog_leap3	]
{
	nmfast();
	ai_face();
	ai_attack_finished(0.2);
	if (self.flags & FL_ONGROUND || self.velocity_z == 0)
	{	
		makevectors (self.angles);
		self.flags = not(self.flags, FL_ONGROUND);
		self.velocity = v_forward * 300 + '0 0 200';
		self.touch = Dog_JumpTouch;
	}
}
void() dog_leap3	=[	$leap3,		dog_leap4	] {nmfast();}
void() dog_leap4	=[	$leap4,		dog_leap5	] {nmfast();}
void() dog_leap5	=[	$leap5,		dog_leap6	] {nmfast();}
void() dog_leap6	=[	$leap6,		dog_leap7	] {nmfast();}
void() dog_leap7	=[	$leap7,		dog_leap8	] {nmfast();}
void() dog_leap8	=[	$leap8,		dog_leap9	] {nmfast();}
void() dog_leap9	=[	$leap9,		dog_airthink] { 
	self.oldorigin = self.origin;
	self.lifetime_finished = time + 1;
}

void() dog_pain1	=[	$pain1 ,	dog_pain2	] {nmfast();}
void() dog_pain2	=[	$pain2 ,	dog_pain3	] {nmfast();}
void() dog_pain3	=[	$pain3 ,	dog_pain4	] {nmfast();}
void() dog_pain4	=[	$pain4 ,	dog_pain5	] {nmfast();}
void() dog_pain5	=[	$pain5 ,	dog_pain6	] {nmfast();}
void() dog_pain6	=[	$pain6 ,	dog_run1	] {nmfast();}

void() dog_painb1	=[	$painb1 ,	dog_painb2	] {nmfast();}
void() dog_painb2	=[	$painb2 ,	dog_painb3	] {nmfast();}
void() dog_painb3	=[	$painb3 ,	dog_painb4	] {nmfast();ai_pain(4);}
void() dog_painb4	=[	$painb4 ,	dog_painb5	] {nmfast();ai_pain(12);}
void() dog_painb5	=[	$painb5 ,	dog_painb6	] {nmfast();ai_pain(12);}
void() dog_painb6	=[	$painb6 ,	dog_painb7	] {nmfast();ai_pain(2);}
void() dog_painb7	=[	$painb7 ,	dog_painb8	] {nmfast();}
void() dog_painb8	=[	$painb8 ,	dog_painb9	] {nmfast();ai_pain(4);}
void() dog_painb9	=[	$painb9 ,	dog_painb10	] {nmfast();}
void() dog_painb10	=[	$painb10 ,	dog_painb11	] {nmfast();ai_pain(10);}
void() dog_painb11	=[	$painb11 ,	dog_painb12	] {nmfast();}
void() dog_painb12	=[	$painb12 ,	dog_painb13	] {nmfast();}
void() dog_painb13	=[	$painb13 ,	dog_painb14	] {nmfast();}
void() dog_painb14	=[	$painb14 ,	dog_painb15	] {nmfast();}
void() dog_painb15	=[	$painb15 ,	dog_painb16	] {nmfast();}
void() dog_painb16	=[	$painb16 ,	dog_run1	] {nmfast();}

void(entity attacker, float damage) dog_pain =
{
	if (time < self.pain_finished) return;
	sound (self, CHAN_VOICE, "dog/dpain1.wav", 1, ATTN_NORM);

	if (random() > 0.5)
	{
		dog_pain1 ();
		PainFinished(0.5);
	}
	else
	{
		dog_painb1 ();
		PainFinished(1.5);
	}
}

void() dog_die1		=[	$death1,	dog_die2	] {}
void() dog_die2		=[	$death2,	dog_die3	] {}
void() dog_die3		=[	$death3,	dog_die4	] {self.solid = SOLID_NOT; }
void() dog_die4		=[	$death4,	dog_die5	] {}
void() dog_die5		=[	$death5,	dog_die6	] {}
void() dog_die6		=[	$death6,	dog_die7	] {}
void() dog_die7		=[	$death7,	dog_die8	] {}
void() dog_die8		=[	$death8,	dog_die9	] {}
void() dog_die9		=[	$death9,	SUB_Null	] {}

void() dog_dieb1	=[	$deathb1,	dog_dieb2	] {}
void() dog_dieb2	=[	$deathb2,	dog_dieb3	] {}
void() dog_dieb3	=[	$deathb3,	dog_dieb4	] {self.solid = SOLID_NOT;}
void() dog_dieb4	=[	$deathb4,	dog_dieb5	] {}
void() dog_dieb5	=[	$deathb5,	dog_dieb6	] {}
void() dog_dieb6	=[	$deathb6,	dog_dieb7	] {}
void() dog_dieb7	=[	$deathb7,	dog_dieb8	] {}
void() dog_dieb8	=[	$deathb8,	dog_dieb9	] {}
void() dog_dieb9	=[	$deathb9,	SUB_Null	] {}


void() dog_die =
{
// check for gib
	if (self.health < -35)
	{
		Gib ("progs/h_dog.mdl", self.health);
		return;
	}

// regular death
	sound (self, CHAN_VOICE, "dog/ddeath.wav", 1, ATTN_NORM);

	if (random() > 0.5)
		dog_die1 ();
	else
		dog_dieb1 ();
}

//============================================================================

/*
==============
CheckDogMelee

Returns TRUE if a melee attack would hit right now
==============
*/
float()	CheckDogMelee =
{
	if (enemy_range == RANGE_MELEE && z_overlap(self.enemy))
	{	// FIXME: check canreach
		self.attack_state = AS_MELEE;
		return TRUE;
	}
	return FALSE;
}

/*
==============
CheckDogJump
==============
*/
float()	CheckDogJump =
{
	local	vector	dist;
	local	float	d;

	if (self.origin_z + self.mins_z > self.enemy.origin_z + self.enemy.mins_z
	+ 0.75 * self.enemy.size_z)
		return FALSE;
		
	if (self.origin_z + self.maxs_z < self.enemy.origin_z + self.enemy.mins_z
	+ 0.25 * self.enemy.size_z)
		return FALSE;
		
	dist = self.enemy.origin - self.origin;
	dist_z = 0;
	
	d = vlen(dist);
	
	if (d < 80)
		return FALSE;
		
	if (d > 150)
		return FALSE;
		
	return TRUE;
}

float()	DogCheckAttack =
{
// if close enough for slashing, go for it
	if (CheckDogMelee ())
	{
		self.attack_state = AS_MELEE;
		return TRUE;
	}
	
	if (CheckDogJump ())
	{
		self.attack_state = AS_MISSILE;
		return TRUE;
	}
	
	return FALSE;
}


//===========================================================================


void() monster_dog_spawn =
{
	self.classname = "monster_dog";
		
	self.solid = SOLID_SLIDEBOX;
	//self.movetype = MOVETYPE_STEP;

	setmodel (self, "progs/dog.mdl");

	setsize (self, '-32 -32 -24', '32 32 40');
	self.health = 35;
	self.customflags |= CFL_MELEEONLY;

	self.th_stand = dog_stand1;
	self.th_walk = dog_walk1;
	self.th_run = dog_run1;
	self.th_pain = dog_pain;
	self.th_die = dog_die;
	self.th_melee = dog_atta1;
	self.th_missile = dog_leap1;
	self.th_checkattack = DogCheckAttack;

	if (self.deathtype == string_null)
		self.deathtype = "was mauled by a Rottweiler";

	nmspeed(0.07);

	walkmonster_start();
}

void() monster_dog_spawner = {mon_spawner_use(monster_dog_spawn);}

/*QUAKED monster_dog (1 0 0) (-32 -32 -24) (32 32 40) AMBUSH ? ? ? TRIGGERED NOTFOG NOTELEFRAG INSTAWAKE
Dog (Rottweiler), 25 health points.

Flags:
"ambush" only wake up on seeing the player, not another monster getting angry
"Triggered"	will not spawn until triggered - triggering again will wake him up. Set 'count' to make this a multi-use spawner.
"NoTfog" 	supress teleport glitter when spawned with 'triggered'
"NoTelefrag" will silently fail to spawn if doing so would telefrag an existing monster. will try again automatically 2x/second until it succeeds.
"Instawake" spawn angry at activator

Keys:
"target" entity to trigger when killed
"targetname" entity name
"movedir" set to a velocity to make the monster jump on awakening
*/
/*FGD
@PointClass base(Monster) size(-32 -32 -24, 32 32 40) model({ "path": ":progs/dog.mdl" }) = monster_dog : "Rottweiler" []
*/
void() monster_dog =
{
	if (!SUB_ShouldSpawn()) return;
	if (nomonster()) return;
	if (deathmatch)
	{
		remove(self);
		return;
	}
	precache_model ("progs/h_dog.mdl");
	precache_model ("progs/dog.mdl");

	precache_sound ("dog/dattack1.wav");
	precache_sound ("dog/ddeath.wav");
	precache_sound ("dog/dpain1.wav");
	precache_sound ("dog/dsight.wav");
	precache_sound ("dog/idle.wav");

	self.health = 35;
	setsize (self, '-32 -32 -24', '32 32 40');
	if ( monster_spawnsetup( monster_dog_spawner ) ) return;

	addmonster(1);
	monster_dog_spawn();
}