Filter Invert Colors

[jeremywilliams]

This is more of a question, is it possible to enable the capability to invert video colors on Web Chimera? If not, is there a way to build in this capability?

[RSATom]

Didn't find any libvlc option for it, and didn't find any QML effect, but it's still doable by modify shader a little bit at https://github.com/RSATom/QmlVlc/blob/master/SGVlcVideoNode.cpp#L76

[jeremywilliams]

Ah great thank you!

[colek42]

we are having some trouble compiling the source fron the current HEAD of master. vs2013 is giving the error mismatch detected for 'RuntimeLibrary': value 'MD_DynamicRelease' doesn't match value 'MT_StaticRelease' in Chimera.obj. Any suggestions? We have some custom QML files so we need to compile from source.

[RSATom]

Try delete build folder and rerun prep script

[RSATom]

I've found how to solve this task solely on QML level:

    VlcVideoSurface {
        id: s1;
        source: vlcPlayer;
        anchors.fill: parent;
    }
    ShaderEffect {
        property variant source: ShaderEffectSource { sourceItem: s1; hideSource: true }
        anchors.fill: parent

        fragmentShader: "
            varying highp vec2 qt_TexCoord0;
            uniform sampler2D source;
            void main(void)
            {
                lowp vec4 tex = texture2D( source, qt_TexCoord0 );
                gl_FragColor = vec4( 1. - tex.r, 1. - tex.g, 1. - tex.b, tex.a );
            }
        "
    }

Btw, maybe it will be interesting to you, I've released proof-of-concept of desktop WebChimera: https://github.com/RSATom/WebChimera-desktop/releases

[sclem]

@RSATom,

The invert filter worked great. How can I hide it at runtime? I tried setting visible: false, but it hides the VlcVideoSurface as well. I also tried opacity: 0. I've got my javascript functions hooked up with emitJsMessage on WebChimeraPlayer. and in Functions.qml.

[RSATom]

I think you should try set hideSource = false first. If it will not help - I'll try find solution. I think it should be something simple.

[sclem]

Just tried hideSource = false, no effect? Let me know if you find another solution, thanks!

[RSATom]

following works for me:

    VlcPlayer {
        id: vlcPlayer;
        mrl: "http://download.blender.org/peach/bigbuckbunny_movies/big_buck_bunny_480p_stereo.avi";
    }
    VlcVideoSurface {
        id: s1
        source: vlcPlayer;

        anchors.centerIn: parent;
        width: parent.width / 2;
        height: parent.height / 2;
    }
    ShaderEffectSource {
        id: shaderSource;
        sourceItem: s1;
        hideSource: true;
    }
    ShaderEffect {
        id: shaderEffect;
        anchors.centerIn: parent;
        width: parent.width / 2;
        height: parent.height / 2;

        property variant source: shaderSource;

        fragmentShader: "
            varying highp vec2 qt_TexCoord0;
            uniform sampler2D source;
            void main(void)
            {
                lowp vec4 tex = texture2D( source, qt_TexCoord0 );
                gl_FragColor = vec4( 1. - tex.r, 1. - tex.g, 1. - tex.b, tex.a );
            }
        "
    }
    MouseArea {
        anchors.fill: parent
        onClicked: { shaderSource.hideSource = !shaderSource.hideSource; shaderEffect.visible =  shaderSource.hideSource; }
    }

[sclem]

You're the man. That worked perfect, thanks!

[RSATom]

I'm glad to see you happy :)