Migrate SRC5 to component

.github/workflows/test.yml

@@ -18,7 +18,7 @@ jobs:
     - uses: actions/checkout@v3
     - uses: software-mansion/setup-scarb@v1
       with:
-        scarb-version: "0.7.0"
+        scarb-version: "2.3.0-rc0"
     - name: Markdown lint
       uses: DavidAnson/markdownlint-cli2-action@5b7c9f74fec47e6b15667b2cc23c63dff11e449e # v9
       with:

Scarb.toml

@@ -1,7 +1,7 @@
 [package]
 name = "openzeppelin"
 version = "0.7.0"
-cairo-version = "2.2.0"
+cairo-version = "2.3.0-rc0"
 authors = ["OpenZeppelin Community <maintainers@openzeppelin.org>"]
 description = "OpenZeppelin Contracts written in Cairo for StarkNet, a decentralized ZK Rollup"
 documentation = "https://docs.openzeppelin.com/contracts-cairo"
@@ -11,11 +11,14 @@ license-file = "LICENSE"
 keywords = ["openzeppelin", "starknet", "cairo", "contracts", "security", "standards"]
 
 [dependencies]
-starknet = ">=2.2.0"
+starknet = "=2.3.0-rc0"
 
 [lib]
 
 [[target.starknet-contract]]
 allowed-libfuncs-list.name = "experimental"
 sierra = true
 casm = false
+
+[tool.fmt]
+sort-module-level-items = true

docs/modules/ROOT/pages/api/introspection.adoc

@@ -50,10 +50,10 @@ on how to compute this ID.
 use openzeppelin::introspection::src5::SRC5;
 ```
 
-SRC5 contract implementation extending xref:ISRC5[`ISRC5`].
+SRC5 component extending xref:ISRC5[`ISRC5`].
 
 [.contract-index]
-.External Functions
+.Embeddable Implementations
 --
 .SRC5Impl
 
@@ -69,8 +69,8 @@ SRC5 contract implementation extending xref:ISRC5[`ISRC5`].
 * xref:#SRC5-deregister_interface[`++deregister_interface(self, interface_id)++`]
 --
 
-[#SRC5-External-Functions]
-==== External Functions
+[#SRC5-Embeddable-Implementations-Functions]
+==== Embeddable Implementations Functions
 
 [.contract-item]
 [[SRC5-supports_interface]]

docs/modules/ROOT/pages/introspection.adoc

@@ -35,24 +35,37 @@ extended function selectors. There are tools such as {src5-rs} that can help wit
 
 === Registering interfaces
 
-For a contract to declare its support for a given interface, the contract should import the SRC5 module and
-register its support. It's recommended to register interface support upon contract deployment through a constructor
-either directly or indirectly (as an initializer) like this:
+For a contract to declare its support for a given interface, we recommend using the the SRC5 component to do it upon contract deployment through a constructor either directly or indirectly (as an initializer) like this:
 
 [,javascript]
 ----
 #[starknet::contract]
 mod MyContract {
     use openzeppelin::account::interface;
-    use openzeppelin::introspection::src5::SRC5;
+    use openzeppelin::introspection::src5::SRC5 as src5_component;
+
+    component!(path: src5_component, storage: src5, event: SRC5Event);
+
+    #[abi(embed_v0)]
+    impl SRC5Impl = src5_component::SRC5Impl<ContractState>;
+    impl InternalImpl = src5_component::InternalImpl<ContractState>;
 
     #[storage]
-    struct Storage {}
+    struct Storage {
+        #[substorage(v0)]
+        src5: src5_component::Storage
+    }
+
+    #[event]
+    #[derive(Drop, starknet::Event)]
+    enum Event {
+        SRC5Event: src5_component::Event
+    }
 
     #[constructor]
     fn constructor(ref self: ContractState) {
-        let mut unsafe_state = SRC5::unsafe_new_contract_state();
-        SRC5::InternalImpl::register_interface(ref unsafe_state, interface::ISRC6_ID);
+        // Register the contract's support for the ISRC6 interface
+        self.src5.register_interface(interface::ISRC6_ID);
     }
 
     (...)
@@ -70,7 +83,6 @@ mod MyContract {
     use openzeppelin::account::interface;
     use openzeppelin::introspection::interface::ISRC5DispatcherTrait;
     use openzeppelin::introspection::interface::ISRC5Dispatcher;
-    use openzeppelin::introspection::src5::SRC5;
     use starknet::ContractAddress;
 
     #[storage]

src/access/accesscontrol/accesscontrol.cairo

@@ -4,17 +4,24 @@
 #[starknet::contract]
 mod AccessControl {
     use openzeppelin::access::accesscontrol::interface;
-    use openzeppelin::introspection::interface::ISRC5;
-    use openzeppelin::introspection::interface::ISRC5Camel;
-    use openzeppelin::introspection::src5::SRC5;
-    use openzeppelin::introspection::src5::unsafe_state as src5_state;
+    use openzeppelin::introspection::src5::SRC5 as src5_component;
     use starknet::ContractAddress;
     use starknet::get_caller_address;
 
+    component!(path: src5_component, storage: src5, event: SRC5Event);
+
+    #[abi(embed_v0)]
+    impl SRC5Impl = src5_component::SRC5Impl<ContractState>;
+    #[abi(embed_v0)]
+    impl SRC5CamelImpl = src5_component::SRC5CamelImpl<ContractState>;
+    impl SRC5InternalImpl = src5_component::InternalImpl<ContractState>;
+
     #[storage]
     struct Storage {
         AccessControl_role_admin: LegacyMap<felt252, felt252>,
         AccessControl_role_member: LegacyMap<(felt252, ContractAddress), bool>,
+        #[substorage(v0)]
+        src5: src5_component::Storage
     }
 
     #[event]
@@ -23,6 +30,7 @@ mod AccessControl {
         RoleGranted: RoleGranted,
         RoleRevoked: RoleRevoked,
         RoleAdminChanged: RoleAdminChanged,
+        SRC5Event: src5_component::Event
     }
 
     /// Emitted when `account` is granted `role`.
@@ -64,20 +72,6 @@ mod AccessControl {
         const MISSING_ROLE: felt252 = 'Caller is missing role';
     }
 
-    #[external(v0)]
-    impl SRC5Impl of ISRC5<ContractState> {
-        fn supports_interface(self: @ContractState, interface_id: felt252) -> bool {
-            SRC5::SRC5Impl::supports_interface(@src5_state(), interface_id)
-        }
-    }
-
-    #[external(v0)]
-    impl SRC5CamelImpl of ISRC5Camel<ContractState> {
-        fn supportsInterface(self: @ContractState, interfaceId: felt252) -> bool {
-            SRC5::SRC5CamelImpl::supportsInterface(@src5_state(), interfaceId)
-        }
-    }
-
     #[external(v0)]
     impl AccessControlImpl of interface::IAccessControl<ContractState> {
         fn has_role(self: @ContractState, role: felt252, account: ContractAddress) -> bool {
@@ -137,8 +131,7 @@ mod AccessControl {
     #[generate_trait]
     impl InternalImpl of InternalTrait {
         fn initializer(ref self: ContractState) {
-            let mut unsafe_state = src5_state();
-            SRC5::InternalImpl::register_interface(ref unsafe_state, interface::IACCESSCONTROL_ID);
+            self.src5.register_interface(interface::IACCESSCONTROL_ID);
         }
 
         fn assert_only_role(self: @ContractState, role: felt252) {

src/account/account.cairo

@@ -14,12 +14,8 @@ trait PublicKeyCamelTrait<TState> {
 #[starknet::contract]
 mod Account {
     use ecdsa::check_ecdsa_signature;
-
     use openzeppelin::account::interface;
-    use openzeppelin::introspection::interface::ISRC5;
-    use openzeppelin::introspection::interface::ISRC5Camel;
-    use openzeppelin::introspection::src5::SRC5;
-    use openzeppelin::introspection::src5::unsafe_state as src5_state;
+    use openzeppelin::introspection::src5::SRC5 as src5_component;
     use starknet::account::Call;
     use starknet::get_caller_address;
     use starknet::get_contract_address;
@@ -29,16 +25,27 @@ mod Account {
     // 2**128 + TRANSACTION_VERSION
     const QUERY_VERSION: felt252 = 0x100000000000000000000000000000001;
 
+    component!(path: src5_component, storage: src5, event: SRC5Event);
+
+    #[abi(embed_v0)]
+    impl SRC5Impl = src5_component::SRC5Impl<ContractState>;
+    #[abi(embed_v0)]
+    impl SRC5CamelImpl = src5_component::SRC5CamelImpl<ContractState>;
+    impl SRC5InternalImpl = src5_component::InternalImpl<ContractState>;
+
     #[storage]
     struct Storage {
-        Account_public_key: felt252
+        Account_public_key: felt252,
+        #[substorage(v0)]
+        src5: src5_component::Storage
     }
 
     #[event]
     #[derive(Drop, starknet::Event)]
     enum Event {
         OwnerAdded: OwnerAdded,
         OwnerRemoved: OwnerRemoved,
+        SRC5Event: src5_component::Event
     }
 
     #[derive(Drop, starknet::Event)]
@@ -116,20 +123,6 @@ mod Account {
         }
     }
 
-    #[external(v0)]
-    impl SRC5Impl of ISRC5<ContractState> {
-        fn supports_interface(self: @ContractState, interface_id: felt252) -> bool {
-            SRC5::SRC5Impl::supports_interface(@src5_state(), interface_id)
-        }
-    }
-
-    #[external(v0)]
-    impl SRC5CamelImpl of ISRC5Camel<ContractState> {
-        fn supportsInterface(self: @ContractState, interfaceId: felt252) -> bool {
-            SRC5::SRC5CamelImpl::supportsInterface(@src5_state(), interfaceId)
-        }
-    }
-
     #[external(v0)]
     impl PublicKeyImpl of super::PublicKeyTrait<ContractState> {
         fn get_public_key(self: @ContractState) -> felt252 {
@@ -171,8 +164,7 @@ mod Account {
     #[generate_trait]
     impl InternalImpl of InternalTrait {
         fn initializer(ref self: ContractState, _public_key: felt252) {
-            let mut unsafe_state = src5_state();
-            SRC5::InternalImpl::register_interface(ref unsafe_state, interface::ISRC6_ID);
+            self.src5.register_interface(interface::ISRC6_ID);
             self._set_public_key(_public_key);
         }
 
@@ -204,14 +196,12 @@ mod Account {
         }
     }
 
-    #[internal]
     fn assert_only_self() {
         let caller = get_caller_address();
         let self = get_contract_address();
         assert(self == caller, Errors::UNAUTHORIZED);
     }
 
-    #[private]
     fn _execute_calls(mut calls: Array<Call>) -> Array<Span<felt252>> {
         let mut res = ArrayTrait::new();
         loop {
@@ -220,15 +210,12 @@ mod Account {
                     let _res = _execute_single_call(call);
                     res.append(_res);
                 },
-                Option::None(_) => {
-                    break ();
-                },
+                Option::None(_) => { break (); },
             };
         };
         res
     }
 
-    #[private]
     fn _execute_single_call(call: Call) -> Span<felt252> {
         let Call{to, selector, calldata } = call;
         starknet::call_contract_syscall(to, selector, calldata.span()).unwrap()

src/introspection/src5.cairo

@@ -1,7 +1,10 @@
 // SPDX-License-Identifier: MIT
 // OpenZeppelin Contracts for Cairo v0.7.0 (introspection/src5.cairo)
-
-#[starknet::contract]
+///
+/// # SRC5 Component
+///
+/// The SRC5 component allows contracts to expose the interfaces they implement.
+#[starknet::component]
 mod SRC5 {
     use openzeppelin::introspection::interface;
 
@@ -14,37 +17,43 @@ mod SRC5 {
         const INVALID_ID: felt252 = 'SRC5: invalid id';
     }
 
-    #[external(v0)]
-    impl SRC5Impl of interface::ISRC5<ContractState> {
-        fn supports_interface(self: @ContractState, interface_id: felt252) -> bool {
+    #[embeddable_as(SRC5Impl)]
+    impl SRC5<
+        TContractState, +HasComponent<TContractState>
+    > of interface::ISRC5<ComponentState<TContractState>> {
+        /// Returns whether the contract implements the given interface.
+        fn supports_interface(
+            self: @ComponentState<TContractState>, interface_id: felt252
+        ) -> bool {
             if interface_id == interface::ISRC5_ID {
                 return true;
             }
             self.SRC5_supported_interfaces.read(interface_id)
         }
     }
 
-    #[external(v0)]
-    impl SRC5CamelImpl of interface::ISRC5Camel<ContractState> {
-        fn supportsInterface(self: @ContractState, interfaceId: felt252) -> bool {
-            SRC5Impl::supports_interface(self, interfaceId)
+    #[embeddable_as(SRC5CamelImpl)]
+    impl SRC5Camel<
+        TContractState, +HasComponent<TContractState>
+    > of interface::ISRC5Camel<ComponentState<TContractState>> {
+        fn supportsInterface(self: @ComponentState<TContractState>, interfaceId: felt252) -> bool {
+            self.supports_interface(interfaceId)
         }
     }
 
     #[generate_trait]
-    impl InternalImpl of InternalTrait {
-        fn register_interface(ref self: ContractState, interface_id: felt252) {
+    impl InternalImpl<
+        TContractState, +HasComponent<TContractState>
+    > of InternalTrait<TContractState> {
+        /// Registers the given interface as supported by the contract.
+        fn register_interface(ref self: ComponentState<TContractState>, interface_id: felt252) {
             self.SRC5_supported_interfaces.write(interface_id, true);
         }
 
-        fn deregister_interface(ref self: ContractState, interface_id: felt252) {
+        /// Deregisters the given interface as supported by the contract.
+        fn deregister_interface(ref self: ComponentState<TContractState>, interface_id: felt252) {
             assert(interface_id != interface::ISRC5_ID, Errors::INVALID_ID);
             self.SRC5_supported_interfaces.write(interface_id, false);
         }
     }
 }
-
-#[inline(always)]
-fn unsafe_state() -> SRC5::ContractState {
-    SRC5::unsafe_new_contract_state()
-}

src/lib.cairo

@@ -2,9 +2,8 @@ mod access;
 mod account;
 mod introspection;
 mod security;
+#[cfg(test)]
+mod tests;
 mod token;
 mod upgrades;
 mod utils;
-
-#[cfg(test)]
-mod tests;

src/tests/access/test_dual_accesscontrol.cairo

@@ -1,16 +1,16 @@
 use openzeppelin::access::accesscontrol::DEFAULT_ADMIN_ROLE;
+use openzeppelin::access::accesscontrol::dual_accesscontrol::DualCaseAccessControl;
+use openzeppelin::access::accesscontrol::dual_accesscontrol::DualCaseAccessControlTrait;
 use openzeppelin::access::accesscontrol::interface::IACCESSCONTROL_ID;
-use openzeppelin::access::accesscontrol::interface::IAccessControlDispatcherTrait;
-use openzeppelin::access::accesscontrol::interface::IAccessControlDispatcher;
-use openzeppelin::access::accesscontrol::interface::IAccessControlCamelDispatcherTrait;
 use openzeppelin::access::accesscontrol::interface::IAccessControlCamelDispatcher;
-use openzeppelin::access::accesscontrol::dual_accesscontrol::DualCaseAccessControlTrait;
-use openzeppelin::access::accesscontrol::dual_accesscontrol::DualCaseAccessControl;
-use openzeppelin::tests::mocks::snake_accesscontrol_mock::SnakeAccessControlMock;
-use openzeppelin::tests::mocks::camel_accesscontrol_mock::CamelAccessControlMock;
-use openzeppelin::tests::mocks::accesscontrol_panic_mock::SnakeAccessControlPanicMock;
+use openzeppelin::access::accesscontrol::interface::IAccessControlCamelDispatcherTrait;
+use openzeppelin::access::accesscontrol::interface::IAccessControlDispatcher;
+use openzeppelin::access::accesscontrol::interface::IAccessControlDispatcherTrait;
 use openzeppelin::tests::mocks::accesscontrol_panic_mock::CamelAccessControlPanicMock;
+use openzeppelin::tests::mocks::accesscontrol_panic_mock::SnakeAccessControlPanicMock;
+use openzeppelin::tests::mocks::camel_accesscontrol_mock::CamelAccessControlMock;
 use openzeppelin::tests::mocks::non_implementing_mock::NonImplementingMock;
+use openzeppelin::tests::mocks::snake_accesscontrol_mock::SnakeAccessControlMock;
 use openzeppelin::tests::utils::constants::{ADMIN, AUTHORIZED, ROLE};
 use openzeppelin::tests::utils;
 use openzeppelin::utils::serde::SerializedAppend;