build.gradle

//file:noinspection GroovyAssignabilityCheck
plugins {
	id 'fabric-loom' version '1.4-SNAPSHOT'
	id 'maven-publish'
	id 'com.modrinth.minotaur' version '2.+'
	id "org.jetbrains.kotlin.jvm" version "${kotlin_version}"
}

archivesBaseName = project.archives_base_name
version = project.mod_version
group = project.maven_group

repositories {
	maven {
		url "https://maven.shedaniel.me"
	}
	maven {
		url "https://maven.terraformersmc.com/releases"
	}
	maven {
		url "https://jitpack.io"
	}
}

dependencies {
	// To change the versions see the gradle.properties file
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
	modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

	// Fabric API. This is technically optional, but you probably want it anyway.
	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

	modImplementation("net.fabricmc:fabric-language-kotlin:${project.fabric_kotlin_version}")

	// PSA: Some older mods, compiled on Loom 0.2.1, might have outdated Maven POMs.
	// You may need to force-disable transitiveness on them.
	modApi("me.shedaniel.cloth:cloth-config-fabric:${project.cloth_config_version}") {
		exclude(group: "net.fabricmc.fabric-api")
	}

	modApi("com.terraformersmc:modmenu:${project.modmenu_version}")

	// Calculator-lib by Octocynth from Jitpack
	def calcLib = "com.github.octocynth:calculator-lib:8c69c67b0e"
	implementation calcLib
	include calcLib

	var brigadierX = "com.github.taskeren:brigadierX:${brigadier_x_version}"
	implementation brigadierX
	include brigadierX
}

base {
	archivesName = project.archives_base_name
}

processResources {
	inputs.property "version", project.version

	filesMatching("fabric.mod.json") {
		expand "version": project.version
	}
}

tasks.withType(JavaCompile).configureEach {
	// ensure that the encoding is set to UTF-8, no matter what the system default is
	// this fixes some edge cases with special characters not displaying correctly
	// see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
	// If Javadoc is generated, this must be specified in that task too.
	it.options.encoding = "UTF-8"

	// Minecraft 1.18 upwards uses Java 17
	it.options.release = 17
}

java {
	// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
	// if it is present.
	// If you remove this line, sources will not be generated.
	withSourcesJar()

	sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17
}

jar {
	from("LICENSE") {
		rename { "${it}_${project.archivesBaseName}"}
	}
}

// configure the maven publication
publishing {
	publications {
		mavenJava(MavenPublication) {
			// add all the jars that should be included when publishing to maven
			artifact(remapJar) {
				builtBy remapJar
			}
			artifact(sourcesJar) {
				builtBy remapSourcesJar
			}
		}
	}

	// See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
	repositories {
		// Add repositories to publish to here.
		// Notice: This block does NOT have the same function as the block in the top level.
		// The repositories here will be used for publishing your artifact, not for
		// retrieving dependencies.
	}
}

// Need to specify the Environment Variable!
var modrinthToken = System.getenv("ModrinthToken")
if(modrinthToken != null) {
    modrinth {
    	token = "${modrinthToken}"
    	projectId = "minequery"
    	versionNumber = "${project.version}"
    	versionType = "beta"
    	uploadFile = remapJar
    	gameVersions = ["${project.for_minecraft_version}"]
    	loaders = ["fabric"]
    	dependencies {
    		required.project "fabric-api"
    		required.project "cloth-config"
    		optional.project "modmenu"
    	}
    }
}