Ported simple.js to coffeescript

Gruntfile.coffee

@@ -26,6 +26,12 @@ module.exports = (grunt) ->
       index:
         files:
           'index.js': 'index.coffee'
+      examples:
+        expand: true
+        cwd: 'examples'
+        src: ['*.coffee']
+        dest: 'examples'
+        ext: '.js'
       classes:
         expand: true
         cwd: 'src'

examples/simple_reverse.coffee

@@ -0,0 +1,89 @@
+# This is a simple example of how to use the slack-client module in CoffeeScript. It creates a
+# bot that responds to all messages in all channels it is in with a reversed
+# string of the text received.
+#
+# To run, copy your token below, then, from the project root directory:
+#
+# To run the script directly
+#    npm install
+#    node_modules/coffee-script/bin/coffee examples/simple_reverse.coffee 
+#
+# If you want to look at / run / modify the compiled javascript
+#    npm install
+#    node_modules/coffee-script/bin/coffee -c examples/simple_reverse.coffee 
+#    cd examples
+#    node simple_reverse.js
+#
+
+Slack = require '..'
+
+token = 'xoxb-YOUR-TOKEN-HERE' # Add a bot at https://my.slack.com/services/new/bot and copy the token here.
+autoReconnect = true
+autoMark = true
+
+slack = new Slack(token, autoReconnect, autoMark)
+
+slack.on 'open', ->
+  channels = []
+  groups = []
+  unreads = slack.getUnreadCount()
+
+  # Get all the channels that bot is a member of
+  channels = ("##{channel.name}" for id, channel of slack.channels when channel.is_member)
+
+  # Get all groups that are open and not archived 
+  groups = (group.name for id, group of slack.groups when group.is_open and not group.is_archived)
+
+  console.log "Welcome to Slack. You are @#{slack.self.name} of #{slack.team.name}"
+  console.log 'You are in: ' + channels.join(', ')
+  console.log 'As well as: ' + groups.join(', ')
+
+  messages = if unreads is 1 then 'message' else 'messages'
+
+  console.log "You have #{unreads} unread #{messages}"
+
+
+slack.on 'message', (message) ->
+  channel = slack.getChannelGroupOrDMByID(message.channel)
+  user = slack.getUserByID(message.user)
+  response = ''
+
+  {type, ts, text} = message
+
+  channelName = if channel?.is_channel then '#' else ''
+  channelName = channelName + if channel then channel.name else 'UNKNOWN_CHANNEL'
+
+  userName = if user?.name? then "@#{user.name}" else "UNKNOWN_USER"
+
+  console.log """
+    Received: #{type} #{channelName} #{userName} #{ts} "#{text}"
+  """
+
+  # Respond to messages with the reverse of the text received.
+  if type is 'message' and text? and channel?
+    response = text.split('').reverse().join('')
+    channel.send response
+    console.log """
+      @#{slack.self.name} responded with "#{response}"
+    """
+  else
+    #this one should probably be impossible, since we're in slack.on 'message' 
+    typeError = if type isnt 'message' then "unexpected type #{type}." else null
+    #Can happen on delete/edit/a few other events
+    textError = if not text? then 'text was undefined.' else null
+    #In theory some events could happen with no channel
+    channelError = if not channel? then 'channel was undefined.' else null
+
+    #Space delimited string of my errors
+    errors = [typeError, textError, channelError].filter((element) -> element isnt null).join ' '
+
+    console.log """
+      @#{slack.self.name} could not respond. #{errors}
+    """
+
+
+slack.on 'error', (error) ->
+  console.error "Error: #{error}"
+
+
+slack.login()