Example query showing incorrect results

[lllama]

The Locate vpcs with no ec2 instances, rds instances lambdas or ENIs attached. query returns all VPCs in my account, including those containing EC2 instances, etc.

Apologies but my SPARQL isn't quite sharp enough to spot the issue.

[jbmchuck]

Thanks - I believe the query should be:

select ?account_id ?region_name ?vpc_id
where {
    ?vpc        a                          <alti:aws:ec2:vpc> ;
                <alti:account>             ?account ;
                <alti:region>              ?region ;
                <alti:id>                  ?vpc_id ;
                <alti:is_default>          ?is_default .
    
    ?region     <alti:name>                ?region_name .
    
    ?account    <alti:account_id>          ?account_id .
        
    FILTER NOT EXISTS { ?resource   a                   ?resource_type ;
                                    <alti:vpc>          ?vpc .
                        FILTER ( ?resource_type IN
                            (   
                                <alti:aws:ec2:instance>,
                                <alti:aws:rds:db>,
                                <alti:aws:lambda:function>,
                                <alti:aws:ec2:network-interface>
                            )
                        )
    }                            
}
order by ?account_id ?region_name ?vpc_id

LMK if that works in your environment and I'll update the docs.

[lllama]

Excellent - thanks! That now returns all of my default VPCs, which is the expected result.

[jbmchuck]

Thanks! Fixed by 236e37f