Merge pull request #135 from UkioInc/feature/vector-stores-api

feat: add support for new stable Vector Stores API

Author: restlessronin

lib/openai_ex/vector_stores.ex

@@ -0,0 +1,79 @@
+defmodule OpenaiEx.VectorStores do
+  @moduledoc """
+  This module provides an implementation of the OpenAI vector_stores API. The API reference can be found at https://platform.openai.com/docs/api-reference/vector-stores.
+  """
+  alias OpenaiEx.Http
+
+  @api_fields [
+    :file_ids,
+    :name,
+    :expires_after,
+    :metadata
+  ]
+
+  defp ep_url(vector_store_id \\ nil) do
+    "/vector_stores" <>
+      if(is_nil(vector_store_id), do: "", else: "/#{vector_store_id}")
+  end
+
+  @doc """
+  Creates a new vector store request
+
+  Example usage:
+
+      iex> _request = OpenaiEx.VectorStores.new(name: "My Vector Store", file_ids: ["file-abc123"])
+      %{name: "My Vector Store", file_ids: ["file-abc123"]}
+
+      iex> _request = OpenaiEx.VectorStores.new(%{name: "My Vector Store", metadata: %{"version" => "1.0"}})
+      %{name: "My Vector Store", metadata: %{"version" => "1.0"}}
+  """
+  def new(args = [_ | _]) do
+    args |> Enum.into(%{}) |> new()
+  end
+
+  def new(args = %{}) do
+    args |> Map.take(@api_fields)
+  end
+
+  def list!(openai = %OpenaiEx{}) do
+    openai |> list() |> Http.bang_it!()
+  end
+
+  def list(openai = %OpenaiEx{}) do
+    openai |> Http.get(ep_url())
+  end
+
+  def create!(openai = %OpenaiEx{}, params \\ %{}) do
+    openai |> create(params) |> Http.bang_it!()
+  end
+
+  def create(openai = %OpenaiEx{}, params \\ %{}) do
+    json = params |> Map.take(@api_fields)
+    openai |> Http.post(ep_url(), json: json)
+  end
+
+  def retrieve!(openai = %OpenaiEx{}, vector_store_id) do
+    openai |> retrieve(vector_store_id) |> Http.bang_it!()
+  end
+
+  def retrieve(openai = %OpenaiEx{}, vector_store_id) do
+    openai |> Http.get(ep_url(vector_store_id))
+  end
+
+  def update!(openai = %OpenaiEx{}, vector_store_id, params \\ %{}) do
+    openai |> update(vector_store_id, params) |> Http.bang_it!()
+  end
+
+  def update(openai = %OpenaiEx{}, vector_store_id, params \\ %{}) do
+    json = params |> Map.take([:name, :expires_after, :metadata])
+    openai |> Http.post(ep_url(vector_store_id), json: json)
+  end
+
+  def delete!(openai = %OpenaiEx{}, vector_store_id) do
+    openai |> delete(vector_store_id) |> Http.bang_it!()
+  end
+
+  def delete(openai = %OpenaiEx{}, vector_store_id) do
+    openai |> Http.delete(ep_url(vector_store_id))
+  end
+end

lib/openai_ex/vector_stores_file_batches.ex

@@ -0,0 +1,50 @@
+defmodule OpenaiEx.VectorStores.File.Batches do
+  @moduledoc """
+  This module provides an implementation of the OpenAI vector_store file batches API. The API reference can be found at https://platform.openai.com/docs/api-reference/vector-stores-file-batches.
+  """
+  alias OpenaiEx.Http
+
+  defp ep_url(vector_store_id, batch_id \\ nil, action \\ nil) do
+    "/vector_stores" <>
+      if(is_nil(vector_store_id), do: "", else: "/#{vector_store_id}") <>
+      "/file_batches" <>
+      if(is_nil(batch_id), do: "", else: "/#{batch_id}") <>
+      if(is_nil(action), do: "", else: "/#{action}")
+  end
+
+  def list!(openai = %OpenaiEx{}, vector_store_id, batch_id, params \\ %{}) do
+    openai |> list(vector_store_id, batch_id, params) |> Http.bang_it!()
+  end
+
+  def list(openai = %OpenaiEx{}, vector_store_id, batch_id, params \\ %{}) do
+    url = ep_url(vector_store_id, batch_id, "files")
+    qry_params = params |> Map.take([:filter | OpenaiEx.list_query_fields()])
+    openai |> Http.get(url, qry_params)
+  end
+
+  def create!(openai = %OpenaiEx{}, vector_store_id, file_ids) do
+    openai |> create(vector_store_id, file_ids) |> Http.bang_it!()
+  end
+
+  def create(openai = %OpenaiEx{}, vector_store_id, file_ids) do
+    url = ep_url(vector_store_id)
+    openai |> Http.post(url, json: %{file_ids: file_ids})
+  end
+
+  def retrieve!(openai = %OpenaiEx{}, vector_store_id, batch_id) do
+    openai |> retrieve(vector_store_id, batch_id) |> Http.bang_it!()
+  end
+
+  def retrieve(openai = %OpenaiEx{}, vector_store_id, batch_id) do
+    openai |> Http.get(ep_url(vector_store_id, batch_id))
+  end
+
+  def cancel!(openai = %OpenaiEx{}, vector_store_id, batch_id) do
+    openai |> cancel(vector_store_id, batch_id) |> Http.bang_it!()
+  end
+
+  def cancel(openai = %OpenaiEx{}, vector_store_id, batch_id) do
+    url = ep_url(vector_store_id, batch_id, "cancel")
+    openai |> Http.post(url)
+  end
+end

lib/openai_ex/vector_stores_files.ex

@@ -0,0 +1,50 @@
+defmodule OpenaiEx.VectorStores.Files do
+  @moduledoc """
+  This module provides an implementation of the OpenAI vector_store files API. The API reference can be found at https://platform.openai.com/docs/api-reference/vector-stores-files.
+  """
+  alias OpenaiEx.Http
+
+  defp ep_url(vector_store_id, file_id \\ nil) do
+    "/vector_stores" <>
+      if(is_nil(vector_store_id), do: "", else: "/#{vector_store_id}") <>
+      "/files" <>
+      if(is_nil(file_id), do: "", else: "/#{file_id}")
+  end
+
+  def list!(openai = %OpenaiEx{}, vector_store_id, params \\ %{}) do
+    openai |> list(vector_store_id, params) |> Http.bang_it!()
+  end
+
+  def list(openai = %OpenaiEx{}, vector_store_id, params \\ %{}) do
+    qry_params = params |> Map.take([:filter | OpenaiEx.list_query_fields()])
+    openai |> Http.get(ep_url(vector_store_id), qry_params)
+  end
+
+  def create!(openai = %OpenaiEx{}, vector_store_id, file_id, params \\ %{}) do
+    openai |> create(vector_store_id, file_id, params) |> Http.bang_it!()
+  end
+
+  def create(openai = %OpenaiEx{}, vector_store_id, file_id, params \\ %{}) do
+    json =
+      %{file_id: file_id}
+      |> Map.merge(params |> Map.take([:attributes]))
+
+    openai |> Http.post(ep_url(vector_store_id), json: json)
+  end
+
+  def retrieve!(openai = %OpenaiEx{}, vector_store_id, file_id) do
+    openai |> retrieve(vector_store_id, file_id) |> Http.bang_it!()
+  end
+
+  def retrieve(openai = %OpenaiEx{}, vector_store_id, file_id) do
+    openai |> Http.get(ep_url(vector_store_id, file_id))
+  end
+
+  def delete!(openai = %OpenaiEx{}, vector_store_id, file_id) do
+    openai |> delete(vector_store_id, file_id) |> Http.bang_it!()
+  end
+
+  def delete(openai = %OpenaiEx{}, vector_store_id, file_id) do
+    openai |> Http.delete(ep_url(vector_store_id, file_id))
+  end
+end

notebooks/userguide.livemd

@@ -1522,9 +1522,9 @@ assts = openai |> Assistants.list()
 ## Vector Stores
 
 ```elixir
-alias OpenaiEx.Beta.VectorStores
-alias OpenaiEx.Beta.VectorStores.Files
-alias OpenaiEx.Beta.VectorStores.File.Batches
+alias OpenaiEx.VectorStores
+alias OpenaiEx.VectorStores.Files
+alias OpenaiEx.VectorStores.File.Batches
 ```
 
 ### Create vector store
@@ -1588,6 +1588,24 @@ vector_store_id = vector_store["id"]
 {:ok, vs_file} = openai |> VectorStores.Files.create(vector_store_id, file_id)
 ```
 
+### Create vector store file with attributes
+
+The new stable API supports adding attributes (metadata) to vector store files:
+
+```elixir
+# Create a file with attributes for better organization
+file_params = %{
+  attributes: %{
+    "source" => "hr_documentation",
+    "category" => "policies",
+    "priority" => "high",
+    "last_updated" => "2024-01-15"
+  }
+}
+
+{:ok, vs_file_with_attrs} = openai |> VectorStores.Files.create(vector_store_id, file_id, file_params)
+```
+
 ### Retrieve vector store file
 
 Retrieve a vector store file using the [`VectorStores.Files.retrieve()`](https://platform.openai.com/docs/api-reference/vector-stores-files/getFile) function

test/openai_ex_test.exs

@@ -11,4 +11,5 @@ defmodule OpenaiExTest do
   doctest OpenaiEx.Beta.Threads.Runs
   doctest OpenaiEx.Containers
   doctest OpenaiEx.ContainerFiles
+  doctest OpenaiEx.VectorStores
 end