Add meck:received/3 API for easier history checking

src/meck.erl

@@ -33,6 +33,7 @@
 -export([validate/1]).
 -export([unload/0]).
 -export([unload/1]).
+-export([called/3]).
 
 %% Callback exports
 -export([init/1]).
@@ -218,6 +219,16 @@ unload() -> lists:foldl(fun unload_if_mocked/2, [], registered()).
 unload(Mod) when is_atom(Mod) -> call(Mod, stop), wait_for_exit(Mod);
 unload(Mods) when is_list(Mods) -> [unload(Mod) || Mod <- Mods], ok.
 
+%% @spec called(Mod:: atom(), Fun:: atom(), Args:: list(term())) -> boolean()
+%% @doc Returns whether `Mod:Func` has been called with `Args`.
+%%
+%% This will check the history for the module, Mod, to determine
+%% whether the function, Fun, was called with arguments, Args. If so,
+%% this function returns true, otherwise false.
+-spec called(Mod::atom(), Fun::atom(), Args::list()) -> boolean().
+called(Mod, Fun, Args) ->
+    has_call({Mod, Fun, Args}, meck:history(Mod)).
+
 %%==============================================================================
 %% Callback functions
 %%==============================================================================
@@ -328,6 +339,14 @@ unload_if_mocked(P, L) when length(P) > 5 ->
 unload_if_mocked(_P, L) ->
     L.
 
+has_call({_M, _F, _A}, []) -> false;
+has_call({M, F, A}, [{{M, F, A}, _Result} | _Rest]) ->
+    true;
+has_call({M, F, A}, [{{M, F, A}, _ExType, _Exception, _Stack} | _Rest]) ->
+    true;
+has_call({M, F, A}, [_Call | Rest]) ->
+    has_call({M, F, A}, Rest).
+
 %% --- Mock handling -----------------------------------------------------------
 
 init_expects(Mod, Options) ->

test/meck_tests.erl

@@ -55,7 +55,16 @@ meck_test_() ->
                            fun shortcut_expect_negative_arity_/1,
                            fun shortcut_call_return_value_/1,
                            fun shortcut_call_argument_/1,
-                           fun delete_/1]]}.
+                           fun delete_/1,
+                           fun received_false_no_args_/1,
+                           fun received_true_no_args_/1,
+                           fun received_false_one_arg_/1,
+                           fun received_true_one_arg_/1,
+                           fun received_false_few_args_/1,
+                           fun received_true_few_args_/1,
+                           fun received_false_error_/1,
+                           fun received_true_error_/1
+                          ]]}.
 
 setup() ->
     % Uncomment to run tests with dbg:
@@ -283,6 +292,76 @@ delete_(Mod) ->
     ?assertError(undef, Mod:test(a, b)),
     ?assert(meck:validate(Mod)).
 
+received_false_no_args_(Mod) ->
+    Args = [],
+    ok = meck:expect(Mod, test, length(Args), ok),
+    ?assertEqual(false, meck:called(Mod, test, Args)),
+    ?assert(meck:validate(Mod)).
+
+received_true_no_args_(Mod) ->
+    Args = [],
+    ok = meck:expect(Mod, test, length(Args), ok),
+    ok = Mod:test(),
+    ?assertEqual(true, meck:called(Mod, test, Args)),
+    ?assert(meck:validate(Mod)).
+
+received_false_one_arg_(Mod) ->
+    Arg = "hello",
+    Args = [Arg],
+    ok = meck:expect(Mod, test, length(Args), ok),
+    ?assertEqual(false, meck:called(Mod, test, [Arg])),
+    ?assert(meck:validate(Mod)).
+
+received_true_one_arg_(Mod) ->
+    Arg = "hello",
+    Args = [Arg],
+    ok = meck:expect(Mod, test, length(Args), ok),
+    ok = Mod:test(Arg),
+    ?assertEqual(true, meck:called(Mod, test, [Arg])),
+    ?assert(meck:validate(Mod)).
+
+received_false_few_args_(Mod) ->
+    Arg1 = one,
+    Arg2 = 2,
+    Arg3 = {three, 3},
+    Arg4 = "four",
+    Args = [Arg1, Arg2, Arg3, Arg4],
+    ok = meck:expect(Mod, test, length(Args), ok),
+    ?assertEqual(false, meck:called(Mod, test, Args)),
+    ?assert(meck:validate(Mod)).
+
+received_true_few_args_(Mod) ->
+    Arg1 = one,
+    Arg2 = 2,
+    Arg3 = {three, 3},
+    Arg4 = "four",
+    Args = [Arg1, Arg2, Arg3, Arg4],
+    ok = meck:expect(Mod, test, length(Args), ok),
+    ok = Mod:test(Arg1, Arg2, Arg3, Arg4),
+    ?assertEqual(true, meck:called(Mod, test, Args)),
+    ?assert(meck:validate(Mod)).
+
+received_false_error_(Mod) ->
+    Arg1 = one,
+    Arg2 = "two",
+    Arg3 = {3, 3},
+    Args = [Arg1, Arg2, Arg3],
+    TestFun = fun (_, _, _) -> meck:exception(error, my_error) end,
+    ok = meck:expect(Mod, test, TestFun),
+    ?assertEqual(false, meck:called(Mod, test, Args)),
+    ?assert(meck:validate(Mod)).
+
+received_true_error_(Mod) ->
+    Arg1 = one,
+    Arg2 = "two",
+    Arg3 = {3, 3},
+    Args = [Arg1, Arg2, Arg3],
+    TestFun = fun (_, _, _) -> meck:exception(error, my_error) end,
+    ok = meck:expect(Mod, test, TestFun),
+    catch Mod:test(Arg1, Arg2, Arg3),
+    ?assertEqual(true, meck:called(Mod, test, Args)),
+    ?assert(meck:validate(Mod)).
+
 %% --- Tests with own setup ----------------------------------------------------
 
 call_original_test() ->