Implement and test use perl5i::2 -skip => [feature1, feature2];

Needs docs.

lib/perl5i/2.pm

@@ -17,6 +17,8 @@ use perl5i::VERSION; our $VERSION = perl5i::VERSION->VERSION;
 our $Latest = perl5i::VERSION->latest;
 
 my %Features = (
+    # A stub for autodie.  It's handled specially in import().
+    autodie => sub {},
     autobox => sub {
         my ($class, $caller) = @_;
 
@@ -142,18 +144,36 @@ use parent 'autodie';
 ## no critic (Subroutines::RequireArgUnpacking)
 sub import {
     my $class = shift;
+    my %import = @_;
 
     my $caller = caller;
 
+    # Read the skip list and turn it into a hash
+    my $skips = delete $import{-skip} || [];
+    $skips = { map { $_ => 1 } @$skips };
+
+    # Any remaining import parameters are unknown
+    if( keys %import ) {
+        croak sprintf "Unknown parameters '%s' in import list",
+          join(", ", map { "$_ => $import{$_}" } keys %import);
+    }
+
+    # Check all the skipped features are valid
+    for my $f ( grep { !exists $Features{$_} } keys %$skips ) {
+        croak "Unknown feature '$f' in skip list";
+    }
+
     # Current lexically active major version of perl5i.
     $^H{perl5i} = 2;
 
-    for my $feature (values %Features) {
-        $feature->($class, $caller);
+    # Load all the features.
+    for my $feature (keys %Features) {
+        next if $skips->{$feature};
+        $Features{$feature}->($class, $caller);
     }
 
     # autodie needs a bit more convincing
-    if( 1 ) {
+    if( !$skips->{autodie} ) {
         @_ = ( $class, ":all" );
         goto &autodie::import;
     }

t/skip.t

@@ -0,0 +1,43 @@
+#!/usr/bin/env perl
+
+use Test::More;
+
+note "skipping a feature";
+{
+    # Needs its own package because perl5i is not always lexical
+    package Foo1;
+
+    use perl5i::latest -skip => ['Signatures'];
+
+    ::ok !eval q[method foo { 42 }; 1];
+    ::ok !defined &foo;
+}
+
+note "skipping autodie";
+{
+    # Needs its own package because perl5i is not always lexical
+    package Foo2;
+
+    use perl5i::latest -skip => ["autodie"];
+    open my $fh, "/i/do/not/exist/alfkjaldjlf";
+    ::pass("autodie is disabled");
+}
+
+note "unknown feature error";
+{
+    my $feature = 'Orbital Mind Control Lasers';
+    ok !eval {
+        perl5i::latest->import( -skip => [$feature] );
+    };
+    is $@, sprintf "Unknown feature '%s' in skip list at %s line %d.\n", $feature, $0, __LINE__-2;
+}
+
+note "unknown import parameter";
+{
+    ok !eval {
+        perl5i::latest->import( wibble => "what" );
+    };
+    is $@, sprintf "Unknown parameters 'wibble => what' in import list at %s line %d.\n", $0, __LINE__-2;
+}
+
+done_testing;