Fzf with arg or with word under cursor

[danihodovic]

Is it possible to call fzf or fzf#tags with the word under the cursor or pass an argument to fzf.vim so that it expands fzf with the argument? If not, how difficult would this be to implement?

[danihodovic]

Seems like the plugin is pretty extensible. I got it to work with

fu! FzfTagsCurrWord()
  let currWord = expand('<cword>')
  if len(currWord) > 0
    call fzf#vim#tags({'options': '-q ' . currWord})
  else
    execute ':Tags'
  endif
endfu

[junegunn]

Nice, you can further simplify the code like follows, no need for if-else branch:

call fzf#vim#tags({'options': '-q '.shellescape(expand('<cword>'))})

Note that :Tags command passes layout option as well.

call fzf#vim#tags({'options': '-q '.shellescape(expand('<cword>')), 'down': '~40%'})

Is there anything else you want to know?

[danihodovic]

Cool!

Is it possible to do this with :Ag too? Provide the word under cursor or a visual selection?

[junegunn]

This is what I have in my .vimrc.

nnoremap <silent> <Leader>ag :Ag <C-R><C-W><CR>

Looks like we can now close the issue.

[danihodovic]

👍

[cj]

@junegunn when I try your solution in nvim I get this error

[junegunn]

@cj Right, the function signature was changed in b9285c8

So you can now simply do this:

call fzf#vim#tags(expand('<cword>'))

[cj]

@junegunn ah, there we go. thank you!

[ghost]

@junegunn : it's beautiful.

[xarthna]

Taking cues from this thread, I mapped over <c-]> to act like :tjump to jump to the tag if a single match or open it with FZF otherwise:

function! FzfTagsCurrentWord()
  let l:word = expand('<cword>')
  let l:list = taglist(l:word)
  if len(l:list) == 1
    execute ':tag ' . l:word
  else
    call fzf#vim#tags(l:word)
  endif
endfunction

noremap <c-]> :call FzfTagsCurrentWord()<cr>

[shaypal5]

Just adding for those preferring to search the current word in :Ag:

" map <Leader>+F to search in ag the word under the cursor
map <Leader>F :call fzf#vim#ag(expand('<cword>'))<kEnter>

[martinklepsch]

This is pretty awesome! Is there a way to have it show the preview like :Ag does as well?

EDIT: I found that the following does show a preview :)

nnoremap <silent><Leader>r :Rg <C-R><C-W><CR>

[shaypal5]

Awesome! I stole your version! Why Rg and not Ag, though?

Edit: Oh, to use ripgrep instead of The Silver Searcher, right?

[nornagon]

Here's what I ended up with to ripgrep for the token under the cursor (i.e. the whole word, not as a substring of another token):

nnoremap <silent>+ :call fzf#vim#grep(
  \ "rg --column --line-number --no-heading --color=always --smart-case -- "
  \ . fzf#shellescape('\b'.expand('<cword>').'\b'),
  \ fzf#vim#with_preview(), 0)<cr>

(it's too bad there's no fzf#vim#rg like there is fzf#vim#ag, that would have made this snippet a lot shorter! As it is, this is copied from the definition of :Rg, as below)

fzf.vim/plugin/fzf.vim

Line 63 in 1e054c1

\'command! -bang -nargs=* Rg call fzf#vim#grep("rg --column --line-number --no-heading --color=always --smart-case -- ".fzf#shellescape(<q-args>), fzf#vim#with_preview(), <bang>0)',