Memory leak in Plugin::Filter [rt.cpan.org #62045]

[atoomic]

Migrated from rt.cpan.org#62045 (status was 'open')

Requestors:

• hiratara@cpan.org

Attachments:

• for_tt-2.22.patch

From hiratara@cpan.org on 2010-10-11 08:42:41:

Hi. I found a memory leak and reported. I used following simple script
to find the problem.

use strict;
use warnings;
use Template;

for my $l (1 .. 1000) {
	my $tpl = Template->new(PLUGIN_BASE  => 'test');
	$tpl->context->plugin('simple', []);

	warn `ps -o rss= -p $$` if $l % 10 == 0;
}

I read https://rt.cpan.org/Public/Bug/Display.html?id=46691 and
understood my patch had been reverted.

So I wrote another one. How is this patch? All tests in the t/ directory
are passed and there are no memory leaks.

Since I thought only the context should have the filter's reference, I
weakened another references.

From pepl@cpan.org on 2011-12-05 10:45:57:

I also experience leaks with that patch. Only the original one ('weaken
$this') works for me.

[atoomic]

I can reproduce this memory leak using a slightly modified version of yours
but Template::Plugin::Simple is not shipped

the leak is coming from $self->install_filter($name) called multiple times

#!/usr/bin/env perl

print $$ . "\n";

use strict;
use warnings;
use Template;
use Template::Plugin::Simple;

my $c = 0;
while (1) {
	++$c;
	
	my $tpl = Template->new(PLUGIN_BASE  => 'test');
	$tpl->context->plugin('Simple', []);

	
	if ( ($c % 10) == 0 ) {
		print qx{grep -i VMRSS /proc/$$/status} ."\n";	
		$c = 0;
	}
	
}

1;
__END__

[atoomic]

was able to detect the circular reference using Devel::Cycle

use Template;
use Template::Plugin::Simple;

use Devel::Cycle;

my $tpl = Template->new(PLUGIN_BASE  => 'test');
$tpl->context->plugin('Simple', []);

find_cycle( $tpl );

Cycle (1):
	     $Template::A->{'SERVICE'} => \%Template::Service::B
	$Template::Service::B->{'CONTEXT'} => \%Template::Context::C
	$Template::Context::C->{'LOAD_FILTERS'} => \@D
	                       $D->[0] => \%Template::Filters::E
	$Template::Filters::E->{'FILTERS'} => \%F
	                $F->{'simple'} => \@G
	                       $G->[0] => \&H
	             $H variable $this => \$I
	                           $$I => \%Template::Plugin::Simple::J
	$Template::Plugin::Simple::J->{'_CONTEXT'} => \%Template::Context::C

The leak is coming from Template::Plugin::Filter itself when setting the _CONTEXT...

A simple fix would be

diff --git a/lib/Template/Plugin/Filter.pm b/lib/Template/Plugin/Filter.pm
index 186c7738..c7b245a7 100644
--- a/lib/Template/Plugin/Filter.pm
+++ b/lib/Template/Plugin/Filter.pm
@@ -49,6 +49,9 @@ sub new {
         _CONFIG  => $config,
     }, $class;

+
+    weaken( $self->{_CONTEXT} );
+
     return $self->init($config)
         || $class->error($self->error());
 }

[toddr]

This has been fixed with #201