verbs.lexc

!! Verb inflection
!  ---------------
!! The Mohawk language verbs inflect in persons.

LEXICON Verbs
<0:ppStart> SimplePresent ;

LEXICON SimplePresent
BoundPronounActive   ; !! red prefixes f
+AgentSg3Neuter:0 BoundPronounPassive  ; !! blue prefixes
 BoundPronounRelation   ; !! purple prefixes


!!------------------ ACTIVE VERBS (RED PREFIXES) --------------
LEXICON BoundPronounActive
+AgentSg1:ke EndActive   ;
+AgentSg2:se EndActive   ;
+AgentSg3Mal:ra EndActive   ;
+AgentSg3Fem:ye EndActive   ;
+AgentSg3Neuter:ka EndActive   ;
+AgentDu21:teni EndActive   ;
+AgentDu31:yakeni EndActive   ;
+AgentDu2:seni EndActive   ;
+AgentDu3:ni EndActive    ;
+AgentDu3Fem:keni EndActive   ;
+AgentPl2Sg1:tewa EndActive   ;
+AgentPl3Sg1:yakwa EndActive   ;
+AgentPl2:sewa EndActive   ;
+AgentPl3:rati EndActive   ;
+AgentPl3Fem:konti EndActive   ;

LEXICON EndActive
+PatSg3Neuter+:0 VerbStem   ; !! put a neutral patient for all active verbs

!!------------------ PASSIVE VERBS (BLUE PREFIXES) --------------
LEXICON BoundPronounPassive
+PatSg1:wake EndPassive   ;
+PatSg2:sa EndPassive   ;
+PatSg3Mal:ro EndPassive   ;
+PatSg3Fem:yako EndPassive   ;
+PatSg3Neuter:yo EndPassive   ; 
+PatDu21:yonkeni EndPassive   ;
+PatDu31:yonkeni EndPassive   ; 
+PatDu2:seni EndPassive   ; 
+PatDu3:roti EndPassive   ;
+PatDu3Fem:yoti EndPassive   ;
+PatPl2Sg1:yonkwa EndPassive   ;
+PatPl3Sg1:yonkwa EndPassive   ;
+PatPl2:sewa EndPassive   ;
+PatPl3:roti EndPassive   ;
+PatPl3Fem:yoti EndPassive   ;

LEXICON EndPassive
+:0 VerbStem   ; !! put a tag boundary marker to improve readability

!!------------------ RELATION OR TRANSITIVE VERBS (PURPLE PREFIXES) --------------
LEXICON BoundPronounRelation
+AgentSg1:0 RelationPronI   ;
+AgentSg2:0 RelationPronYou   ;

LEXICON RelationPronI
+PatSg2:kon EndRelation   ;
+PatSg3Mal:ri EndRelation   ;
+PatSg3Fem:khe EndRelation   ;


LEXICON RelationPronYou
+PatSg1:take EndRelation   ;
+PatSg3Mal:etshe EndRelation   ;
+PatSg3Fem:she EndRelation   ;


LEXICON EndRelation
+:0 VerbStem   ; !! put a tag boundary marker to improve readability


! vim: set ft=xfst-lexc: