Patch "interrupt-map" properties to contain the phandles from SLOF

huth · huth · commit 82954d4c1088 · 2011-10-12T16:24:55.000+02:00
The flattened device tree from QEMU contains some "phandle" and "linux,phandle"
properties which are referenced from the "interrupt-map" properties in the
pci root nodes. This is bad, since SLOF has a different concept of phandles.
Now the code patches the "interrupt-map" properties to contain the values
from SLOF and removes the "phandle" and "linux,phandle" properties from the
device tree.

Signed-off-by: Thomas Huth &lt;thuth@linux.vnet.ibm.com&gt;
diff --git a/board-qemu/slof/fdt.fs b/board-qemu/slof/fdt.fs
@@ -232,6 +232,102 @@ fdt-parse-memory
 ;
 fdt-claim-reserve 
 
+
+\ The following functions are use to replace the FDT phandle and
+\ linux,phandle properties with our own OF1275 phandles...
+
+\ This is used to check whether we successfully replaced a phandle value
+0 VALUE (fdt-phandle-replaced)
+
+\ Replace phandle value in "interrupt-map" property
+: fdt-replace-interrupt-map  ( old new prop-addr prop-len -- old new )
+   BEGIN
+      dup                    ( old new prop-addr prop-len prop-len )
+   WHILE
+      \ This is a little bit ugly ... we're accessing the property at
+      \ hard-coded offsets instead of analyzing it completely...
+      swap dup 10 +          ( old new prop-len prop-addr prop-addr+10 )
+      dup l@ 5 pick = IF
+          \ it matches the old phandle value!
+          3 pick swap l!
+          TRUE TO (fdt-phandle-replaced)
+      ELSE
+          drop
+      THEN
+      ( old new prop-len prop-addr )
+      1c + swap 1c -
+      ( old new new-prop-addr new-prop-len )
+   REPEAT
+   2drop
+;
+
+\ Replace one FDT phandle "old" with a OF1275 phandle "new" in the
+\ whole tree:
+: fdt-replace-all-phandles ( old new node -- )
+   \ ." Replacing in " dup node>path type cr
+   >r
+   s" interrupt-map" r@ get-property 0= IF
+      ( old new prop-addr prop-len  R: node )
+      fdt-replace-interrupt-map
+   THEN
+   s" interrupt-parent" r@ get-property 0= IF
+      ( old new prop-addr prop-len  R: node )
+      decode-int -rot 2drop                  ( old new val  R: node )
+      2 pick = IF                            ( old new      R: node )
+         dup encode-int s" interrupt-parent" r@ set-property
+         TRUE TO (fdt-phandle-replaced)
+      THEN
+   THEN
+   \ ... add more properties that have to be fixed here ...
+   r>
+   \ Now recurse over all child nodes:       ( old new node )
+   child BEGIN
+      dup
+   WHILE
+      3dup RECURSE
+      PEER
+   REPEAT
+   3drop
+;
+
+\ Check whether a node has "phandle" or "linux,phandle" properties
+\ and replace them:
+: fdt-fix-node-phandle  ( node -- )
+   >r
+   FALSE TO (fdt-phandle-replaced)
+   s" phandle" r@ get-property 0= IF
+      decode-int                       ( p-addr2 p-len2 val )
+      \ ." found phandle: " dup . cr
+      r@ s" /" find-node               ( p-addr2 p-len2 val node root )  
+      fdt-replace-all-phandles         ( p-addr2 p-len2 )
+      2drop
+      (fdt-phandle-replaced) IF
+         r@ set-node
+         s" phandle" delete-property
+         s" linux,phandle" delete-property
+      ELSE
+         cr ." Warning: Did not replace phandle in " r@ node>path type cr
+      THEN
+   THEN
+   r> drop
+;
+
+\ Recursively walk through all nodes to fix their phandles:
+: fdt-fix-phandles  ( node -- )
+   \ ." fixing phandles of " dup node>path type cr
+   dup fdt-fix-node-phandle
+   child BEGIN
+      dup
+   WHILE
+      dup RECURSE
+      PEER
+   REPEAT
+   drop
+   device-end
+;
+s" /" find-node fdt-fix-phandles
+
+
 \ Remaining bits from root.fs
 
 defer (client-exec)
