-
Notifications
You must be signed in to change notification settings - Fork 0
/
xcsp.pi
2322 lines (2177 loc) · 94.3 KB
/
xcsp.pi
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
import sat, util.
/****************************************************************************
xcsp.pi, Neng-Fa Zhou, 2018, 2019, 2022.
Thanks to Hakan Kjellerstrand for testing this interpreter, to Christophe Lecoutre
and Olivier Roussel for many clarifications about the XCSP specification.
This is an interpreter for the XCSP language (www.xcsp.org) written in Picat (picat-lang.org).
This program assumes correct syntax, and thus does not detect syntax errors. Also, it assumes
that no operators or keywords are used as identifiers.
Given an XCSP instance, say "nqueens_8.xml", this program can be run as follows:
Picat> cl("xcsp")
Picat> main("nqueens_8")
Alternatively, this program can be run as a standalone command:
picat xcsp nqueens_8
/*********************************************************************/
main(InFile),string(InFile) =>
xcsp2picat(InFile).
main([InFile]),string(InFile) =>
xcsp2picat(InFile).
main(Args) =>
throw($invalid_args(Args)).
xcsp2picat(InFile) =>
(append(MainFileStr,".xml",InFile) ->
CSPFile = InFile
;
MainFileStr = InFile,
CSPFile = InFile ++ ".xml"
),
println("c xcsp_picat version 3.2#5 (7/5/2022)"),
% printf("c converting %s\n",CSPFile),
bp.c_set_eolcom_flag(0), % treat % as a token
InStream = open(CSPFile,read),
catch(parse_xcsp_xml(InStream),Exception,(printf("c exception occurred %w\n",Exception), halt)),
close(InStream),
bp.c_set_eolcom_flag(1).
parse_xcsp_xml(InStream) ?=>
VarMap = new_map(),
read_next_key_token(InStream,Token),
once(parse_sections(InStream,Token,VarMap,Objs)),
(var(Objs) -> Objs = []; true),
AllVars = vars([Val : (_Key=Val) in VarMap]),
DVars = [Var : Var in AllVars, dvar(Var)],
% println("c conversion successful!"),!,
solve_xcsp(Objs,DVars,VarMap).
parse_xcsp_xml(_InStream) =>
println("c failed before solving."),
println("s UNSATISFIABLE").
%%%
solve_xcsp([],Vars,VarMap) =>
(solve(Vars) ->
Header = "s SATISFIABLE",
output_sol(Header,VarMap)
;
println("s UNSATISFIABLE")
).
solve_xcsp(Objs@[min(Exp)],Vars,VarMap) =>
Header1 = "s SATISFIABLE",
(solve($[report((is(O,Exp),printf("o %w\n",O),output_sol(Header1,VarMap)))|Objs],Vars) ->
Header2 = "s OPTIMUM FOUND",
output_sol(Header2,VarMap)
;
println("s UNSATISFIABLE")
).
solve_xcsp(Objs@[max(Exp)],Vars,VarMap) =>
Header1 = "s SATISFIABLE",
(solve($[report((is(O,Exp),printf("o %w\n",O),output_sol(Header1,VarMap)))|Objs],Vars) ->
Header2 = "s OPTIMUM FOUND",
output_sol(Header2,VarMap)
;
println("s UNSATISFIABLE")
).
solve_xcsp(Objs,_Vars,_VarMap) =>
printf("c multi-objective optimization unsupported %w\n",Objs).
%%%
output_sol(Header,VarMap) =>
println(Header),
println("v <instantiation>"),
List = map_to_list(VarMap),
print("v <list> "),
foreach ((Key=Val) in List)
print(Key),
output_subscripts(Val),
print(" ")
end,
println(" </list> "),
print("v <values> "),
foreach ((_Key=Val) in List)
output_val(Val),
print(" ")
end,
println(" </values> "),
println("v </instantiation>"),
flush.
output_subscripts(Arr),compound(Arr) =>
print("[]"),
output_subscripts(Arr[1]).
output_subscripts(_Arr) => true.
output_val(T), compound(T) =>
foreach (I in 1..len(T))
output_val(T[I])
end.
output_val(T), integer(T) =>
print(T), print(" ").
output_val(_T) =>
print('*'), print(" ").
%%%
/*
parse_sections(_InStream,KeyToken,_VarMap,_Objs) ?=>
writeln(KeyToken),
fail.
*/
parse_sections(_InStream,end_of_file,_VarMap,_Objs) => true.
parse_sections(InStream,variables,VarMap,Objs) =>
read_next_key_token(InStream,KeyToken),
parse_variables(InStream,KeyToken,VarMap,Objs).
parse_sections(InStream,constraints,VarMap,Objs) =>
read_next_key_token(InStream,KeyToken),
parse_constrs(InStream,KeyToken,VarMap),
read_next_key_token(InStream,KeyToken2),
parse_sections(InStream,KeyToken2,VarMap,Objs).
parse_sections(InStream,objectives,VarMap,Objs) =>
read_next_key_token(InStream,KeyToken),
parse_objectives(InStream,KeyToken,VarMap,Objs).
parse_sections(_InStream,_,_VarMap,_Objs) =>
true.
%%%
parse_variables(InStream,var,VarMap,Objs) => % <var id = Name .../>
read_picat_token(InStream,_,Attr),
parse_var_attrs(InStream,Attr,_VarName,_Alias,VarMap),
read_next_key_token(InStream,NextKeyToken),
parse_variables(InStream,NextKeyToken,VarMap,Objs).
parse_variables(InStream,array,VarMap,Objs) => % <array id = Name .../>
read_picat_token(InStream,_,Attr),
parse_arr_attrs(InStream,Attr,_ArrName,_Alias,_Dims,_Arr,VarMap),
read_next_key_token(InStream,NextKeyToken),
parse_variables(InStream,NextKeyToken,VarMap,Objs).
parse_variables(InStream,KeyToken,VarMap,Objs) =>
parse_sections(InStream,KeyToken,VarMap,Objs).
%%%% (id = ArrName | as = Alias | size = Size)*
parse_arr_attrs(InStream,id,ArrName,Alias,Dims,Arr,VarMap) =>
read_picat_token(InStream,_,_), % =
read_picat_token(InStream,_,ArrNameStr),
ArrName = to_atom(ArrNameStr),
read_picat_token(InStream,_,NextAttr),
parse_arr_attrs(InStream,NextAttr,ArrName,Alias,Dims,Arr,VarMap).
parse_arr_attrs(InStream,as,ArrName,Alias,Dims,Arr,VarMap) =>
read_picat_token(InStream,_,_), % =
read_picat_token(InStream,_,AliasStr),
Alias = to_atom(AliasStr),
read_picat_token(InStream,_,NextAttr),
parse_arr_attrs(InStream,NextAttr,ArrName,Alias,Dims,Arr,VarMap).
parse_arr_attrs(InStream,size,ArrName,Alias,Dims,Arr,VarMap) =>
read_picat_token(InStream,_,_), % =
read_picat_token(InStream,_,DimStr), % "[D1][D2]...[Dn]"
DimTokens = split(DimStr,"[] \t\r\n"), % ["D1","D2",...,"Dn"]
Dims = [to_int(DimToken) : DimToken in DimTokens],
Arr = construct_array(Dims),
read_picat_token(InStream,_,NextAttr),
parse_arr_attrs(InStream,NextAttr,ArrName,Alias,Dims,Arr,VarMap).
parse_arr_attrs(_InStream,'/>',ArrName,Alias,Dims,Arr,VarMap) => % nonvar(Alias) must be true
AliasArr = VarMap.get(Alias),
(var(Arr) ->
get_array_dims(AliasArr,Dims),
Arr = construct_array(Dims)
;
true
),
same_array_domains(Arr,AliasArr),
VarMap.put(ArrName,Arr).
parse_arr_attrs(InStream,'>',ArrName,_Alias,Dims,Arr,VarMap) => % var(Alias) is true
VarMap.put(ArrName,Arr),
read_picat_token(InStream,_,Token1),
(start_int(Token1) ->
parse_intExps(InStream,Token1,VarMap,Dom,Dom),
bp.'::'(vars(Arr),Dom), % Arr :: Dom,
skip_until_1(InStream,'>') % skip until array>
;
read_picat_token(InStream,_,NextKeyToken), % NextKeyToken = domain
parse_arr_mixed_doms(InStream,Dims,Arr,NextKeyToken,VarMap)
).
parse_arr_attrs(InStream,_Attr,ArrName,Alias,Dims,Arr,VarMap) => % ignore this attr
read_picat_token(InStream,_,_), % =
read_picat_token(InStream,_,_),
read_picat_token(InStream,_,NextAttr),
parse_arr_attrs(InStream,NextAttr,ArrName,Alias,Dims,Arr,VarMap).
/*
parse_arr_mixed_doms(InStream,Dims,Arr,KeyToken,VarMap) ?=>
writeln($parse_arr_mixed_doms(InStream,Dims,KeyToken,VarMap)),fail.
*/
parse_arr_mixed_doms(InStream,Dims,Arr,domain,VarMap) =>
read_picat_token(InStream,_,_T1), % for
read_picat_token(InStream,_,_T2), % =
read_picat_token(InStream,_,SubscriptsStr), % like "z [][0..1][] z [][2][2..4] "
% writeln((_T1,_T2,SubscriptsStr)),
my_split(SubscriptsStr,SubscriptsTokens), % similar to split, but keeps "[" and "]" as tokens
skip_until_1(InStream,'>'),
read_picat_token(InStream,_,NextToken),
parse_intExps(InStream,NextToken,VarMap,Dom,Dom),
parse_arr_domain_subscripts(Dims,Arr,SubscriptsTokens,Dom),
skip_until_1(InStream,'>'), % skip </ domain>
read_next_key_token(InStream,NextKeyToken), % domain declarations
parse_arr_mixed_doms(InStream,Dims,Arr,NextKeyToken,VarMap).
parse_arr_mixed_doms(InStream,_Dims,_Arr,_KeyToken,_VarMap) =>
skip_until_1(InStream,'>'). % skip </ array>
/*
parse_arr_domain_subscripts(Dims,Arr,SubscriptsTokens,Dom) ?=>
writeln($parse_arr_domain_subscripts(Dims,Arr,SubscriptsTokens,Dom)),fail.
*/
parse_arr_domain_subscripts(_Dims,_Arr,[],_Dom) => true.
parse_arr_domain_subscripts(Dims,Arr,["others"],Dom) =>
dom_constr_others(Dims,Arr,Dom).
parse_arr_domain_subscripts(Dims,Arr,[_ArrNameStr|Tokens],Dom) =>
extract_subscripts(Dims,Tokens,TokensR,Ranges),
dom_constr_subarray(Ranges,Arr,Dom),
parse_arr_domain_subscripts(Dims,Arr,TokensR,Dom).
/*
extract_subscripts(_,Tokens,TokensR,Ranges) ?=>
writeln($extract_subscripts(_,Tokens,TokensR,Ranges)),fail.
*/
extract_subscripts([],Tokens,TokensR,Ranges) =>
Tokens = TokensR,
Ranges = [].
extract_subscripts([Dim|Dims],["[","]"|Tokens],TokensR,Ranges) =>
Ranges = [(1,Dim)|RangesR],
extract_subscripts(Dims,Tokens,TokensR,RangesR).
extract_subscripts([_Dim|Dims],["[",FromToken,"..",ToToken,_RBracketToken|Tokens],TokensR,Ranges) => % [From..To]
From = to_int(FromToken)+1, % array indices are 1-based in Picat
To = to_int(ToToken)+1,
Ranges = [(From,To)|RangesR],
extract_subscripts(Dims,Tokens,TokensR,RangesR).
extract_subscripts([_Dim|Dims],["[",IndexToken,_RBracketToken|Tokens],TokensR,Ranges) => % [I]
Index = to_int(IndexToken)+1,
Ranges = [(Index,Index)|RangesR],
extract_subscripts(Dims,Tokens,TokensR,RangesR).
dom_constr_others([],Var,_Dom), dvar_or_int(Var) => true.
dom_constr_others([],Var,Dom) => % Var is a plain variable
bp.'::'(Var,Dom).
dom_constr_others([Dim|Dims],Arr,Dom) =>
foreach (I in 1..Dim)
dom_constr_others(Dims,Arr[I],Dom)
end.
dom_constr_subarray([],Var,Dom) => bp.'::'(Var,Dom).
dom_constr_subarray([(From,To)|Ranges],Arr,Dom) =>
foreach (I in From..To)
dom_constr_subarray(Ranges,Arr[I],Dom)
end.
%%%% (id = VarName | as = Alias | type = _)+
parse_var_attrs(InStream,id,VarName,Alias,VarMap) =>
read_picat_token(InStream,_,_), % =
read_picat_token(InStream,_,VarNameStr),
VarName = to_atom(VarNameStr),
read_picat_token(InStream,_,NextAttr),
parse_var_attrs(InStream,NextAttr,VarName,Alias,VarMap).
parse_var_attrs(InStream,as,VarName,Alias,VarMap) =>
read_picat_token(InStream,_,_), % =
read_picat_token(InStream,_,AliasStr),
Alias = to_atom(AliasStr),
read_picat_token(InStream,_,NextAttr),
parse_var_attrs(InStream,NextAttr,VarName,Alias,VarMap).
parse_var_attrs(_InStream,'/>',VarName,Alias,VarMap) => % </variable>, Alias must be nonvar
DVar0 = VarMap.get(Alias),
same_domains(DVar,DVar0),
VarMap.put(VarName,DVar).
parse_var_attrs(InStream,'>',VarName,_Alias,VarMap) => % Alias must be var
read_picat_token(InStream,_,Token),
parse_intExps(InStream,Token,VarMap,Dom,Dom),
bp.'::'(DVar, Dom),
VarMap.put(VarName,DVar),
skip_until_1(InStream,'>').
parse_var_attrs(InStream,_Attr,VarName,Alias,VarMap) => % ignore this attr
read_picat_token(InStream,_,_), % =
read_picat_token(InStream,_,_),
read_picat_token(InStream,_,NextAttr),
parse_var_attrs(InStream,NextAttr,VarName,Alias,VarMap).
%%%%
/*
parse_constrs(_InStream,Token,_VarMap) ?=>
writeln($parse_constrs(Token)),fail.
*/
parse_constrs(InStream,constraints,_VarMap) =>
skip_until_1(InStream,'>'). % skip until after </constraints>
parse_constrs(InStream,slide,VarMap) =>
read_picat_token(InStream,_,Token),
parse_slide_circular(InStream,Token,Circular),
parse_slide(InStream,VarMap,Circular),
read_next_key_token(InStream,NextKeyToken),
parse_constrs(InStream,NextKeyToken,VarMap).
parse_constrs(InStream,group,VarMap) =>
skip_until_1(InStream,'>'), % skip until after group>
read_next_key_token(InStream,KeyToken1),
parse_constr(InStream,KeyToken1,VarMap,Constr),
read_next_key_token(InStream,KeyToken2),
max_param_num(Constr,0,MaxParamNum),
parse_group_args(InStream,KeyToken2,VarMap,Constr,MaxParamNum),
skip_until_1(InStream,'>'), % skip until after </group>
read_next_key_token(InStream,KeyToken3),
parse_constrs(InStream,KeyToken3,VarMap).
parse_constrs(InStream,block,VarMap) => % blocks are ignored
skip_until_1(InStream,'>'),
read_next_key_token(InStream,KeyToken),
parse_constrs(InStream,KeyToken,VarMap).
parse_constrs(InStream,Token,VarMap) =>
parse_constr(InStream,Token,VarMap,Constr),
(post_constr(Constr) -> true; printf("c failed while posting %w\n",Constr),fail),
read_next_key_token(InStream,KeyToken),
parse_constrs(InStream,KeyToken,VarMap).
parse_constr(InStream,extension,VarMap,Constr) =>
skip_until_1(InStream,'>'), % skip until after extension>
parse_extension_constr(InStream,VarMap,Constr).
parse_constr(InStream,intension,VarMap,Constr) =>
skip_until_1(InStream,'>'), % skip until after intension>
read_picat_token(InStream,_,Token),
parse_intension_constr(InStream,Token,VarMap,Constr).
parse_constr(InStream,regular,VarMap,Constr) =>
skip_until_1(InStream,'>'), % skip until after regular>
parse_regular_constr(InStream,VarMap,Constr).
parse_constr(InStream,grammar,_VarMap,Constr) =>
printf(stderr,"c unknown constraint %w\n",grammar),
Constr = (1 #= 1),
skip_until_2(InStream,'</',grammar),
skip_until_1(InStream,'>').
parse_constr(InStream,mdd,VarMap,Constr) =>
skip_until_1(InStream,'>'), % skip until after regular>
parse_mdd_constr(InStream,VarMap,Constr).
parse_constr(InStream,allDifferent,VarMap,Constr) =>
skip_until_1(InStream,'>'), % skip until after allDifferent>
read_picat_token(InStream,_,Token),
parse_allDifferent_constr(InStream,Token,VarMap,Constr).
parse_constr(InStream,allEqual,VarMap,Constr) =>
skip_until_1(InStream,'>'), % skip until after allEqual>
read_picat_token(InStream,_,Token),
parse_allEqual_constr(InStream,Token,VarMap,Constr).
parse_constr(InStream,allDistant,VarMap,Constr) =>
skip_until_1(InStream,'>'), % skip until after allDistant>
read_picat_token(InStream,_,Token),
parse_allDistant_constr(InStream,Token,VarMap,Constr).
parse_constr(InStream,ordered,VarMap,Constr) =>
skip_until_1(InStream,'>'), % skip until after allEqual>
read_picat_token(InStream,_,Token),
parse_ordered_constr(InStream,Token,VarMap,Constr).
parse_constr(InStream,cardinality,VarMap,Constr) =>
skip_until_1(InStream,'>'), % skip until after cardinality>
parse_cardinality_constr(InStream,VarMap,Constr).
parse_constr(InStream,maximum,VarMap,Constr) =>
skip_until_1(InStream,'>'), % skip until after maximum>
read_picat_token(InStream,_,Token),
parse_minmax_constr(InStream,Token,VarMap,max,Constr).
parse_constr(InStream,minimum,VarMap,Constr) =>
skip_until_1(InStream,'>'), % skip until after minimum>
read_picat_token(InStream,_,Token),
parse_minmax_constr(InStream,Token,VarMap,min,Constr).
parse_constr(InStream,sum,VarMap,Constr) =>
skip_until_1(InStream,'>'), % skip until after sum>
read_picat_token(InStream,_,Token),
parse_sum_constr(InStream,Token,VarMap,Constr).
parse_constr(InStream,count,VarMap,Constr) =>
skip_until_1(InStream,'>'), % skip until after count>
read_picat_token(InStream,_,Token),
parse_count_constr(InStream,Token,VarMap,Constr).
parse_constr(InStream,nValues,VarMap,Constr) =>
skip_until_1(InStream,'>'), % skip until after nValues>
read_picat_token(InStream,_,Token),
parse_nValues_constr(InStream,Token,VarMap,Constr).
parse_constr(InStream,element,VarMap,Constr) =>
skip_until_1(InStream,'>'), % skip until after element>
read_picat_token(InStream,_,_), % <
read_picat_token(InStream,_,Token),
parse_element_constr(InStream,Token,VarMap,Constr).
parse_constr(InStream,channel,VarMap,Constr) =>
skip_until_1(InStream,'>'), % skip until after channel>
read_picat_token(InStream,_,Token),
parse_channel_constr(InStream,Token,VarMap,Constr).
parse_constr(InStream,noOverlap,VarMap,Constr) =>
skip_until_1(InStream,'>'), % skip until after noOverlap>
parse_noOverlap_constr(InStream,VarMap,Constr).
parse_constr(InStream,cumulative,VarMap,Constr) =>
skip_until_1(InStream,'>'), % skip until after cumulative>
parse_cumulative_constr(InStream,VarMap,Constr).
parse_constr(InStream,lex,VarMap,Constr) =>
skip_until_1(InStream,'>'), % skip until after allEqual>
read_picat_token(InStream,_,Token),
parse_lex_constr(InStream,Token,VarMap,Constr).
parse_constr(InStream,circuit,VarMap,Constr) =>
skip_until_1(InStream,'>'), % skip until after circuit>
read_picat_token(InStream,_,Token),
parse_circuit_constr(InStream,Token,VarMap,Constr).
parse_constr(InStream,instantiation,VarMap,Constr) =>
skip_until_1(InStream,'>'), % skip until after instantiation>
read_picat_token(InStream,_,Token),
parse_instantiation_constr(InStream,Token,VarMap,Constr).
parse_constr(InStream,Token,VarMap,Constr) =>
printf("c unrecognized constraint %w\n",Token),
fail.
%%%
/*
parse_group_args(InStream,Token,VarMap,Constr,MaxParamNum) ?=>
writeln($parse_group_args(InStream,Token,VarMap,Constr,MaxParamNum)),fail.
*/
parse_group_args(InStream,args,VarMap,Constr,MaxParamNum) =>
skip_until_1(InStream,'>'), % skip until after <args>
read_picat_token(InStream,_,Token),
parse_list(InStream,Token,VarMap,Args,Args),
take_drop(Args,MaxParamNum,ParamsArr,List),
substitute_constr_args(Constr,ParamsArr,List,Constr1),
(post_constr(Constr1) -> true; printf("c failed while posting %w\n",Constr1), fail),
read_next_key_token(InStream,KeyToken),
parse_group_args(InStream,KeyToken,VarMap,Constr,MaxParamNum).
parse_group_args(_InStream,_Token,_VarMap,_Constr,_MaxParamNum) => % _Token == group
true.
%%%
parse_extension_constr(InStream,VarMap,Constr) =>
skip_until_1(InStream,'>'), % skip until after <list>
read_picat_token(InStream,_,Token),
parse_list(InStream,Token,VarMap,Args,Args),
read_picat_token(InStream,_,_), % <conflicts> or <supports>
read_picat_token(InStream,_,Type),
read_picat_token(InStream,_,_),
read_picat_token(InStream,_,Token2),
parse_tuples(InStream,Token2,VarMap,Tuples,HasStar),
skip_until_1(InStream,'>'), % skip until after </conflicts> or </supports>
skip_until_1(InStream,'>'), % skip until after </extension>
(Args == params -> Scope = params; Scope = to_array(Args)),
Constr = $table(Type,Scope,Tuples,HasStar).
/*
parse_list(InStream,Token,VarMap,Elms0,Elms) ?=>
writeln($parse_list(Token)),fail.
*/
parse_list(InStream,Token,VarMap,Elms0,Elms) => % </list> or </args> ...
parse_intExps(InStream,Token,VarMap,Elms0,Elms),
skip_until_1(InStream,'>'). % skip until after </list>
parse_matrix(InStream,Token,VarMap,Matrix) => %
(Token == '(' ->
parse_tuples(InStream,Token,VarMap,Tuples,_HasStar), % _HasStar not used
Matrix = to_array(Tuples)
;
Matrix = VarMap.get(Token) % x[][]
).
%%%
% for parsing (1) list elements: <list> a b x[] </list>;
% (2) domain items: <var..> 1 3..4 </var>
% (3) unary tables: <supports > 1 2 4 8..10 </ supports >
% (4) cardinatility constraints: <occurs> 1 1..2 </occurs>
/*
parse_intExps(InStream,Token,VarMap,Elms0,Elms) ?=>
writeln($intExps(Token)),fail.
*/
parse_intExps(_InStream,'</',_VarMap,Elms0,Elms) =>
(Elms0 == params ->
true
;
Elms = []
).
parse_intExps(InStream,'%',VarMap,Elms0,Elms) =>
read_picat_token(InStream,_,Token),
(Token == '...' -> % %...
Elms0 = params
;
Index = Token+1,
Elms = [$param(Index)|Elms1] % %1 %2 ...
),
read_picat_token(InStream,_,NextToken),
parse_intExps(InStream,NextToken,VarMap,Elms0,Elms1).
parse_intExps(InStream,'_$xcsp_vx'(Val),VarMap,Elms0,Elms) =>
read_picat_token(InStream,_,K),
duplicate_xk_token(Val,K,Elms,ElmsR),
read_picat_token(InStream,_,NextToken),
parse_intExps(InStream,NextToken,VarMap,Elms0,ElmsR).
parse_intExps(InStream,Token,VarMap,Elms0,Elms), xcsp_start_intExp(Token) =>
parse_intExp(InStream,Token,VarMap,E1),
read_picat_token(InStream,_,Token2),
(int(E1) ->
(Token2 == '..' ->
read_picat_token(InStream,_,Token3),
parse_intExp(InStream,Token3,VarMap,E2),
read_picat_token(InStream,_,NextToken),
construct_range(E1,E2,E),
Elms = [E|ElmsR]
;
NextToken = Token2,
Elms = [E1|ElmsR]
)
;E1 = $'_$xcsp_vx'(Val) ->
K = Token2,
duplicate_xk_token(Val,K,Elms,ElmsR),
read_picat_token(InStream,_,NextToken)
;
NextToken = Token2,
Elms = [E1|ElmsR]
),
parse_intExps(InStream,NextToken,VarMap,Elms0,ElmsR).
parse_intExps(InStream,Token,VarMap,Elms0,Elms) =>
Content = VarMap.get(Token),
(compound(Content) ->
skip_until_1(InStream,'['),
read_picat_token(InStream,_,Token2),
parse_indexing_list(InStream,Content,Token2,Elms,ElmsR)
;
Elms = [Content|ElmsR]
),
read_picat_token(InStream,_,Token3),
parse_intExps(InStream,Token3,VarMap,Elms0,ElmsR).
%%% for parsing tables and matrices
parse_tuples(InStream,'(',VarMap,Tuples,HasStar) => % first tuple
read_picat_token(InStream,_,Token),
parse_first_tuple(InStream,Token,VarMap,Elms,HasStar),
Tuple = to_array(Elms),
N = len(Tuple),
Tuples = [Tuple|TuplesR],
read_picat_token(InStream,_,Token2),
parse_rest_tuples(InStream,N,Token2,VarMap,TuplesR,HasStar).
parse_tuples(_InStream,'</',_VarMap,Tuples,_HasStar) => % empty table
Tuples = [].
parse_tuples(InStream,Token,VarMap,Tuples,_HasStar) => % must be a unary table
parse_intExps(InStream,Token,VarMap,Tuples,Tuples). % 1 3..4 5
parse_first_tuple(InStream,'*',VarMap,Elms,HasStar) =>
(var(HasStar) -> HasStar = [_]; HasStar = [1]), % [_] means one star, [1] means at least two stars
Elms = ['*'|ElmsR],
read_picat_token(InStream,_,Token),
parse_first_tuple(InStream,Token,VarMap,ElmsR,HasStar).
parse_first_tuple(InStream,',',VarMap,Elms,HasStar) =>
read_picat_token(InStream,_,Token),
parse_first_tuple(InStream,Token,VarMap,Elms,HasStar).
parse_first_tuple(_InStream,')',_VarMap,Elms,_HasStar) =>
Elms = [].
parse_first_tuple(InStream,Token,VarMap,Elms,HasStar) =>
parse_intExp(InStream,Token,VarMap,E),
Elms = [E|ElmsR],
read_picat_token(InStream,_,NextToken),
parse_first_tuple(InStream,NextToken,VarMap,ElmsR,HasStar).
parse_rest_tuples(InStream,N,'(',VarMap,Tuples,HasStar) =>
Tuple = new_array(N),
read_picat_token(InStream,_,Token),
parse_tuple(InStream,1,Token,VarMap,Tuple,HasStar),
Tuples = [Tuple|TuplesR],
read_picat_token(InStream,_,NextToken),
parse_rest_tuples(InStream,N,NextToken,VarMap,TuplesR,HasStar).
parse_rest_tuples(_InStream,_N,_Token,_VarMap,Tuples,_HasStar) => % _Token == '<'
Tuples = [].
parse_tuple(InStream,I,'*',VarMap,Tuple,HasStar) =>
(var(HasStar) -> HasStar = [_]; HasStar = [1]), % [_] means one star, [1] means at least two stars
Tuple[I] = '*',
read_picat_token(InStream,_,Token),
parse_tuple(InStream,I+1,Token,VarMap,Tuple,HasStar).
parse_tuple(InStream,I,',',VarMap,Tuple,HasStar) =>
read_picat_token(InStream,_,Token),
parse_tuple(InStream,I,Token,VarMap,Tuple,HasStar).
parse_tuple(_InStream,_I,')',_VarMap,_Tuple,_HasStar) => true.
parse_tuple(InStream,I,Token,VarMap,Tuple,HasStar) => % Token is a number
parse_intExp(InStream,Token,VarMap,E),
Tuple[I] = E,
read_picat_token(InStream,_,NextToken),
parse_tuple(InStream,I+1,NextToken,VarMap,Tuple,HasStar).
%%%
% parse_intension_constr(InStream,Token,VarMap,Constr) ?=> writeln(Token),fail.
parse_intension_constr(InStream,'<',VarMap,Constr) => % <function>
skip_until_1(InStream,'>'), % skip until after <function>
read_picat_token(InStream,_,Token),
parse_boolExp(InStream,Token,VarMap,Constr),
skip_until_1(InStream,'>'), % skip until after </function>
skip_until_1(InStream,'>'). % skip until after </intension>
parse_intension_constr(InStream,Token,VarMap,Constr) =>
parse_boolExp(InStream,Token,VarMap,Constr),
skip_until_1(InStream,'>'). % skip until after </intension>
%%%
parse_boolExp(InStream,lt,VarMap,Exp) => % "lt(" intExp "," intExp ")"
skip_until_1(InStream,'('),
read_picat_token(InStream,_,Token1),
parse_intExp(InStream,Token1,VarMap,Exp1),
skip_until_1(InStream,','),
read_picat_token(InStream,_,Token2),
parse_intExp(InStream,Token2,VarMap,Exp2),
Exp = (Exp1 #< Exp2),
skip_until_1(InStream,')').
parse_boolExp(InStream,le,VarMap,Exp) => % "le(" intExp "," intExp ")"
skip_until_1(InStream,'('),
read_picat_token(InStream,_,Token1),
parse_intExp(InStream,Token1,VarMap,Exp1),
skip_until_1(InStream,','),
read_picat_token(InStream,_,Token2),
parse_intExp(InStream,Token2,VarMap,Exp2),
Exp = (Exp1 #=< Exp2),
skip_until_1(InStream,')').
parse_boolExp(InStream,ge,VarMap,Exp) => % "ge(" intExp "," intExp ")"
skip_until_1(InStream,'('),
read_picat_token(InStream,_,Token1),
parse_intExp(InStream,Token1,VarMap,Exp1),
skip_until_1(InStream,','),
read_picat_token(InStream,_,Token2),
parse_intExp(InStream,Token2,VarMap,Exp2),
Exp = (Exp1 #>= Exp2),
skip_until_1(InStream,')').
parse_boolExp(InStream,gt,VarMap,Exp) => % "gt(" intExp "," intExp ")"
skip_until_1(InStream,'('),
read_picat_token(InStream,_,Token1),
parse_intExp(InStream,Token1,VarMap,Exp1),
skip_until_1(InStream,','),
read_picat_token(InStream,_,Token2),
parse_intExp(InStream,Token2,VarMap,Exp2),
Exp = (Exp1 #> Exp2),
skip_until_1(InStream,')').
parse_boolExp(InStream,ne,VarMap,Exp) => % "ne(" intExp "," intExp ")"
skip_until_1(InStream,'('),
read_picat_token(InStream,_,Token1),
parse_intExp(InStream,Token1,VarMap,Exp1),
skip_until_1(InStream,','),
read_picat_token(InStream,_,Token2),
parse_intExp(InStream,Token2,VarMap,Exp2),
Exp = (Exp1 #!= Exp2),
skip_until_1(InStream,')').
parse_boolExp(InStream,eq,VarMap,Exp) => % "eq(" intExp "," ... ")"
skip_until_1(InStream,'('),
read_picat_token(InStream,_,Token1),
parse_intExp(InStream,Token1,VarMap,Exp1),
read_picat_token(InStream,_,Token2),
parse_intExpsPrime(InStream,Token2,VarMap,Exps),
(Exps = [Exp2] ->
Exp = $(Exp1 #= Exp2)
;
Exp = $eq([Exp1|Exps])
).
parse_boolExp(InStream,in,VarMap,Exp) => % "in(" intExp "," intSet ")"
skip_until_1(InStream,'('),
read_picat_token(InStream,_,Token1),
parse_intExp(InStream,Token1,VarMap,Exp1),
skip_until_1(InStream,','),
read_picat_token(InStream,_,Token2),
parse_intSet(InStream,Token2,VarMap,Exp2),
Exp = $(Exp1 :: Exp2),
skip_until_1(InStream,')').
parse_boolExp(InStream,not,VarMap,Exp) => % "not(" boolExp ")"
skip_until_1(InStream,'('),
read_picat_token(InStream,_,Token1),
parse_boolExp(InStream,Token1,VarMap,Exp1),
Exp = (#~ Exp1),
skip_until_1(InStream,')').
parse_boolExp(InStream,and,VarMap,Exp) => % "and(" boolExp ("," boolExp)+ ")"
skip_until_1(InStream,'('),
read_picat_token(InStream,_,Token1),
parse_boolExp(InStream,Token1,VarMap,Exp1),
read_picat_token(InStream,_,Token2),
parse_boolExpsPrime(InStream,Token2,VarMap,Exps),
Exp = $min([Exp1|Exps]).
parse_boolExp(InStream,or,VarMap,Exp) => % "or(" boolExp ("," boolExp)+ ")"
skip_until_1(InStream,'('),
read_picat_token(InStream,_,Token1),
parse_boolExp(InStream,Token1,VarMap,Exp1),
read_picat_token(InStream,_,Token2),
parse_boolExpsPrime(InStream,Token2,VarMap,Exps),
Exp = $max([Exp1|Exps]).
parse_boolExp(InStream,xor,VarMap,Exp) => % "xor(" boolExp ("," boolExp)+ ")"
skip_until_1(InStream,'('),
read_picat_token(InStream,_,Token1),
parse_boolExp(InStream,Token1,VarMap,Exp1),
read_picat_token(InStream,_,Token2),
parse_boolExpsPrime(InStream,Token2,VarMap,Exps),
construct_xor([Exp1|Exps],Exp).
parse_boolExp(InStream,iff,VarMap,Exp) => % "iff(" boolExp ("," boolExp)+ ")"
skip_until_1(InStream,'('),
read_picat_token(InStream,_,Token1),
parse_boolExp(InStream,Token1,VarMap,Exp1),
read_picat_token(InStream,_,Token2),
parse_boolExpsPrime(InStream,Token2,VarMap,Exps),
construct_iff([Exp1|Exps],Exp).
parse_boolExp(InStream,imp,VarMap,Exp) => % "imp(" boolExp "," boolExp ")"
skip_until_1(InStream,'('),
read_picat_token(InStream,_,Token1),
parse_boolExp(InStream,Token1,VarMap,Exp1),
skip_until_1(InStream,','),
read_picat_token(InStream,_,Token2),
parse_boolExp(InStream,Token2,VarMap,Exp2),
Exp = (Exp1 #=> Exp2),
skip_until_1(InStream,')').
parse_boolExp(InStream,'%',_VarMap,Exp) => % can't be %...
read_picat_token(InStream,_,Token),
Index = Token+1,
Exp = $param(Index).
parse_boolExp(_InStream,Token,_VarMap,Exp), int(Token) => % 0 or 1
Exp = Token.
parse_boolExp(InStream,Token,VarMap,Exp) =>
Content = VarMap.get(Token),
(compound(Content) ->
skip_until_1(InStream,'['),
parse_indexing(InStream,Content,Exp)
;
Exp = Content
).
construct_xor([Exp1,Exp2],Exp) =>
Exp = (Exp1 #^ Exp2).
construct_xor([Exp1,Exp2|Exps],Exp) =>
construct_xor([(Exp1 #^ Exp2)|Exps],Exp).
construct_iff([Exp1,Exp2],Exp) =>
Exp = (Exp1 #<=> Exp2).
construct_iff([Exp1,Exp2|Exps],Exp) =>
construct_iff([(Exp1 #<=> Exp2)|Exps],Exp).
%%%
parse_intExp(InStream,neg,VarMap,Exp) => % "neg(" intExp ")"
skip_until_1(InStream,'('),
read_picat_token(InStream,_,Token),
parse_intExp(InStream,Token,VarMap,Exp1),
skip_until_1(InStream,')'),
Exp = $-Exp1.
parse_intExp(InStream,abs,VarMap,Exp) => % "abs(" intExp ")
skip_until_1(InStream,'('),
read_picat_token(InStream,_,Token),
parse_intExp(InStream,Token,VarMap,Exp1),
skip_until_1(InStream,')'),
Exp = $abs(Exp1).
parse_intExp(InStream,add,VarMap,Exp) => % "add(" intExp ("," intExp)+ ")"
skip_until_1(InStream,'('),
read_picat_token(InStream,_,Token1),
parse_intExp(InStream,Token1,VarMap,Exp1),
read_picat_token(InStream,_,Token2),
parse_intExpsPrime(InStream,Token2,VarMap,Exps),
(Exps = [Exp2] ->
Exp = $(Exp1+Exp2)
;
Exp = $sum([Exp1|Exps])
).
parse_intExp(InStream,sub,VarMap,Exp) => % "sub(" intExp "," intExp ")"
skip_until_1(InStream,'('),
read_picat_token(InStream,_,Token1),
parse_intExp(InStream,Token1,VarMap,Exp1),
skip_until_1(InStream,','),
read_picat_token(InStream,_,Token2),
parse_intExp(InStream,Token2,VarMap,Exp2),
skip_until_1(InStream,')'),
Exp = $(Exp1-Exp2).
parse_intExp(InStream,mul,VarMap,Exp) => % "mul(" intExp ("," intExp)+ ")"
skip_until_1(InStream,'('),
read_picat_token(InStream,_,Token1),
parse_intExp(InStream,Token1,VarMap,Exp1),
read_picat_token(InStream,_,Token2),
parse_intExpsPrime(InStream,Token2,VarMap,Exps),
(Exps = [Exp2] ->
Exp = $(Exp1*Exp2)
;
Exp = $prod([Exp1|Exps])
).
parse_intExp(InStream,div,VarMap,Exp) => % "div(" intExp "," intExp ")"
skip_until_1(InStream,'('),
read_picat_token(InStream,_,Token1),
parse_intExp(InStream,Token1,VarMap,Exp1),
skip_until_1(InStream,','),
read_picat_token(InStream,_,Token2),
parse_intExp(InStream,Token2,VarMap,Exp2),
skip_until_1(InStream,')'),
Exp = $(Exp1 div Exp2).
parse_intExp(InStream,mod,VarMap,Exp) => % "mod(" intExp "," intExp ")"
skip_until_1(InStream,'('),
read_picat_token(InStream,_,Token1),
parse_intExp(InStream,Token1,VarMap,Exp1),
skip_until_1(InStream,','),
read_picat_token(InStream,_,Token2),
parse_intExp(InStream,Token2,VarMap,Exp2),
skip_until_1(InStream,')'),
Exp = $(Exp1 mod Exp2).
parse_intExp(InStream,sqr,VarMap,Exp) => % "sqr(" intExp ")
skip_until_1(InStream,'('),
read_picat_token(InStream,_,Token),
parse_intExp(InStream,Token,VarMap,Exp1),
skip_until_1(InStream,')'),
Exp = $(Exp1*Exp1).
parse_intExp(InStream,pow,VarMap,Exp) => % "pow(" intExp "," intExp ")"
skip_until_1(InStream,'('),
read_picat_token(InStream,_,Token1),
parse_intExp(InStream,Token1,VarMap,Exp1),
skip_until_1(InStream,','),
read_picat_token(InStream,_,Token2),
parse_intExp(InStream,Token2,VarMap,Exp2),
skip_until_1(InStream,')'),
Exp = $(Exp1 ** Exp2).
parse_intExp(InStream,min,VarMap,Exp) => % "min(" intExp ("," intExp)+ ")"
skip_until_1(InStream,'('),
read_picat_token(InStream,_,Token1),
parse_intExp(InStream,Token1,VarMap,Exp1),
read_picat_token(InStream,_,Token2),
parse_intExpsPrime(InStream,Token2,VarMap,Exps),
Exp = $min([Exp1|Exps]).
parse_intExp(InStream,max,VarMap,Exp) => % "max(" intExp ("," intExp)+ ")"
skip_until_1(InStream,'('),
read_picat_token(InStream,_,Token1),
parse_intExp(InStream,Token1,VarMap,Exp1),
read_picat_token(InStream,_,Token2),
parse_intExpsPrime(InStream,Token2,VarMap,Exps),
Exp = $max([Exp1|Exps]).
parse_intExp(InStream,dist,VarMap,Exp) => % "dist(" intExp "," intExp ")"
skip_until_1(InStream,'('),
read_picat_token(InStream,_,Token1),
parse_intExp(InStream,Token1,VarMap,Exp1),
skip_until_1(InStream,','),
read_picat_token(InStream,_,Token2),
parse_intExp(InStream,Token2,VarMap,Exp2),
skip_until_1(InStream,')'),
Exp = $abs(Exp1-Exp2).
parse_intExp(InStream,if,VarMap,Exp) => % "if(" boolExp "," intExp "," intExp ")"
skip_until_1(InStream,'('),
read_picat_token(InStream,_,Token1),
parse_boolExp(InStream,Token1,VarMap,Exp1),
skip_until_1(InStream,','),
read_picat_token(InStream,_,Token2),
parse_intExp(InStream,Token2,VarMap,Exp2),
skip_until_1(InStream,','),
read_picat_token(InStream,_,Token3),
parse_intExp(InStream,Token3,VarMap,Exp3),
skip_until_1(InStream,')'),
Exp = $cond(Exp1,Exp2,Exp3).
parse_intExp(InStream,'+',_VarMap,Exp) =>
read_picat_token(InStream,_,Token), % must be an int
Exp = Token.
parse_intExp(InStream,'-',_VarMap,Exp) =>
read_picat_token(InStream,_,Token), % must be an int or '_$xcsp_vx'(Val)
(Token = $'_$xcsp_vx'(Val) ->
Val1 is -Val,
Exp = $'_$xcsp_vx'(Val1)
;
Exp = -Token
).
parse_intExp(_InStream,'*',_VarMap,Exp) => % in <instantiation>...</instantiation>
Exp = '*'.
parse_intExp(InStream,'%',_VarMap,Exp) =>
read_picat_token(InStream,_,Token), % must be an int
Index = Token+1,
Exp = $param(Index).
parse_intExp(_InStream,Token@'_$xcsp_vx'(_),_VarMap,Exp) =>
Exp = Token.
parse_intExp(_InStream,Token,_VarMap,Exp), int(Token) =>
Exp = Token.
parse_intExp(InStream,Token,VarMap,Exp) =>
(bool_rel(Token) ->
parse_boolExp(InStream,Token,VarMap,Exp)
;
Content = VarMap.get(Token),
(compound(Content) ->
skip_until_1(InStream,'['),
parse_indexing(InStream,Content,Exp)
;
Exp = Content
)
).
% ("," intExp)+ ")"
parse_intExpsPrime(InStream,Token,VarMap,Exps) =>
(Token == ',' ->
Exps = [Exp|ExpsR],
read_picat_token(InStream,_,Token1),
parse_intExp(InStream,Token1,VarMap,Exp),
read_picat_token(InStream,_,Token2),
parse_intExpsPrime(InStream,Token2,VarMap,ExpsR)
;
Exps = [] % Token == ')'
).
% ("," boolExp)+ ")"
parse_boolExpsPrime(InStream,Token,VarMap,Exps) =>
(Token == ',' ->
Exps = [Exp|ExpsR],
read_picat_token(InStream,_,Token1),
parse_boolExp(InStream,Token1,VarMap,Exp),
read_picat_token(InStream,_,Token2),
parse_boolExpsPrime(InStream,Token2,VarMap,ExpsR)
;
Exps = [] % Token == ')'
).
parse_indexing(InStream,Arr,Exp) =>
read_picat_token(InStream,_,Index), % must be an int
skip_until_1(InStream,']'),
E = Arr[Index+1], % indexing is 1-based in Picat
(compound(E) ->
skip_until_1(InStream,'['),
parse_indexing(InStream,E,Exp)
;
Exp = E
).
%%%
% x[][4] x[2..3] x[1], have observed x[
parse_indexing_list(InStream,Arr,Token,List,ListR) =>
get_array_dims(Arr,Dims),
parse_indexing_subscripts(InStream,Dims,Token,Ranges),
access_array(Arr,Ranges,List,ListR).
parse_indexing_subscripts(InStream,[Dim|Dims],Token,Ranges) =>
parse_indexing_subscript(InStream,Dim,Token,Range),
(Dims == [] ->
Ranges = [Range]
;
Ranges = [Range|RangesR],
skip_until_1(InStream,'['),
read_picat_token(InStream,_,NextToken),
parse_indexing_subscripts(InStream,Dims,NextToken,RangesR)
).
parse_indexing_subscript(_InStream,Dim,']',Range) => Range = (1,Dim). % []
parse_indexing_subscript(InStream,_Dim,FromIndex,Range) =>
Index = FromIndex+1,
read_picat_token(InStream,_,Token1),
(Token1 == '..' ->
read_picat_token(InStream,_,ToIndex), % must be an int
skip_until_1(InStream,']'),
Range = (Index,ToIndex+1)
; % Token1 == ']'
Range = Index
).
access_array(E,[],List,ListR) =>
List = [E|ListR].
access_array(Arr,[(From,To)|Ranges],List,ListR) =>
access_array_aux(Arr,From,To,Ranges,List,ListR).
access_array(Arr,[E|Ranges],List,ListR) =>
access_array_aux(Arr,E,E,Ranges,List,ListR).
access_array_aux(_Arr,Index,ToIndex,_Ranges,List,ListR), Index > ToIndex =>
List = ListR.
access_array_aux(Arr,Index,ToIndex,Ranges,List,ListR) =>
access_array(Arr[Index],Ranges,List,List1),
access_array_aux(Arr,Index+1,ToIndex,Ranges,List1,ListR).
% "set(" [integer ("," integer)*] ")"
parse_intSet(InStream,_set,VarMap,Set) =>
Set = [E|SetR],
skip_until_1(InStream,'('),
read_picat_token(InStream,_,Token1),
parse_intExp(InStream,Token1,VarMap,E),
read_picat_token(InStream,_,Token2),
read_intSetPrime(InStream,Token2,VarMap,SetR).
read_intSetPrime(InStream,',',VarMap,Set) =>
Set = [E|SetR],
read_picat_token(InStream,_,Token1),
parse_intExp(InStream,Token1,VarMap,E),
read_picat_token(InStream,_,Token2),
read_intSetPrime(InStream,Token2,VarMap,SetR).
read_intSetPrime(_InStream,_Token,_VarMap,Set) =>
Set = [].
bool_rel(lt) => true.
bool_rel(le) => true.
bool_rel(ge) => true.
bool_rel(gt) => true.
bool_rel(ne) => true.
bool_rel(eq) => true.
bool_rel(in) => true.
bool_rel(not) => true.
bool_rel(and) => true.
bool_rel(or) => true.
bool_rel(xor) => true.
bool_rel(iff) => true.
bool_rel(imp) => true.
xcsp_start_intExp(neg) => true.
xcsp_start_intExp(abs) => true.
xcsp_start_intExp(add) => true.
xcsp_start_intExp(sub) => true.
xcsp_start_intExp(mul) => true.
xcsp_start_intExp(div) => true.
xcsp_start_intExp(mod) => true.
xcsp_start_intExp(sqr) => true.