refactor: bundle types for non-APF compiler-cli package and localize/tools entry-point

packages/compiler-cli/BUILD.bazel

@@ -1,19 +1,46 @@
-load("//tools:defaults.bzl", "api_golden_test", "pkg_npm", "ts_config", "ts_library")
 load("@npm//@bazel/esbuild:index.bzl", "esbuild", "esbuild_config")
-load("//tools:extract_typings_rule.bzl", "extract_typings")
+load("//tools:defaults.bzl", "api_golden_test", "pkg_npm", "ts_config", "ts_library")
+load("//tools:types_bundle_artifact.bzl", "generate_types_bundle_artifact")
 
 # Load ng_perf_flag explicitly from ng_perf.bzl as it's private API, and not exposed to other
 # consumers of @angular/bazel.
 load("//packages/bazel/src:ng_perf.bzl", "ng_perf_flag")
 
 package(default_visibility = ["//visibility:public"])
 
-PUBLIC_TARGETS = [
-    ":compiler-cli",
-    "//packages/compiler-cli/private",
-    "//packages/compiler-cli/ngcc",
-    "//packages/compiler-cli/linker",
-    "//packages/compiler-cli/linker/babel",
+PUBLIC_ENTRY_POINTS = [
+    {
+        "file": "//packages/compiler-cli:index.ts",
+        "target": "//packages/compiler-cli",
+    },
+    {
+        "file": "//packages/compiler-cli/ngcc:index.ts",
+        "target": "//packages/compiler-cli/ngcc",
+    },
+    {
+        "file": "//packages/compiler-cli/linker:index.ts",
+        "target": "//packages/compiler-cli/linker",
+    },
+    {
+        "file": "//packages/compiler-cli/linker/babel:index.ts",
+        "target": "//packages/compiler-cli/linker/babel",
+    },
+    {
+        "file": "//packages/compiler-cli/private:bazel.ts",
+        "target": "//packages/compiler-cli/private",
+    },
+    {
+        "file": "//packages/compiler-cli/private:localize.ts",
+        "target": "//packages/compiler-cli/private",
+    },
+    {
+        "file": "//packages/compiler-cli/private:migrations.ts",
+        "target": "//packages/compiler-cli/private",
+    },
+    {
+        "file": "//packages/compiler-cli/private:tooling.ts",
+        "target": "//packages/compiler-cli/private",
+    },
 ]
 
 esbuild_config(
@@ -24,18 +51,10 @@ esbuild_config(
 esbuild(
     name = "bundles",
     config = ":esbuild_config",
-    entry_points = [
-        ":index.ts",
+    entry_points = [e["file"] for e in PUBLIC_ENTRY_POINTS] + [
         "//packages/compiler-cli:src/bin/ngc.ts",
         "//packages/compiler-cli/ngcc:main-ngcc.ts",
-        "//packages/compiler-cli/ngcc:index.ts",
         "//packages/compiler-cli:src/bin/ng_xi18n.ts",
-        "//packages/compiler-cli/linker:index.ts",
-        "//packages/compiler-cli/linker/babel:index.ts",
-        "//packages/compiler-cli/private:bazel.ts",
-        "//packages/compiler-cli/private:localize.ts",
-        "//packages/compiler-cli/private:migrations.ts",
-        "//packages/compiler-cli/private:tooling.ts",
         "//packages/compiler-cli/ngcc:src/locking/lock_file_with_child_process/ngcc_lock_unlocker.ts",
         "//packages/compiler-cli/ngcc:src/execution/cluster/ngcc_cluster_worker.ts",
     ],
@@ -59,7 +78,7 @@ esbuild(
     platform = "node",
     splitting = True,
     target = "node12",
-    deps = PUBLIC_TARGETS,
+    deps = depset([e["target"] for e in PUBLIC_ENTRY_POINTS]).to_list(),
 )
 
 ts_config(
@@ -116,16 +135,17 @@ ts_library(
     ],
 )
 
-extract_typings(
-    name = "api_type_definitions",
-    deps = PUBLIC_TARGETS,
+generate_types_bundle_artifact(
+    name = "types_tree_artifact",
+    entry_points = PUBLIC_ENTRY_POINTS,
 )
 
 pkg_npm(
     name = "npm_package",
     srcs = [
         "package.json",
     ],
+    nested_packages = [":types_tree_artifact"],
     tags = [
         "release-with-framework",
     ],
@@ -136,38 +156,37 @@ pkg_npm(
         "//packages/compiler-cli/integrationtest:__pkg__",
     ],
     deps = [
-        ":api_type_definitions",
         ":bundles",
     ],
 )
 
 api_golden_test(
     name = "error_code_api",
     data = [
-        ":npm_package",
         "//goldens:public-api",
+        "//packages/compiler-cli/src/ngtsc/diagnostics",
     ],
-    entry_point = "angular/packages/compiler-cli/npm_package/src/ngtsc/diagnostics/src/error_code.d.ts",
+    entry_point = "angular/packages/compiler-cli/src/ngtsc/diagnostics/src/error_code.d.ts",
     golden = "angular/goldens/public-api/compiler-cli/error_code.md",
 )
 
 api_golden_test(
     name = "extended_template_diagnostic_name_api",
     data = [
-        ":npm_package",
         "//goldens:public-api",
+        "//packages/compiler-cli/src/ngtsc/diagnostics",
     ],
-    entry_point = "angular/packages/compiler-cli/npm_package/src/ngtsc/diagnostics/src/extended_template_diagnostic_name.d.ts",
+    entry_point = "angular/packages/compiler-cli/src/ngtsc/diagnostics/src/extended_template_diagnostic_name.d.ts",
     golden = "angular/goldens/public-api/compiler-cli/extended_template_diagnostic_name.md",
 )
 
 api_golden_test(
     name = "compiler_options_api",
     data = [
-        ":npm_package",
         "//goldens:public-api",
+        "//packages/compiler-cli/src/ngtsc/core:api",
     ],
-    entry_point = "angular/packages/compiler-cli/npm_package/src/ngtsc/core/api/src/public_options.d.ts",
+    entry_point = "angular/packages/compiler-cli/src/ngtsc/core/api/src/public_options.d.ts",
     golden = "angular/goldens/public-api/compiler-cli/compiler_options.md",
 )
 

packages/localize/tools/BUILD.bazel

@@ -1,6 +1,6 @@
 load("@npm//@bazel/esbuild:index.bzl", "esbuild", "esbuild_config")
 load("//tools:defaults.bzl", "pkg_npm", "ts_library")
-load("//tools:extract_typings_rule.bzl", "extract_typings")
+load("//tools:types_bundle_artifact.bzl", "generate_types_bundle_artifact")
 
 ts_library(
     name = "tools",
@@ -55,17 +55,18 @@ esbuild(
     ],
 )
 
-extract_typings(
-    name = "api_type_definitions",
-    deps = [":tools"],
+generate_types_bundle_artifact(
+    name = "bundled_type_tree_artifact",
+    entry_points = [{
+        "file": "//packages/localize/tools:index.ts",
+        "target": "//packages/localize/tools",
+    }],
 )
 
 pkg_npm(
     name = "npm_package",
     srcs = ["README.md"],
+    nested_packages = [":bundled_type_tree_artifact"],
     visibility = ["//packages/localize:__pkg__"],
-    deps = [
-        ":api_type_definitions",
-        ":bundles",
-    ],
+    deps = [":bundles"],
 )

tools/types_bundle_artifact.bzl

@@ -0,0 +1,43 @@
+load("@aspect_bazel_lib//lib:copy_to_directory.bzl", "copy_to_directory")
+load("//packages/bazel:index.bzl", "types_bundle")
+
+def generate_types_bundle_artifact(name, entry_points):
+    """Generates a tree artfiact containing the bundled public entry-point type definitions.
+
+    Bundled entry-points need to be put into a tree artifact to avoid collisions with
+    the original type outputs.
+
+    Args:
+        name: Name of the tree artifact.
+        entry_points: List of entry-points. Entry-points are expected be directionaries
+                      with properties for `file` (the `.ts` file as label) and `target`.
+      """
+    type_bundle_targets = []
+    temp_directory_name = "%s_temp" % name
+
+    for entry_point in entry_points:
+        entry_point_file_label = Label(entry_point["file"])
+        entry_point_path = "%s/%s" % (entry_point_file_label.package, entry_point_file_label.name)
+
+        # Use the `.d.ts` output file as entry-point and relativize it to the current package.
+        entry_point_path = entry_point_path.replace(".ts", ".d.ts")[len(native.package_name()) + 1:]
+
+        target_name = "dts_bundle_%s" % (entry_point_path.replace("/", "_"))
+        type_bundle_targets.append(target_name)
+
+        types_bundle(
+            name = target_name,
+            output_name = "%s/%s" % (temp_directory_name, entry_point_path),
+            entry_point = entry_point_path,
+            deps = [entry_point["target"]],
+        )
+
+    copy_to_directory(
+        name = name,
+        srcs = type_bundle_targets,
+        replace_prefixes = {
+            # Remove the special prefix we add to all type bundles. Bundles are prefixed
+            # that way to avoid collisions with the actual `.d.ts` entry-points.
+            temp_directory_name: "",
+        },
+    )