-
Notifications
You must be signed in to change notification settings - Fork 22
/
DECHash.pas
3709 lines (3394 loc) · 165 KB
/
DECHash.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
{*****************************************************************************
Delphi Encryption Compendium (DEC Part I)
Version 5.3 for Delphi 7 - 10.4 or higher/FPC 2.6 or higher
Remarks: Freeware, Copyright must be included
Original Author: (c) 2006 Hagen Reddmann, HaReddmann [at] T-Online [dot] de
Modifications: (c) 2008 Arvid Winkelsdorf, info [at] digivendo [dot] de
(c) 2017, 2021 decfpc
* THIS SOFTWARE IS PROVIDED BY THE AUTHORS ''AS IS'' AND ANY EXPRESS
* OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
* WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
* ARE DISCLAIMED. IN NO EVENT SHALL THE AUTHORS OR CONTRIBUTORS BE
* LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
* CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
* SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR
* BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
* WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE
* OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE,
* EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
*****************************************************************************}
unit DECHash;
{$IFDEF FPC}
{$MODE Delphi}
{$ENDIF}
{$WARNINGS OFF}
{$RANGECHECKS OFF}
interface
uses SysUtils, Classes, DECUtil, DECFmt;
{$I Ver.inc}
type
{all Hash Classes}
THash_MD2 = class; {$IFDEF CPU386}{$DEFINE THash_MD2_asm}{$ENDIF}
THash_MD4 = class; {$IFDEF CPU386}{$DEFINE THash_MD4_asm}{$ENDIF}
THash_MD5 = class; {$IFDEF CPU386}{$DEFINE THash_MD5_asm}{$ENDIF}
THash_RipeMD128 = class; {$IFDEF CPU386}{$DEFINE THash_RipeMD128_asm}{$ENDIF}
THash_RipeMD160 = class; {$IFDEF CPU386}{$DEFINE THash_RipeMD160_asm}{$ENDIF}
THash_RipeMD256 = class; {$IFDEF CPU386}{$DEFINE THash_RipeMD256_asm}{$ENDIF}
THash_RipeMD320 = class; {$IFDEF CPU386}{$DEFINE THash_RipeMD320_asm}{$ENDIF}
THash_SHA = class; {$IFDEF CPU386}{$DEFINE THash_SHA_asm}{$ENDIF}
THash_SHA1 = class;
THash_SHA256 = class; {$IFDEF CPU386}{$DEFINE THash_SHA256_asm}{$ENDIF}
THash_SHA384 = class; {$IFDEF CPU386}{$DEFINE THash_SHA384_asm}{$ENDIF}
THash_SHA512 = class;
THash_Haval128 = class; {$IFDEF CPU386}{$DEFINE THashBaseHaval_asm}{$ENDIF}
THash_Haval160 = class; // Haval 160, 3 Rounds
THash_Haval192 = class; // Haval 192, 4 Rounds
THash_Haval224 = class; // Haval 224, 4 Rounds
THash_Haval256 = class; // Haval 256, 5 Rounds
THash_Tiger = class; {$IFDEF CPU386}{$DEFINE THash_Tiger_asm}{$ENDIF}
THash_Panama = class; {$IFDEF CPU386}{$DEFINE THash_Panama_asm}{$ENDIF}
THash_Whirlpool = class; {$IFDEF CPU386}{$DEFINE THashBaseWhirlpool_asm}{$ENDIF}
THash_Whirlpool1 = class;
THash_Square = class; {$IFDEF CPU386}{$DEFINE THash_Square_asm}{$ENDIF}
THash_Snefru128 = class; {$IFDEF CPU386}{$DEFINE THash_Snefru128_asm}{$ENDIF}
THash_Snefru256 = class; {$IFDEF CPU386}{$DEFINE THash_Snefru256_asm}{$ENDIF}
THash_Sapphire = class; {$IFDEF CPU386}{$DEFINE THash_Sapphire_asm}{$ENDIF}
TDECHashClass = class of TDECHash;
TDECHash = class(TDECObject)
protected
FCount: array[0..7] of LongWord;
FBuffer: PByteArray;
FBufferSize: Integer;
FBufferIndex: Integer;
FPaddingByte: Byte;
procedure DoTransform(Buffer: PLongArray); virtual; abstract;
procedure DoInit; virtual; abstract;
procedure DoDone; virtual; abstract;
public
destructor Destroy; override;
procedure Init;
procedure Calc(const Data; DataSize: Integer); virtual;
procedure Done;
function Digest: PByteArray; virtual; abstract;
function DigestStr(Format: TDECFormatClass = nil): Binary; virtual;
class function DigestSize: Integer; virtual; abstract;
class function BlockSize: Integer; virtual; abstract;
class function CalcBuffer(const Buffer; BufferSize: Integer; Format: TDECFormatClass = nil): Binary;
class function CalcStream(const Stream: TStream; Size: Int64; Format: TDECFormatClass = nil; const Progress: IDECProgress = nil): Binary;
class function CalcBinary(const Data: Binary; Format: TDECFormatClass = nil): Binary;
class function CalcFile(const FileName: String; Format: TDECFormatClass = nil; const Progress: IDECProgress = nil): Binary;
class function MGF1(const Data: Binary; MaskSize: Integer; Format: TDECFormatClass = nil): Binary; overload;
class function MGF1(const Data; DataSize, MaskSize: Integer; Format: TDECFormatClass = nil): Binary; overload;
class function KDF2(const Data,Seed: Binary; MaskSize: Integer; Format: TDECFormatClass = nil): Binary; overload;
class function KDF2(const Data; DataSize: Integer; const Seed; SeedSize, MaskSize: Integer; Format: TDECFormatClass = nil): Binary; overload;
// DEC's own KDF+MGF
class function MGFx(const Data; DataSize, MaskSize: Integer; Format: TDECFormatClass = nil; Index: LongWord = 1): Binary; overload;
class function MGFx(const Data: Binary; MaskSize: Integer; Format: TDECFormatClass = nil; Index: LongWord = 1): Binary; overload;
class function KDFx(const Data,Seed: Binary; MaskSize: Integer; Format: TDECFormatClass = nil; Index: LongWord = 1): Binary; overload;
class function KDFx(const Data; DataSize: Integer; const Seed; SeedSize, MaskSize: Integer; Format: TDECFormatClass = nil; Index: LongWord = 1): Binary; overload;
published
property PaddingByte: Byte read FPaddingByte write FPaddingByte;
end;
THash_MD2 = class(TDECHash)
private
FDigest: array[0..63] of Byte;
protected
procedure DoTransform(Buffer: PLongArray); override;
procedure DoInit; override;
procedure DoDone; override;
public
class function DigestSize: Integer; override;
class function BlockSize: Integer; override;
function Digest: PByteArray; override;
end;
THashBaseMD4 = class(TDECHash)
private
FDigest: array[0..9] of LongWord;
protected
procedure DoInit; override;
procedure DoDone; override;
public
class function DigestSize: Integer; override;
class function BlockSize: Integer; override;
function Digest: PByteArray; override;
end;
THash_MD4 = class(THashBaseMD4)
protected
procedure DoTransform(Buffer: PLongArray); override;
end;
THash_MD5 = class(THashBaseMD4)
protected
procedure DoTransform(Buffer: PLongArray); override;
end;
THash_RipeMD128 = class(THashBaseMD4)
protected
procedure DoTransform(Buffer: PLongArray); override;
end;
THash_RipeMD160 = class(THashBaseMD4)
protected
procedure DoTransform(Buffer: PLongArray); override;
public
class function DigestSize: Integer; override;
end;
THash_RipeMD256 = class(THashBaseMD4)
protected
procedure DoTransform(Buffer: PLongArray); override;
procedure DoInit; override;
public
class function DigestSize: Integer; override;
end;
THash_RipeMD320 = class(THashBaseMD4)
protected
procedure DoTransform(Buffer: PLongArray); override;
public
class function DigestSize: Integer; override;
end;
THash_SHA = class(THashBaseMD4)
protected
procedure DoTransform(Buffer: PLongArray); override;
procedure DoDone; override;
public
class function DigestSize: Integer; override;
end;
THash_SHA1 = class(THash_SHA);
THash_SHA256 = class(THash_SHA)
protected
procedure DoTransform(Buffer: PLongArray); override;
procedure DoInit; override;
public
class function DigestSize: Integer; override;
end;
THash_SHA384 = class(TDECHash)
private
FDigest: array[0..7] of Int64;
protected
procedure DoTransform(Buffer: PLongArray); override;
procedure DoInit; override;
procedure DoDone; override;
public
class function DigestSize: Integer; override;
class function BlockSize: Integer; override; // 128
function Digest: PByteArray; override;
end;
THash_SHA512 = class(THash_SHA384)
protected
procedure DoInit; override;
public
class function DigestSize: Integer; override;
end;
THashBaseHaval = class(TDECHash)
private
FDigest: array[0..7] of LongWord;
FRounds: Integer; {3 - 5}
FTransform: procedure(Buffer: PLongArray) of object;
procedure SetRounds(Value: Integer);
protected
procedure DoTransform (Buffer: PLongArray); override;
procedure DoTransform3(Buffer: PLongArray);
procedure DoTransform4(Buffer: PLongArray);
procedure DoTransform5(Buffer: PLongArray);
procedure DoInit; override;
procedure DoDone; override;
public
class function BlockSize: Integer; override;
function Digest: PByteArray; override;
published
property Rounds: Integer read FRounds write SetRounds;
end;
THash_Haval128 = class(THashBaseHaval)
public
class function DigestSize: Integer; override;
end;
THash_Haval160 = class(THashBaseHaval)
public
class function DigestSize: Integer; override;
end;
THash_Haval192 = class(THashBaseHaval)
public
class function DigestSize: Integer; override;
end;
THash_Haval224 = class(THashBaseHaval)
public
class function DigestSize: Integer; override;
end;
THash_Haval256 = class(THashBaseHaval)
public
class function DigestSize: Integer; override;
end;
THash_Tiger = class(THashBaseMD4)
private
FRounds: Integer;
procedure SetRounds(Value: Integer);
protected
procedure DoTransform(Buffer: PLongArray); override;
procedure DoInit; override;
public
class function DigestSize: Integer; override;
published
property Rounds: Integer read FRounds write SetRounds;
end;
THash_Panama = class(TDECHash)
private
FLFSRBuffer: array[0..31, 0..7] of LongWord;
FDigest: array[0..16] of LongWord;
FTap: LongWord;
protected
procedure DoInit; override;
procedure DoDone; override;
procedure DoPull;
procedure DoTransform(Buffer: PLongArray); override;
public
class function DigestSize: Integer; override;
class function BlockSize: Integer; override; // 32
function Digest: PByteArray; override;
end;
THashBaseWhirlpool = class(TDECHash)
private
FDigest: array[0..15] of LongWord;
FTableC: Pointer;
FTableR: Pointer;
protected
procedure DoTransform(Buffer: PLongArray); override;
procedure DoDone; override;
public
class function DigestSize: Integer; override;
class function BlockSize: Integer; override;
function Digest: PByteArray; override;
end;
THash_Whirlpool = class(THashBaseWhirlpool)
protected
procedure DoInit; override;
end;
THash_Whirlpool1 = class(THashBaseWhirlpool)
protected
procedure DoInit; override;
end;
THash_Square = class(TDECHash)
private
FDigest: array[0..3] of LongWord;
protected
procedure DoInit; override;
procedure DoDone; override;
procedure DoTransform(Buffer: PLongArray); override;
public
class function DigestSize: Integer; override;
class function BlockSize: Integer; override;
function Digest: PByteArray; override;
end;
THashBaseSnefru = class(TDECHash) {"derived from the Xerox Secure Hash Function"}
private
FDigest: array[0..23] of LongWord;
FSecurity_Level: Integer;
procedure SetSecurity_Level(Value: Integer);
protected
procedure DoInit; override;
procedure DoDone; override;
public
function Digest: PByteArray; override;
published
property Security_Level: Integer read FSecurity_Level write SetSecurity_Level; // can set from 2 to 8, default is 8
end;
THash_Snefru128 = class(THashBaseSnefru)
protected
procedure DoTransform(Buffer: PLongArray); override;
public
class function DigestSize: Integer; override;
class function BlockSize: Integer; override; // 48
end;
THash_Snefru256 = class(THashBaseSnefru)
protected
procedure DoTransform(Buffer: PLongArray); override;
public
class function DigestSize: Integer; override;
class function BlockSize: Integer; override; // 32
end;
THash_Sapphire = class(TDECHash)
private
FCards: array[0..255] of LongWord;
FDigest: array[0..15] of LongWord;
FRotor: LongWord; // don't change order
FRatchet: LongWord;
FAvalanche: LongWord;
FPlain: LongWord;
FCipher: LongWord;
FDigestSize: Integer;
protected
procedure DoInit; override;
procedure DoDone; override;
public
class function BlockSize: Integer; override;
class function DigestSize: Integer; override;
function Digest: PByteArray; override;
function DigestStr(Format: TDECFormatClass = nil): Binary; override;
procedure Calc(const Data; DataSize: Integer); override;
published
property RequestedDigestSize: Integer read FDigestSize write FDigestSize;
end;
function ValidHash(HashClass: TDECHashClass = nil): TDECHashClass;
function HashByName(const Name: String): TDECHashClass;
function HashByIdentity(Identity: LongWord): TDECHashClass;
procedure SetDefaultHashClass(HashClass: TDECHashClass);
var
StreamBufferSize: Integer = 8192;
implementation
uses DECData;
{$I DECHash.inc}
{ assembler pascal
THash_SHA512 : 85.1 cycles/byte 17.62 Mb/sec 220.9 cycles/byte 6.79 Mb/sec 159%
THash_SHA384 : 85.2 cycles/byte 17.61 Mb/sec 220.0 cycles/byte 6.82 Mb/sec 158%
THash_Tiger : 24.6 cycles/byte 60.98 Mb/sec 60.7 cycles/byte 24.69 Mb/sec 147%
THash_Haval128 : 13.3 cycles/byte 112.55 Mb/sec 26.0 cycles/byte 57.77 Mb/sec 95%
THash_SHA1 : 20.1 cycles/byte 74.80 Mb/sec 36.1 cycles/byte 41.51 Mb/sec 80%
THash_SHA : 20.0 cycles/byte 75.03 Mb/sec 35.5 cycles/byte 42.21 Mb/sec 78%
THash_Haval160 : 13.2 cycles/byte 113.30 Mb/sec 22.7 cycles/byte 66.12 Mb/sec 71%
THash_Haval256 : 25.9 cycles/byte 57.84 Mb/sec 40.5 cycles/byte 37.07 Mb/sec 56%
THash_Snefru128 : 159.7 cycles/byte 9.39 Mb/sec 248.2 cycles/byte 6.04 Mb/sec 55%
THash_Snefru256 : 239.3 cycles/byte 6.27 Mb/sec 367.9 cycles/byte 4.08 Mb/sec 54%
THash_RipeMD256 : 14.5 cycles/byte 103.16 Mb/sec 21.4 cycles/byte 70.08 Mb/sec 47%
THash_MD4 : 5.8 cycles/byte 256.73 Mb/sec 8.5 cycles/byte 176.92 Mb/sec 45%
THash_MD2 : 251.6 cycles/byte 5.96 Mb/sec 366.1 cycles/byte 4.10 Mb/sec 45%
THash_RipeMD128 : 15.2 cycles/byte 98.89 Mb/sec 21.2 cycles/byte 70.61 Mb/sec 40%
THash_RipeMD320 : 25.5 cycles/byte 58.73 Mb/sec 35.8 cycles/byte 41.87 Mb/sec 40%
THash_MD5 : 8.9 cycles/byte 169.43 Mb/sec 11.4 cycles/byte 131.01 Mb/sec 29%
THash_RipeMD160 : 26.5 cycles/byte 56.66 Mb/sec 31.4 cycles/byte 47.79 Mb/sec 19%
THash_Square : 44.7 cycles/byte 33.58 Mb/sec 53.1 cycles/byte 28.23 Mb/sec 19%
THash_Haval192 : 32.5 cycles/byte 46.17 Mb/sec 37.6 cycles/byte 39.87 Mb/sec 18%
THash_Whirlpool1 : 104.9 cycles/byte 14.30 Mb/sec 122.8 cycles/byte 12.22 Mb/sec 17%
THash_Whirlpool : 104.7 cycles/byte 14.33 Mb/sec 119.9 cycles/byte 12.51 Mb/sec 15%
THash_Sapphire : 52.9 cycles/byte 28.35 Mb/sec 53.8 cycles/byte 27.86 Mb/sec 2%
THash_Haval224 : 32.0 cycles/byte 46.82 Mb/sec 32.3 cycles/byte 46.46 Mb/sec 1%
THash_SHA256 : 47.8 cycles/byte 31.35 Mb/sec 47.8 cycles/byte 31.39 Mb/sec 0%
THash_Panama : 8.9 cycles/byte 169.01 Mb/sec 7.3 cycles/byte 206.55 Mb/sec -18%
}
resourcestring
sHashingOverflowError = 'Hash function have to many bits processed';
sHashNotInitialized = 'Hash must be initialized';
sHashNoDefault = 'No default hash are registered';
var
FDefaultHashClass: TDECHashClass = nil;
function ValidHash(HashClass: TDECHashClass): TDECHashClass;
begin
if HashClass <> nil then Result := HashClass
else Result := FDefaultHashClass;
if Result = nil then raise EDECException.Create(sHashNoDefault);
end;
function HashByName(const Name: String): TDECHashClass;
begin
Result := TDECHashClass(DECClassByName(Name, TDECHash));
end;
function HashByIdentity(Identity: LongWord): TDECHashClass;
begin
Result := TDECHashClass(DECClassByIdentity(Identity, TDECHash));
end;
procedure SetDefaultHashClass(HashClass: TDECHashClass);
begin
if HashClass <> nil then HashClass.Register;
FDefaultHashClass := HashClass;
end;
// .TDECHash
destructor TDECHash.Destroy;
begin
ProtectBuffer(Digest^, DigestSize);
ProtectBuffer(FBuffer^, FBufferSize);
ReallocMem(FBuffer, 0);
inherited Destroy;
end;
procedure TDECHash.Init;
begin
FBufferIndex := 0;
FBufferSize := BlockSize;
ReallocMem(FBuffer, FBufferSize);
FillChar(FBuffer^, FBufferSize, 0);
FillChar(FCount, SizeOf(FCount), 0);
DoInit;
end;
procedure TDECHash.Done;
begin
DoDone;
ProtectBuffer(FBuffer^, FBufferSize);
FBufferSize := 0;
ReallocMem(FBuffer, 0);
end;
procedure HashingOverflowError;
begin
raise EDECException.Create(sHashingOverflowError);
end;
procedure HashNotInitialized;
begin
raise EDECException.Create(sHashNotInitialized);
end;
procedure Increment8(var Value; Add: LongWord);
// Value := Value + 8 * Add
// Value: array[0..7] of LongWord
{$IFDEF UseASM86}
asm
MOV ECX,EDX
LEA EDX,[EDX * 8]
SHR ECX,29
ADD [EAX].DWord[ 0],EDX
ADC [EAX].DWord[ 4],ECX
ADC [EAX].DWord[ 8],0
ADC [EAX].DWord[12],0
ADC [EAX].DWord[16],0
ADC [EAX].DWord[20],0
ADC [EAX].DWord[24],0
ADC [EAX].DWord[28],0
JC HashingOverflowError
end;
{$ELSE}
var
V: PLongArray;
A, C, i: Cardinal;
begin
V := PLongArray(@Value);
A := V[0] + Add * 8;
C := Ord(V[0] > A);
V[0] := A;
A := V[1] + (Add shr 29) + C;
C := Ord(V[1] > A);
V[1] := A;
for i := 2 to 7 do
begin
if C = 0 then
Exit;
A := V[i] + C;
C := Ord(V[i] > A);
V[i] := A;
end;
if C <> 0 then
HashingOverflowError;
end;
{$ENDIF}
procedure TDECHash.Calc(const Data; DataSize: Integer);
var
Remain: Integer;
Source: PByte;
begin
if DataSize <= 0 then Exit;
if FBuffer = nil then HashNotInitialized;
Increment8(FCount, DataSize);
Source := @TByteArray(Data)[0];
if FBufferIndex > 0 then
begin
Remain := FBufferSize - FBufferIndex;
if DataSize < Remain then
begin
Move(Source^, FBuffer[FBufferIndex], DataSize);
Inc(FBufferIndex, DataSize);
Exit;
end;
Move(Source^, FBuffer[FBufferIndex], Remain);
DoTransform(Pointer(FBuffer));
Dec(DataSize, Remain);
Inc(Source, Remain);
end;
while DataSize >= FBufferSize do
begin
DoTransform(Pointer(Source));
Inc(Source, FBufferSize);
Dec(DataSize, FBufferSize);
end;
Move(Source^, FBuffer^, DataSize);
FBufferIndex := DataSize;
end;
function TDECHash.DigestStr(Format: TDECFormatClass): Binary;
begin
Result := ValidFormat(Format).Encode(Digest[0], DigestSize);
end;
class function TDECHash.CalcStream(const Stream: TStream; Size: Int64; Format: TDECFormatClass; const Progress: IDECProgress): Binary;
var
Buffer: Binary;
Bytes: Integer;
Min,Max,Pos: Int64;
begin
Min := 0;
Max := 0;
with Create do
try
Init;
if StreamBufferSize <= 0 then StreamBufferSize := 8192;
if Size < 0 then
begin
Stream.Position := 0;
Size := Stream.Size;
Pos := 0;
end else Pos := Stream.Position;
Bytes := StreamBufferSize mod FBufferSize;
if Bytes = 0 then Bytes := StreamBufferSize
else Bytes := StreamBufferSize + FBufferSize - Bytes;
if Bytes > Size then SetLength(Buffer, Size)
else SetLength(Buffer, Bytes);
Min := Pos;
Max := Pos + Size;
while Size > 0 do
begin
if Assigned(Progress) then Progress.Process(Min, Max, Pos);
Bytes := Length(Buffer);
if Bytes > Size then Bytes := Size;
Stream.ReadBuffer(Buffer[1], Bytes);
Calc(Buffer[1], Bytes);
Dec(Size, Bytes);
Inc(Pos, Bytes);
end;
Done;
Result := DigestStr(Format);
finally
Free;
ProtectBinary(Buffer);
if Assigned(Progress) then Progress.Process(Min, Max, Max);
end;
end;
class function TDECHash.CalcBinary(const Data: Binary; Format: TDECFormatClass): Binary;
begin
Result := CalcBuffer(Data[1], Length(Data), Format);
end;
class function TDECHash.CalcFile(const FileName: String; Format: TDECFormatClass; const Progress: IDECProgress): Binary;
var
S: TFileStream;
begin
S := TFileStream.Create(FileName, fmOpenRead or fmShareDenyNone);
try
Result := CalcStream(S, S.Size, Format, Progress);
finally
S.Free;
end;
end;
class function TDECHash.CalcBuffer(const Buffer; BufferSize: Integer; Format: TDECFormatClass): Binary;
begin
with Create do
try
Init;
Calc(Buffer, BufferSize);
Done;
Result := DigestStr(Format);
finally
Free;
end;
end;
class function TDECHash.MGF1(const Data; DataSize, MaskSize: Integer; Format: TDECFormatClass = nil): Binary;
// indexed Mask generation function, IEEE P1363 Working Group
// equal to KDF2 except without Seed
begin
Result := KDF2(Data, DataSize, EmptyStr[1], 0, MaskSize, Format);
end;
class function TDECHash.MGF1(const Data: Binary; MaskSize: Integer; Format: TDECFormatClass = nil): Binary;
begin
Result := KDF2(Data, Length(Data), EmptyStr[1], 0, MaskSize, Format);
end;
class function TDECHash.KDF2(const Data; DataSize: Integer; const Seed; SeedSize, MaskSize: Integer; Format: TDECFormatClass = nil): Binary;
// Key Generation Function 2, IEEE P1363 Working Group
var
I,Rounds,DigestBytes: Integer;
Dest: PByteArray;
Count: LongWord;
begin
DigestBytes := DigestSize;
Assert(MaskSize >= 0);
Assert(DataSize >= 0);
Assert(SeedSize >= 0);
Assert(DigestBytes >= 0);
with Create do
try
Rounds := (MaskSize + DigestBytes -1) div DigestBytes;
SetLength(Result, Rounds * DigestBytes);
Dest := @Result[1];
for I := 0 to Rounds -1 do
begin
Count := SwapLong(I);
Init;
Calc(Data, DataSize);
Calc(Count, SizeOf(Count));
Calc(Seed, SeedSize);
Done;
Move(Digest[0], Dest[I * DigestBytes], DigestBytes);
end;
finally
Free;
end;
SetLength(Result, MaskSize);
Result := ValidFormat(Format).Encode(Result[1], MaskSize);
end;
class function TDECHash.KDF2(const Data, Seed: Binary; MaskSize: Integer; Format: TDECFormatClass = nil): Binary;
begin
Result := KDF2(Data[1], Length(Data), Seed[1], Length(Seed), MaskSize, Format);
end;
class function TDECHash.KDFx(const Data; DataSize: Integer; const Seed; SeedSize, MaskSize: Integer; Format: TDECFormatClass = nil; Index: LongWord = 1): Binary;
// DEC's own KDF, even stronger
var
I,J: Integer;
Count: LongWord;
R: Byte;
begin
Assert(MaskSize >= 0);
Assert(DataSize >= 0);
Assert(SeedSize >= 0);
Assert(DigestSize >= 0);
SetLength(Result, MaskSize);
Index := SwapLong(Index);
with Create do
try
for I := 0 to MaskSize -1 do
begin
Init;
Count := SwapLong(I);
Calc(Count, SizeOf(Count));
Calc(Result[1], I);
Calc(Index, SizeOf(Index));
Count := SwapLong(SeedSize);
Calc(Count, SizeOf(Count));
Calc(Seed, SeedSize);
Count := SwapLong(DataSize);
Calc(Count, SizeOf(Count));
Calc(Data, DataSize);
Done;
R := 0;
for J := 0 to DigestSize -1 do
R := R xor Digest[J];
Result[I +1] := AnsiChar(R);
end;
finally
Free;
end;
Result := ValidFormat(Format).Encode(Result[1], MaskSize);
end;
class function TDECHash.KDFx(const Data, Seed: Binary; MaskSize: Integer; Format: TDECFormatClass = nil; Index: LongWord = 1): Binary;
begin
Result := KDFx(Data[1], Length(Data), Seed[1], Length(Seed), MaskSize, Format, Index);
end;
class function TDECHash.MGFx(const Data; DataSize, MaskSize: Integer; Format: TDECFormatClass = nil; Index: LongWord = 1): Binary;
begin
Result := KDFx(Data, DataSize, EmptyStr[1], 0, MaskSize, Format, Index);
end;
class function TDECHash.MGFx(const Data: Binary; MaskSize: Integer; Format: TDECFormatClass = nil; Index: LongWord = 1): Binary;
begin
Result := KDFx(Data[1], Length(Data), EmptyStr[1], 0, MaskSize, Format, Index);
end;
// .THash_MD2
class function THash_MD2.DigestSize: Integer;
begin
Result := 16;
end;
class function THash_MD2.BlockSize: Integer;
begin
Result := 16;
end;
function THash_MD2.Digest: PByteArray;
begin
Result := @FDigest;
end;
{$IFNDEF THash_MD2_asm}
procedure THash_MD2.DoTransform(Buffer: PLongArray);
var
I,J,T: LongWord;
begin
for I := 0 to 3 do
begin
PLongArray(@FDigest[16])[I] := Buffer[I];
PLongArray(@FDigest[32])[I] := PLongArray(@FDigest[0])[I] xor PLongArray(@FDigest[16])[I];
end;
T := FDigest[63];
for I := 0 to 15 do
begin
T := FDigest[I + 48] xor MD2_PISubst[FDigest[I + 16] xor Byte(T)];
FDigest[I + 48] := Byte(T);
end;
T := 0;
for I := 0 to 17 do
begin
for J := 0 to 47 do
begin
T := FDigest[J] xor MD2_PISubst[T];
FDigest[J] := Byte(T);
end;
T := (T + I) and $FF;
end;
end;
{$ENDIF}
procedure THash_MD2.DoInit;
begin
FillChar(FDigest, SizeOf(FDigest), 0);
end;
procedure THash_MD2.DoDone;
var
Remain: Integer;
begin
Remain := FBufferSize - FBufferIndex;
FillChar(FBuffer[FBufferIndex], Remain, Remain);
DoTransform(Pointer(FBuffer));
Move(FDigest[48], FBuffer^, FBufferSize);
DoTransform(Pointer(FBuffer));
end;
// .THashBaseMD4
class function THashBaseMD4.DigestSize: Integer;
begin
Result := 16;
end;
class function THashBaseMD4.BlockSize: Integer;
begin
Result := 64;
end;
function THashBaseMD4.Digest: PByteArray;
begin
Result := @FDigest;
end;
procedure THashBaseMD4.DoInit;
begin
FDigest[0] := $67452301;
FDigest[1] := $EFCDAB89;
FDigest[2] := $98BADCFE;
FDigest[3] := $10325476;
FDigest[4] := $C3D2E1F0;
FDigest[5] := $76543210;
FDigest[6] := $FEDCBA98;
FDigest[7] := $89ABCDEF;
FDigest[8] := $01234567;
FDigest[9] := $3C2D1E0F;
end;
procedure THashBaseMD4.DoDone;
begin
if FCount[2] or FCount[3] <> 0 then
HashingOverflowError;
if FPaddingByte = 0 then
FPaddingByte := $80;
FBuffer[FBufferIndex] := FPaddingByte;
Inc(FBufferIndex);
if FBufferIndex > FBufferSize - 8 then
begin
FillChar(FBuffer[FBufferIndex], FBufferSize - FBufferIndex, 0);
DoTransform(Pointer(FBuffer));
FBufferIndex := 0;
end;
FillChar(FBuffer[FBufferIndex], FBufferSize - FBufferIndex, 0);
{$IFNDEF ENDIAN_BIG}
Move(FCount, FBuffer[FBufferSize - 8], 8);
{$ELSE}
SwapLongBuffer(FCount, FBuffer[FBufferSize - 8], 2);
{$ENDIF}
DoTransform(Pointer(FBuffer));
{$IFDEF ENDIAN_BIG}
if ClassType <> THash_Tiger then
SwapLongBuffer(FDigest, FDigest, DigestSize div 4)
else
SwapInt64Buffer(FDigest, FDigest, DigestSize div 8);
{$ENDIF}
end;
// .THash_MD4
{$IFNDEF THash_MD4_asm}
procedure THash_MD4.DoTransform(Buffer: PLongArray);
const
S1 = $5A827999;
S2 = $6ED9EBA1;
var
A,B,C,D: LongWord;
{$IFDEF ENDIAN_BIG}
BufferBig: array[0..15] of UInt32;
{$ENDIF}
begin
A := FDigest[0];
B := FDigest[1];
C := FDigest[2];
D := FDigest[3];
{$IFDEF ENDIAN_BIG}
SwapLongBuffer(Buffer^, BufferBig, 16);
Buffer := @BufferBig;
{$ENDIF}
Inc(A, B and C or not B and D + Buffer[ 0]); A := A shl 3 or A shr 29;
Inc(D, A and B or not A and C + Buffer[ 1]); D := D shl 7 or D shr 25;
Inc(C, D and A or not D and B + Buffer[ 2]); C := C shl 11 or C shr 21;
Inc(B, C and D or not C and A + Buffer[ 3]); B := B shl 19 or B shr 13;
Inc(A, B and C or not B and D + Buffer[ 4]); A := A shl 3 or A shr 29;
Inc(D, A and B or not A and C + Buffer[ 5]); D := D shl 7 or D shr 25;
Inc(C, D and A or not D and B + Buffer[ 6]); C := C shl 11 or C shr 21;
Inc(B, C and D or not C and A + Buffer[ 7]); B := B shl 19 or B shr 13;
Inc(A, B and C or not B and D + Buffer[ 8]); A := A shl 3 or A shr 29;
Inc(D, A and B or not A and C + Buffer[ 9]); D := D shl 7 or D shr 25;
Inc(C, D and A or not D and B + Buffer[10]); C := C shl 11 or C shr 21;
Inc(B, C and D or not C and A + Buffer[11]); B := B shl 19 or B shr 13;
Inc(A, B and C or not B and D + Buffer[12]); A := A shl 3 or A shr 29;
Inc(D, A and B or not A and C + Buffer[13]); D := D shl 7 or D shr 25;
Inc(C, D and A or not D and B + Buffer[14]); C := C shl 11 or C shr 21;
Inc(B, C and D or not C and A + Buffer[15]); B := B shl 19 or B shr 13;
Inc(A, B and C or B and D or C and D + Buffer[ 0] + S1); A := A shl 3 or A shr 29;
Inc(D, A and B or A and C or B and C + Buffer[ 4] + S1); D := D shl 5 or D shr 27;
Inc(C, D and A or D and B or A and B + Buffer[ 8] + S1); C := C shl 9 or C shr 23;
Inc(B, C and D or C and A or D and A + Buffer[12] + S1); B := B shl 13 or B shr 19;
Inc(A, B and C or B and D or C and D + Buffer[ 1] + S1); A := A shl 3 or A shr 29;
Inc(D, A and B or A and C or B and C + Buffer[ 5] + S1); D := D shl 5 or D shr 27;
Inc(C, D and A or D and B or A and B + Buffer[ 9] + S1); C := C shl 9 or C shr 23;
Inc(B, C and D or C and A or D and A + Buffer[13] + S1); B := B shl 13 or B shr 19;
Inc(A, B and C or B and D or C and D + Buffer[ 2] + S1); A := A shl 3 or A shr 29;
Inc(D, A and B or A and C or B and C + Buffer[ 6] + S1); D := D shl 5 or D shr 27;
Inc(C, D and A or D and B or A and B + Buffer[10] + S1); C := C shl 9 or C shr 23;
Inc(B, C and D or C and A or D and A + Buffer[14] + S1); B := B shl 13 or B shr 19;
Inc(A, B and C or B and D or C and D + Buffer[ 3] + S1); A := A shl 3 or A shr 29;
Inc(D, A and B or A and C or B and C + Buffer[ 7] + S1); D := D shl 5 or D shr 27;
Inc(C, D and A or D and B or A and B + Buffer[11] + S1); C := C shl 9 or C shr 23;
Inc(B, C and D or C and A or D and A + Buffer[15] + S1); B := B shl 13 or B shr 19;
Inc(A, B xor C xor D + Buffer[ 0] + S2); A := A shl 3 or A shr 29;
Inc(D, A xor B xor C + Buffer[ 8] + S2); D := D shl 9 or D shr 23;
Inc(C, D xor A xor B + Buffer[ 4] + S2); C := C shl 11 or C shr 21;
Inc(B, C xor D xor A + Buffer[12] + S2); B := B shl 15 or B shr 17;
Inc(A, B xor C xor D + Buffer[ 2] + S2); A := A shl 3 or A shr 29;
Inc(D, A xor B xor C + Buffer[10] + S2); D := D shl 9 or D shr 23;
Inc(C, D xor A xor B + Buffer[ 6] + S2); C := C shl 11 or C shr 21;
Inc(B, C xor D xor A + Buffer[14] + S2); B := B shl 15 or B shr 17;
Inc(A, B xor C xor D + Buffer[ 1] + S2); A := A shl 3 or A shr 29;
Inc(D, A xor B xor C + Buffer[ 9] + S2); D := D shl 9 or D shr 23;
Inc(C, D xor A xor B + Buffer[ 5] + S2); C := C shl 11 or C shr 21;
Inc(B, C xor D xor A + Buffer[13] + S2); B := B shl 15 or B shr 17;
Inc(A, B xor C xor D + Buffer[ 3] + S2); A := A shl 3 or A shr 29;
Inc(D, A xor B xor C + Buffer[11] + S2); D := D shl 9 or D shr 23;
Inc(C, D xor A xor B + Buffer[ 7] + S2); C := C shl 11 or C shr 21;
Inc(B, C xor D xor A + Buffer[15] + S2); B := B shl 15 or B shr 17;
Inc(FDigest[0], A);
Inc(FDigest[1], B);
Inc(FDigest[2], C);
Inc(FDigest[3], D);
end;
{$ENDIF}
// .THash_MD5
{$IFNDEF THash_MD5_asm}
procedure THash_MD5.DoTransform(Buffer: PLongArray);
var
A,B,C,D: LongWord;
{$IFDEF ENDIAN_BIG}
BufferBig: array[0..15] of UInt32;
{$ENDIF}
begin
A := FDigest[0];
B := FDigest[1];
C := FDigest[2];
D := FDigest[3];
{$IFDEF ENDIAN_BIG}
SwapLongBuffer(Buffer^, BufferBig, 16);
Buffer := @BufferBig;
{$ENDIF}
Inc(A, Buffer[ 0] + $D76AA478 + (D xor (B and (C xor D)))); A := A shl 7 or A shr 25 + B;
Inc(D, Buffer[ 1] + $E8C7B756 + (C xor (A and (B xor C)))); D := D shl 12 or D shr 20 + A;
Inc(C, Buffer[ 2] + $242070DB + (B xor (D and (A xor B)))); C := C shl 17 or C shr 15 + D;
Inc(B, Buffer[ 3] + $C1BDCEEE + (A xor (C and (D xor A)))); B := B shl 22 or B shr 10 + C;
Inc(A, Buffer[ 4] + $F57C0FAF + (D xor (B and (C xor D)))); A := A shl 7 or A shr 25 + B;
Inc(D, Buffer[ 5] + $4787C62A + (C xor (A and (B xor C)))); D := D shl 12 or D shr 20 + A;
Inc(C, Buffer[ 6] + $A8304613 + (B xor (D and (A xor B)))); C := C shl 17 or C shr 15 + D;
Inc(B, Buffer[ 7] + $FD469501 + (A xor (C and (D xor A)))); B := B shl 22 or B shr 10 + C;
Inc(A, Buffer[ 8] + $698098D8 + (D xor (B and (C xor D)))); A := A shl 7 or A shr 25 + B;
Inc(D, Buffer[ 9] + $8B44F7AF + (C xor (A and (B xor C)))); D := D shl 12 or D shr 20 + A;
Inc(C, Buffer[10] + $FFFF5BB1 + (B xor (D and (A xor B)))); C := C shl 17 or C shr 15 + D;
Inc(B, Buffer[11] + $895CD7BE + (A xor (C and (D xor A)))); B := B shl 22 or B shr 10 + C;
Inc(A, Buffer[12] + $6B901122 + (D xor (B and (C xor D)))); A := A shl 7 or A shr 25 + B;
Inc(D, Buffer[13] + $FD987193 + (C xor (A and (B xor C)))); D := D shl 12 or D shr 20 + A;
Inc(C, Buffer[14] + $A679438E + (B xor (D and (A xor B)))); C := C shl 17 or C shr 15 + D;
Inc(B, Buffer[15] + $49B40821 + (A xor (C and (D xor A)))); B := B shl 22 or B shr 10 + C;
Inc(A, Buffer[ 1] + $F61E2562 + (C xor (D and (B xor C)))); A := A shl 5 or A shr 27 + B;
Inc(D, Buffer[ 6] + $C040B340 + (B xor (C and (A xor B)))); D := D shl 9 or D shr 23 + A;
Inc(C, Buffer[11] + $265E5A51 + (A xor (B and (D xor A)))); C := C shl 14 or C shr 18 + D;
Inc(B, Buffer[ 0] + $E9B6C7AA + (D xor (A and (C xor D)))); B := B shl 20 or B shr 12 + C;
Inc(A, Buffer[ 5] + $D62F105D + (C xor (D and (B xor C)))); A := A shl 5 or A shr 27 + B;