Problems with sequences in reactions? (to reactive?)

[ZabelTech]

Hi,

let's say my app db is a nested dict where the root-keys are string ids.
(e.g {"1" {:a "a" :b "b"} ...}
When i put a reaction on a collection of the keys ( I tried lazy-seq,list,array,set)
that reaction is triggered when I do updates on the values.
I expected it not to, because the value of the collection has not changed.
Are you aware of this and is this expected behavior?
Otherwise i'm happy ton come up with a complete example.
(For now i serialize the collection of keys into edn, put a reaction on that and after the deref i do read-string. This is obviously horrible, but works as expected!)

[yatesco]

If you are doing (reaction (vals @db)) then the entire chunk of code inside the reaction will re-evaluate when anything in @db changes. Anything that subscribes to this reaction won't be re-run because the 'resolution' of that reaction won't have changed.

It sounds like you want to chain reactions, so a reaction for just the keys which is really cheap then another subscription onto that reaction which does the expensive processing when the (cheap) 'keys subscription' changes.

I often have subscriptions like:

(register-sub
  :page-1/cursor
  (fn [db]
    (reaction (-> db deref :my :nested :path)))

(register-sub
  :page-1/interesting-stream
  (fn [_]
    (let [state (subscribe [:page-1/cursor])]
      (reaction (some-expensive-process @state))))

If I want to do any searching then I might have an intermediary subscription to filter etc. But only if the processing is expensive - I find it very easy to 'early optimise' this stuff so I restrain myself to in-line processing until it proves a hotspot in which case I only memoise via a subscription.

The code to calculate the subscription for page-1/cursor' is going to happen whenever _anything_ changesdb. However,page-1/interesting-streamwill only be called whenever the chunk ofdb` I am actually interested in changes.

Maybe you could post some sample code...

(Mike - not sure of the etiquette of community answering github issues or the use of github issues as a support tool so apologies if I have overstepped ;-))

[ZabelTech]

Hi,

thanks for your fast response. I my case i want to avoid re-rendering the whole collection when an Item changes. Thats why i have a component that does create the list and each item is a seperate component. The List Item subscribes only to a reaction of the keys, so it should not need to update if an item changes. But it does.
Here is a minimal example to reproduce this:

(re-frame/register-handler
 :initialize-db
 (fn  [_ _]
  {0 {:name 0}
   1 {:name 1}
   2 {:name 2}
   3 {:name 3}}))

(re-frame/register-handler
 :change-name
 (fn  [db _]
   (let [id (rand-int 4)]
     (update-in db [id :name] inc))))

(re-frame/register-sub
 :ids
 (fn [db _]
   (reaction (keys @db))))

(re-frame/register-sub
 :name
 (fn [db [_ id]]
   (reaction (get-in @db [id :name]))))

(defn entry-render [id]
  (let [name (re-frame/subscribe [:name id])]
    (fn []
        [:div "Hello from " @name])))

(defn entry-comp [id]
  (r/create-class {:render (entry-render id)
                   :display-name "entry"
                   :component-did-mount #(prn "entry mount")
                   :component-did-update #(prn "entry update")}))

(defn list-render []
  (let [ids (re-frame/subscribe [:ids])]
    (fn []
      [:div
       [:a {:href "#" :on-click #(re-frame/dispatch [:change-name])} "change name"]
       (doall
        (for [id @ids]
          ^{:key id} [(entry-comp id)]))])))

(defn list-comp []
  (r/create-class {:reagent-render (list-render)
                   :display-name "list"
                   :component-did-mount #(prn "list mount")
                   :component-did-update #(prn "list update")}))

Everytime i click on the href all entries re-mount and the list updates.

The hack with that i have come up is to wrap a reaction around the seriealisation of the keys and deserialize them in the for loop like this:

(defn list-render []
  (let [ids (re-frame/subscribe [:ids])
        sids (reaction (pr-str @ids))]
    (fn []
      [:div
       [:a {:href "#" :on-click #(re-frame/dispatch [:change-name])} "change name"]
       (doall
        (for [id (cljs.reader/read-string @sids)]
          ^{:key id} [(entry-comp id)]))])))

With this only the entry that changes updates.

Do I miss somthing?

[mike-thompson-day8]

I haven't looked too deeply but I noticed this in your code immediately above...

Each time ids changes list-render will run.
And each time list-render runs it will re render all items via the for. Now, normally that wouldn't be a problem - items which stayed unchanged wouldn't be rerendered. Except you do this:
^{:key id} [(entry-comp id)]
Each time that is run (entry-comp id) will return a different value to last time. So it will appear to reagent that the component has changed .... leading to all items being rerendered.

Replace with:
^{:key id} [entry-render id]

I'd rewrite:

(defn entry-render [id]
  (let [name (re-frame/subscribe [:name id])]
    (fn [new-id]
        (assert (= new-id id))         ;; because I'm paranoid
        (println "rerendering " id)   ;; so you know when things are getting rerendered
        [:div "Hello from " @name])))

[mike-thompson-day8]

Also, a reminder: this place is for reporting bugs and requesting features. Please take this up in the various help forums like:

• http://clojurians.net/ (#reagent channel or #re-frame channel)
• https://groups.google.com/forum/#!forum/clojurescript

[ZabelTech]

Ok, your suggestion works.

But still, is it not a bug that this reaction (reaction (keys @db)) triggers the re-rendering but (reaction (pr-str @(reaction (keys @db))) does not ?
(this is essentially what i did in my 'solution')

[hkjels]

http://clojurians.net/ is broken.
Missing admin scope: The token you provided is for an account that is not an admin. You must provide a token from an admin account in order to invite users through the Slack API.
I have a few questions myself, but nowhere to turn.

[mike-thompson-day8]

@hkjels Must have been a temporary issue. Seems to be working now.

[hkjels]

Nope. Same result. It happens when I press the "GET MY INVITE"-button.

[mike-thompson-day8]

That's odd. I looked across in #general, where people start, and I can see that 5 people have joined in the last 6 hours. So it seems to be working for others.

Anyways, perhaps you could use: https://groups.google.com/forum/#!forum/clojurescript