build.gradle

buildscript {
    repositories {
        maven {
            url 'https://plugins.gradle.org/m2'
        }
    }

    dependencies {
        classpath 'gradle.plugin.net.minecrell:licenser:0.4.1'
    }
}

group = 'me.tassu.cfg'

version = "1.0.01"

defaultTasks 'licenseFormat', 'build'

subprojects {
    apply plugin: 'java'
    apply plugin: 'net.minecrell.licenser'

    apply plugin: 'maven'
    apply plugin: 'maven-publish'

    group = rootProject.group
    version = rootProject.version

    sourceCompatibility = 1.8
    targetCompatibility = 1.8

    tasks.withType(JavaCompile) {
        options.encoding = 'UTF-8'
    }

    jar {
        from '../LICENSE'
    }

    license {
        header = rootProject.file('LICENSE')
        include '**/*.java'
        newLine = true
    }

    repositories {
        mavenCentral()
        maven {
            url 'https://maven.tassu.me/'
            name 'tassu-repo'
        }
        maven {
            name 'sponge'
            url 'https://repo.spongepowered.org/maven'
        }
    }

    task sourcesJar(type: Jar) {
        from sourceSets.main.allJava
        classifier = 'sources'
    }

    task javadocJar(type: Jar) {
        from javadoc
        classifier = 'javadoc'
    }

    publishing {
        publications {
            maven(MavenPublication) {
                artifact sourcesJar
                artifact javadocJar

                from components.java
            }
        }

        repositories {
            maven { url "file:///home/tassu/maven" }
        }
    }
}