Skip to content
New issue

Have a question about this project? Sign up for a free GitHub account to open an issue and contact its maintainers and the community.

Sign up for GitHub

By clicking “Sign up for GitHub”, you agree to our terms of service and privacy statement. We’ll occasionally send you account related emails.

Already on GitHub? Sign in to your account

Jump to bottom

gnome-extra/gnome-pomodoro: Add new package, version 0.24.1 #35543

Open
wants to merge 1 commit into
base: master
Choose a base branch
from
+74 −0
Open

gnome-extra/gnome-pomodoro: Add new package, version 0.24.1 #35543

Show file tree
Hide file tree
Changes from all commits
Commits
Show all changes
1 commit
Select commit
File filter

Filter by extension

Filter by extension
Conversations
Failed to load comments.
Jump to
Jump to file
Failed to load files.
Diff view
Diff view
1 change: 1 addition & 0 deletions gnome-extra/gnome-pomodoro/Manifest
View file
Open in desktop
Original file line number Diff line number Diff line change
@@ -0,0 +1 @@
DIST gnome-pomodoro-0.24.1.tar.gz 6205806 BLAKE2B 9319d3d40e2aa79b7088ca026c05632a19354bea60c62f3b294e655b35cf67d9248fc6b11912ac7822876d33eefebcab0dfc8ea1f9cd35998f0ca3b15352aad1 SHA512 b25745beb1a366d63672da0e9ec748a41bef2977952c8e4a85d8fd115b3b313cb5248a18ec21034e5455d5d57c92e1fe430ce7d7a612684c36ddd0dd71b42779
62 changes: 62 additions & 0 deletions gnome-extra/gnome-pomodoro/gnome-pomodoro-0.24.1.ebuild
View file
Open in desktop
Original file line number Diff line number Diff line change
@@ -0,0 +1,62 @@
# Copyright 2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit gnome2-utils meson vala virtualx xdg

DESCRIPTION="A time management utility for GNOME based on the pomodoro technique"
HOMEPAGE="http://gnomepomodoro.org https://github.com/gnome-pomodoro/gnome-pomodoro"
SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~amd64"

DEPEND="
>=dev-libs/glib-2.38.0:2
>=x11-libs/gtk+-3.20:3
x11-libs/gdk-pixbuf:2[introspection]
x11-libs/cairo
dev-libs/gobject-introspection
>=dev-libs/libpeas-1.5.0:0
>=dev-libs/gom-0.3
>=media-libs/gstreamer-1.0.10:1.0[introspection]
>=media-libs/libcanberra-0.30
>=dev-libs/json-glib-1.6.2[introspection]
dev-db/sqlite:3
"
RDEPEND="${DEPEND}"
BDEPEND="
$(vala_depend)
dev-libs/glib
sys-devel/gettext
virtual/pkgconfig
"

src_prepare() {
default

# This function overrides GSETTINGS_SCHEMA_DIR which breaks the test
sed -i -e '/this.setup_settings/d' tests/tests.vala || die

vala_setup
xdg_environment_reset
}

src_test() {
local -x GSETTINGS_BACKEND="memory"
local -x GSETTINGS_SCHEMA_DIR="${S}"/data
"${BROOT}"${GLIB_COMPILE_SCHEMAS} --allow-any-name "${GSETTINGS_SCHEMA_DIR}" || die
virtx meson_src_test
}

pkg_postinst() {
xdg_pkg_postinst
gnome2_schemas_update
}

pkg_postrm() {
xdg_pkg_postrm
gnome2_schemas_update
}
11 changes: 11 additions & 0 deletions gnome-extra/gnome-pomodoro/metadata.xml
View file
Open in desktop
Original file line number Diff line number Diff line change
@@ -0,0 +1,11 @@
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<maintainer type="person">
<email>mattst88@gentoo.org</email>
<name>Matt Turner</name>
</maintainer>
<upstream>
<remote-id type="github">gnome-pomodoro/gnome-pomodoro</remote-id>
</upstream>
</pkgmetadata>