File upload

[nojaf]

It would be nice if we have some helper methods when uploading files.

Based on the aspnet core docs and this stackoverflow issue I came up with this but it the code isn't all that nice.

[dustinmoris]

Hi, just to let you know I will look at your example later this evening and pick this one up next!

[nojaf]

Thanks!

[dustinmoris]

Hi,

I spent some time looking into this and I created an example in the SampleApp. I have added two new HTTP POST endpoints, one for small file uploads and another for large file uploads:

POST >=>
    choose [
        route "/small-upload" >=> smallFileUploadHandler
        route "/large-upload" >=> largeFileUploadHandler ]

Then I implemented two handlers to deal with small and large file uploads:

open System.Threading
open Microsoft.AspNetCore.Http.Features

let smallFileUploadHandler =
    fun (ctx : HttpContext) ->
        async {
            return!
                (match ctx.Request.HasFormContentType with
                | false -> setStatusCode 400 >=> text "Bad request"
                | true  ->
                    ctx.Request.Form.Files
                    |> Seq.fold (fun acc file -> sprintf "%s\n%s" acc file.FileName) ""
                    |> text) ctx
        }

let largeFileUploadHandler =
    fun (ctx : HttpContext) ->
        async {
            let formFeature = ctx.Features.Get<IFormFeature>()
            let! form = formFeature.ReadFormAsync CancellationToken.None |> Async.AwaitTask
            return!
                (form.Files
                |> Seq.fold (fun acc file -> sprintf "%s\n%s" acc file.FileName) ""
                |> text) ctx
        }

I used the built in features form ASP.NET Core. For small file uploads you can directly access the files by calling ctx.Request.Form.Files, which returns an IFormCollection where each item is of type IFormFile. This matches exactly what you would get by injecting an IFormFile object into an MVC action as shown in the documented example for small file uploads.

For large file uploads there is an existing IFormFeature inside the Microsoft.AspNetCore.Http.Features namespace that you can use to stream large files. The original implementation can be found here and as you can see, it does exactly what has been described in the documentation for large file uploads.

It uses the MultipartReader to read each section and a KeyValueAccumulator to store the streamed data.

What do you think of my two examples? Is there something you would like to add or extend from a Giraffe point of view?

[nojaf]

Hi, thanks for these examples. They are great! I had no idea that it could be this easy to process files.
I was able to reduce my own code from 90 lines to 15.

I don't think Giraffe itself needs any extension to work with files.