build.gradle

// build.gradle for overthere repository containing the overthere and itest-support projects
defaultTasks 'build'

allprojects {
	version = '1.0.1'
	group = 'com.xebialabs.overthere'

	apply plugin: 'idea'
}

subprojects {
	apply plugin: 'java'
	apply plugin: 'eclipse'

	repositories {
		mavenLocal()
		mavenCentral()
		mavenRepo urls: 'http://download.java.net/maven/2/'
	}

	apply from: 'https://github.com/xebialabs/deployit-common-build/raw/master/releaseable.gradle'
	apply from: 'https://github.com/xebialabs/deployit-common-build/raw/master/artifacts.gradle'

	sourceCompatibility = 1.6
	targetCompatibility = 1.6

	configurations {
	    compile {
	        transitive = false
	    }
	}

	test {
		excludes = ["**/*Itest.*"]
	}

	task itest(type: Test) {
		includes = ['**/*Itest.*']
		testResultsDir = file("${buildDir}/itest-results")

		copyProjectPropertyToSystemProperty(project, systemProperties, 'itests')
		copyProjectPropertyToSystemProperty(project, systemProperties, 'aws.endpoint')
		copyProjectPropertyToSystemProperty(project, systemProperties, 'aws.accessKey')
		copyProjectPropertyToSystemProperty(project, systemProperties, 'aws.secretKey')
	}
}

def copyProjectPropertyToSystemProperty(project, systemProperties, name) {
	if(project.hasProperty(name)) {
		systemProperties[name] = project.getProperty(name)
	}
}