sys-apps/i2c-tools: python3_9 and version bump to 4.2

sys-apps/i2c-tools/Manifest

@@ -1 +1,2 @@
 DIST i2c-tools-4.1.tar.xz 83576 BLAKE2B 0a9ed3bb335b61f6c17a6b6c705502ff008b4fb8bab6a5fde63163a32528b5214d92affc4b8d6cca29676dc7ba82dfa84be5f14943b7e81c8612a7d9419ac628 SHA512 83262bcfd94c2adf74517cc50095dd78221fa4d16a62397245d4a538de7463272abf4f6727024be8ab1ca8ecbfe647af85ba2a553e5b5e68a53e50dfcad20248
+DIST i2c-tools-4.2.tar.xz 87600 BLAKE2B 89f84ad07f4c042f67c308d48a402aa9ed46352062ddad3456d048730019e099e6eef626d487d802e07b100ae2c836e9aa6b2345950ff8744cbc0fe1a22616fb SHA512 5e230be4983c5c9c5718491d3ce9ee2e6205edea75c4097735eb32a25e522e37a074ef4cb61d2492707efebf0cb1b75ff65f1b2ae8c0bc1684a169526809a096

sys-apps/i2c-tools/i2c-tools-4.1-r1.ebuild

@@ -3,7 +3,7 @@
 
 EAPI=7
 
-PYTHON_COMPAT=( python{3_6,3_7,3_8} )
+PYTHON_COMPAT=( python3_{6,7,8,9} )
 DISTUTILS_OPTIONAL="1"
 
 inherit distutils-r1 flag-o-matic toolchain-funcs

sys-apps/i2c-tools/i2c-tools-4.2.ebuild

@@ -0,0 +1,81 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+DISTUTILS_OPTIONAL="1"
+
+inherit distutils-r1 flag-o-matic toolchain-funcs
+
+DESCRIPTION="I2C tools for bus probing, chip dumping, EEPROM decoding, and more"
+HOMEPAGE="https://www.kernel.org/pub/software/utils/i2c-tools"
+SRC_URI="https://www.kernel.org/pub/software/utils/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="perl python static-libs"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	python? ( ${PYTHON_DEPS} )"
+DEPEND="${RDEPEND}"
+RDEPEND+="
+	perl? ( dev-lang/perl )"
+
+src_prepare() {
+	default
+	use python && distutils-r1_src_prepare
+
+	# Cut out the eeprom/ & stub/ dirs as only perl scripts live there.
+	if ! use perl ; then
+		sed -i '/^SRCDIRS/s: eeprom stub : :g' Makefile || die
+	fi
+}
+
+src_configure() {
+	use python && distutils-r1_src_configure
+
+	# Always build & use dynamic libs if possible.
+	if tc-is-static-only ; then
+		export BUILD_DYNAMIC_LIB=0
+		export USE_STATIC_LIB=1
+		export BUILD_STATIC_LIB=1
+	else
+		export BUILD_DYNAMIC_LIB=1
+		export USE_STATIC_LIB=0
+		export BUILD_STATIC_LIB=$(usex static-libs 1 0)
+	fi
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)" CC="$(tc-getCC)" all-lib # parallel make
+	emake CC="$(tc-getCC)"
+	emake -C eepromer CC="$(tc-getCC)" CFLAGS="${CFLAGS}"
+
+	if use python ; then
+		cd py-smbus || die
+		append-cppflags -I../include
+		distutils-r1_src_compile
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" libdir="/usr/$(get_libdir)" PREFIX="/usr" install-lib install
+	dosbin eepromer/eeprom{,er}
+	rm -rf "${D}"/usr/include || die # part of linux-headers
+	dodoc CHANGES README
+	local d
+	for d in $(usex perl eeprom '') eepromer ; do
+		docinto "${d}"
+		dodoc "${d}"/README*
+	done
+
+	if use python ; then
+		cd py-smbus || die
+		docinto py-smbus
+		dodoc README*
+		distutils-r1_src_install
+	fi
+}