Seafile Client: Version bump to 6.1.3 and some minor improvements

net-libs/ccnet/Manifest

@@ -1,2 +1,3 @@
 DIST ccnet-6.0.7.tar.gz 179356 SHA256 c4e02b5b77d774ffaa47235e6e265ecce00f656766a2f232397ce86eeb3162fa SHA512 66df998bb544ad614479d853820e3ee3119c2b08087d82a2a0633202c860447a7ac79f3639e587d531c2443def3cd58bf9ccdb2fed350c8bd7005737fb3d85fd WHIRLPOOL 27022bcae05958ad34c3b26221f7278184068fba119b63bfb4b13fe1f74ac19b61a34deb2e8b9047e6005c95abb0191299e3c105058e3937d8b873f1c75df73f
 DIST ccnet-6.1.0.tar.gz 179362 SHA256 6b91c1a1a00622a2a07669dae144dd7fcd8f11275912384aa65d33da05088a60 SHA512 0053d342cf9256a37ca2ebf774794c791cb08caa7d608035c1b307a271e11719da1d4c272870ab51ad1cd8d8c0a84d22959b513865ddf98b4691cba35bc93018 WHIRLPOOL fd0a421fcd6433134520d7e9a667a3937af329b2761cc353095cc98814f7cd37b19b4b4593094f4e5d153ecbc632ccb569fb99c328c8c7c7cf547b33f19e4ad7
+DIST ccnet-6.1.3.tar.gz 179321 SHA256 0ac3dcd86d22f6bb729027783da8ea14f832276982e36cc814fda0cf3ed78050 SHA512 1700237749dd250798b6bd3ea2d74bd09f72e3f5502520d413671c247eeeae05f92947a4a4429035f8ab6414c9c67353939025de046b00941956b6854f4cfcc3 WHIRLPOOL ce46693893056337c4411313f41589a28af1d46084bf2e51e0f4e4ad0d8ff45d760506b96fa4266fcf745e5322eac116cbc89d0a46629171201194c641eb2021

net-libs/ccnet/ccnet-6.1.3.ebuild

@@ -0,0 +1,39 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+inherit autotools python-single-r1 vala
+
+DESCRIPTION="Ccnet is a framework for writing networked applications in C"
+HOMEPAGE="https://github.com/haiwen/ccnet http://seafile.com/"
+SRC_URI="https://github.com/haiwen/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+-with-openssl-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	net-libs/libsearpc[${PYTHON_USEDEP}]
+	>=dev-libs/glib-2.16.0:2
+	>=dev-libs/libevent-2.0
+	dev-libs/openssl:0=
+	dev-db/sqlite:3"
+DEPEND="${RDEPEND}
+	$(vala_depend)"
+
+src_prepare() {
+	default
+	sed -i -e "s/(DESTDIR)//" libccnet.pc.in || die
+	sed -i -e 's/valac /${VALAC} /' lib/Makefile.am || die
+	eautoreconf
+	vala_src_prepare
+}
+
+src_install() {
+	default
+	# Remove unnecessary .la files, as recommended by ltprune.eclass
+	find "${ED}" -name '*.la' -delete || die
+}

net-libs/libsearpc/libsearpc-3.0.8-r2.ebuild

@@ -0,0 +1,35 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+inherit autotools python-single-r1 vcs-snapshot
+
+DESCRIPTION="A simple C language RPC framework"
+HOMEPAGE="https://github.com/haiwen/libsearpc/ http://seafile.com/"
+SRC_URI="https://github.com/haiwen/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="${PYTHON_DEPS}
+	>=dev-libs/glib-2.26.0
+	>=dev-libs/jansson-2.2.1"
+RDEPEND="${DEPEND}
+	dev-python/simplejson[${PYTHON_USEDEP}]"
+
+src_prepare() {
+	default
+	sed -i -e "s/(DESTDIR)//" ${PN}.pc.in || die
+	eautoreconf
+}
+
+src_install() {
+	default
+	# Remove unnecessary .la files, as recommended by ltprune.eclass
+	find "${ED}" -name '*.la' -delete || die
+	python_fix_shebang "${ED}"usr/bin
+}

net-misc/seafile-client/Manifest

@@ -1,2 +1,3 @@
 DIST seafile-client-6.0.7.tar.gz 2192384 SHA256 3212acab89ec3cee1508dd37826303447b7a738232e455b44ffc1a29d3c48baf SHA512 4baa15d454a9c937c9ae944b2bcc6b549fc41a1558e40578a273497ccb120a9131580f2b5db047ce6d7e0503105bd0fa5312e823ab475241fb07f5ba0021224f WHIRLPOOL b5b4595038c237a01d3421411047b99dc3189708dfd2cb0de90fe7b113a791d946fc4c65434ff8dc9996684b38aeda11b2a776a81cd5b12b2d88d69cde372a4a
 DIST seafile-client-6.1.0.tar.gz 2246388 SHA256 6d1d9fdb238cdd8514f2aa22e81cbab7a4b178807e68883a7f8c29afd232369b SHA512 c6e3191afcaa833876c24690566be36ccc94e7a333c94f78df9201f23a3eed37397641e237e63b70cdc413ed6dc5683737d2eefa5c2c628b5e207bef1176b0d5 WHIRLPOOL 4e0ff1711cbe1447fd14734488cca65cdacce095efd92f9702ad6ea7f6ccd95af1525d179318029fc90dca54c478fa53c4f7b64854481f32620e5b20d90d611c
+DIST seafile-client-6.1.3.tar.gz 2358459 SHA256 63a124d7e27881bb30304c7a66dab87fddf8634462dc5741102a561dd4c38689 SHA512 be5426ef472ac7e788e164f601c4c2b2ca91e305b15dac7eddf9874af5639141bf845e36c5385c4af1d2f6df4c7af6554497bd107cbccb35f8c904694705497d WHIRLPOOL 758f60ccd735eadefff071eb632ef861d07584442dd69f21d73e4eebf9094677deff5c2b51ea06a0e4cd9347cc0293fc7e54bd3e6855075c75e11103a0882a45

net-misc/seafile-client/seafile-client-6.1.3.ebuild

@@ -0,0 +1,50 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit cmake-utils
+
+DESCRIPTION="Seafile desktop client"
+HOMEPAGE="https://github.com/haiwen/seafile-client/ http://www.seafile.com/"
+SRC_URI="https://github.com/haiwen/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="shibboleth test"
+
+RDEPEND="net-libs/libsearpc
+	=net-libs/ccnet-${PV}
+	=net-misc/seafile-${PV}
+	>=dev-libs/libevent-2.0
+	>=dev-libs/jansson-2.0
+	dev-libs/openssl:0=
+	dev-db/sqlite:3
+
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtdbus:5
+	shibboleth? ( || ( dev-qt/qtwebengine:5[widgets] dev-qt/qtwebkit:5 ) )"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+	test? ( dev-qt/qttest:5 )"
+
+src_prepare() {
+	eapply "${FILESDIR}/${PN}-select-qt5.patch"
+	cmake-utils_src_prepare
+	if use shibboleth ; then
+		if ! has_version "dev-qt/qtwebengine:5[widgets]" ; then
+			sed -i -e 's/IF(WIN32 OR DETECTED_QT_VERSION VERSION_LESS 5.6.0)/IF(TRUE)/' CMakeLists.txt || die
+		fi
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_SHIBBOLETH_SUPPORT="$(usex shibboleth)"
+		-DBUILD_TESTING="$(usex test)"
+	)
+	cmake-utils_src_configure
+}

net-misc/seafile/Manifest

@@ -1,2 +1,3 @@
 DIST seafile-6.0.7.tar.gz 823384 SHA256 e563eade01330bf679f3e6b9f0202b198170cdd8ec80642d9fb670b3a5cda793 SHA512 ec33fbb6b925d4be9b89140d75287115e09f570654946aff994eb50d2ca46e233005b8e0e917682822806d0b5fd70cb9b8a728bb0fd09d124adaadaf3efc849a WHIRLPOOL 8abb588994f06f4d167e1ca55a0e67c742ae7e089a96eb6a438a26fcc59e21b917444e0a8dcb4d099318af79f618a2af2d0a81d3459918ecb2f768b788a11b1f
 DIST seafile-6.1.0.tar.gz 823289 SHA256 06871c6b2ecf27c5c87329b5be03b5aba37cf7c6a4cc81867d3d8451c4ecfb0f SHA512 ccf2c66288093da7a00c24d019a1d765c6072485584d045b0d7acec4faee3448f52448113976eaf63950b1feda2c08d8ebda274f3178ca8ca6c643a822dde3fa WHIRLPOOL 4175bf1df72b83b6eb06e085c9191fe743a2a4310aea929da993c95b69eccab040f072fe4eed968e55783c5151601bbddfc8830815c95b855cfefa5185c3016b
+DIST seafile-6.1.3.tar.gz 823078 SHA256 bcd6e363dc3e1727b1cbf1c889724ffff6e4002c507745445d6fd623faf7d47e SHA512 c8c046952d5c8910f0ba444cdcaa2659260d328ba6449099777850e7d04f494186c56a2fd00e43fd20372c817d977e1a2fe36be040521ca92742c48d83d0b777 WHIRLPOOL 38a5678fce8e2149a546c7219da1b323b1eccf11662b6aabb25f0e714c28fe68d572c6f7934eb7e0f1a402be8d7cf0c9032a4b9f8f4051b57eba81eeef1968a3

net-misc/seafile/seafile-6.1.3.ebuild

@@ -0,0 +1,43 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+inherit autotools python-single-r1 vala
+
+DESCRIPTION="File syncing and sharing software with file encryption and group sharing"
+HOMEPAGE="https://github.com/haiwen/seafile/ http://www.seafile.com/"
+SRC_URI="https://github.com/haiwen/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+-with-openssl-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	net-libs/libsearpc[${PYTHON_USEDEP}]
+	=net-libs/ccnet-${PV}[${PYTHON_USEDEP}]
+	>=dev-libs/glib-2.16.0:2
+	>=dev-libs/libevent-2.0
+	>=dev-libs/jansson-2.2.1
+	>=sys-libs/zlib-1.2.0
+	>=net-misc/curl-7.17
+	dev-libs/openssl:0=
+	dev-db/sqlite:3"
+DEPEND="${RDEPEND}
+	$(vala_depend)"
+
+src_prepare() {
+	default
+	sed -i -e 's/valac /${VALAC} /' lib/Makefile.am || die
+	eautoreconf
+	vala_src_prepare
+}
+
+src_install() {
+	default
+	# Remove unnecessary .la files, as recommended by ltprune.eclass
+	find "${ED}" -name '*.la' -delete || die
+	python_fix_shebang "${ED}"usr/bin
+}