-
Notifications
You must be signed in to change notification settings - Fork 21
/
demo.v
238 lines (144 loc) · 5.21 KB
/
demo.v
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
Require Import ssreflect ssrfun.
(* 1 : ring and additive sg ================================================================= *)
Module Example1.
Module ASG.
Axiom laws : forall T, T -> (T -> T -> T) -> Prop.
Record mixin_of A := Mixin {
zero : A;
plus : A -> A -> A;
_ : laws A zero plus;
}.
Record class_of (A : Type) := Class {
mixin : mixin_of A
}.
Structure type := Pack {
sort : Type;
class : class_of sort
}.
Notation Make T m := (Pack T (Class _ m)).
Module Exports.
Coercion sort : type >-> Sortclass.
Definition plus {A : type} := plus _ (mixin _ (class A)).
Definition zero {A : type} := zero _ (mixin _ (class A)).
End Exports.
End ASG.
Export ASG.Exports.
Check fun x : _ => plus x zero = x. (* _ is a ASG.type *)
Module RING.
Axiom from_asg_laws : forall T : ASG.type, T -> (T -> T -> T) -> Prop.
Record mixin_of (A : ASG.type) := Mixin {
one : A;
times : A -> A -> A;
_ : from_asg_laws A one times;
}.
Record class_of (A : Type) := Class {
base : ASG.class_of A;
mixin : mixin_of (ASG.Pack A base)
}.
Structure type := Pack {
sort : Type;
class : class_of sort
}.
Definition pack (T : Type) (asg : ASG.type) (m : mixin_of asg) :=
fun b of phant_id (ASG.class asg) b =>
fun m' of phant_id m m' =>
Pack T (Class _ b m').
Notation Make T m := (pack T _ m _ idfun _ idfun).
Module Exports.
Definition times {A : type} := times _ (mixin _ (class A)).
Definition one {A : type} := one _ (mixin _ (class A)).
Coercion sort : type >-> Sortclass.
Definition asgType (R : type) : ASG.type := ASG.Pack R (base R (class R)).
Coercion asgType : type >-> ASG.type.
Canonical asgType. (* RING.sort ? = ASG.sort ? *)
End Exports.
End RING.
Export RING.Exports.
Check fun x : _ => times x one = x. (* _ is a RING.type *)
(* requires the Canonical asgType. *)
Check fun (r : RING.type) (x : r) => plus x one = x. (* x is both in a ring and a group *)
Axiom N_asg : ASG.laws nat 0 Nat.add.
Canonical NasgType := ASG.Make nat (ASG.Mixin _ _ _ N_asg).
Axiom N_ring : RING.from_asg_laws _ 1 Nat.mul.
Canonical NringType := RING.Make nat (RING.Mixin _ _ _ N_ring).
Check fun n : nat => plus 1 (times 0 n) = n.
End Example1.
Module Example1_meta.
Module ASG_input.
Axiom laws : forall T, T -> (T -> T -> T) -> Prop.
Record from_type A := FromType { (* from scratch *)
zero : A;
plus : A -> A -> A;
_ : laws A zero plus;
}.
End ASG_input.
(* declare_structure ASG_input.mixin_of *)
Module ASG.
Record class_of (A : Type) := Class {
mixin : ASG_input.from_type A (* TODO: inline *)
}.
Structure type := Pack {
sort : Type;
class : class_of sort
}.
Module Exports.
Coercion sort : type >-> Sortclass.
Definition plus {A : type} := ASG_input.plus _ (mixin _ (class A)).
Definition zero {A : type} := ASG_input.zero _ (mixin _ (class A)).
End Exports.
End ASG.
(* declare_factory ASG_input.from_type *)
Module ASG_Make.
Notation from_type T m := (ASG.Pack T (ASG.Class _ m)).
End ASG_Make.
Export ASG.Exports.
(* test *)
Check fun x : _ => plus x zero = x. (* _ is a ASG.type *)
Module RING_input.
Axiom from_asg_laws : forall T : ASG.type, T -> (T -> T -> T) -> Prop.
Record from_asg (A : ASG.type) := FromAsg {
one : A;
times : A -> A -> A;
_ : from_asg_laws A one times;
}.
End RING_input.
(* declare_structure base: ASG mix: RING_input.from_asg *)
Module RING.
Record class_of (A : Type) := Class {
base : ASG.class_of A;
mixin : RING_input.from_asg (ASG.Pack A base)
}.
Structure type := Pack {
sort : Type;
class : class_of sort
}.
Module Exports.
Definition times {A : type} := RING_input.times _ (mixin _ (class A)).
Definition one {A : type} := RING_input.one _ (mixin _ (class A)).
Coercion sort : type >-> Sortclass.
Definition asgType (R : type) : ASG.type := ASG.Pack R (base R (class R)).
Coercion asgType : type >-> ASG.type.
Canonical asgType. (* RING.sort ? = ASG.sort ? *)
End Exports.
End RING.
Export RING.Exports.
(* declare_factory RING_input.from_asg *)
Module RING_Make.
Definition pack_from_asg (T : Type) (asg : ASG.type) (m : RING_input.from_asg asg) :=
fun asg' of phant_id (ASG.sort asg') T => (* (T : Type) = (sort asg' : Type) *)
fun b' of phant_id (ASG.class asg') b' => (* (b' : class_of T) = (class asg' : class_of T) *)
fun m' of phant_id m m' => (* (m' : from_asg asg') = (m : from_asg asg)
because the C provided in the type of (m : frmo_asg C)
may not be the canonical one, so we unify m and m' hence,
it will unify their types that contain asg and asg' *)
RING.Pack T (RING.Class _ b' m').
Notation from_asg T m := (pack_from_asg T _ m _ idfun _ idfun _ idfun).
End RING_Make.
Check fun x : _ => times x one = x. (* _ is a RING.type *)
Check fun (r : RING.type) (x : r) => plus x one = x. (* x is both in a ring and a group *)
Axiom N_asg : ASG_input.laws nat 0 Nat.add.
Canonical NasgType := ASG_Make.from_type nat (ASG_input.FromType _ _ _ N_asg).
Axiom N_ring : RING_input.from_asg_laws _ 1 Nat.mul.
Canonical NringType := RING_Make.from_asg nat (RING_input.FromAsg _ _ _ N_ring).
Check fun n : nat => plus 1 (times 0 n) = n.
End Example1_meta.