elementary-icon-theme: add theme

recipes-art/elementaryicons/elementary-icon-theme-enable.bb

@@ -0,0 +1,17 @@
+DESCRIPTION = "Enable elementary-icon-theme in gtkrc"
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
+
+RDEPENDS_${PN} = "elementary-icon-theme"
+
+ALLOW_EMPTY_${PN} = "1"
+PACKAGE_ARCH = "all"
+
+pkg_postinst() {
+#!/bin/sh
+mkdir -p $D${sysconfdir}/gtk-2.0
+touch $D${sysconfdir}/gtk-2.0/gtkrc
+sed -i /gtk-icon-theme-name/d $D${sysconfdir}/gtk-2.0/gtkrc
+echo 'gtk-icon-theme-name = "elementary"' >> $D${sysconfdir}/gtk-2.0/gtkrc
+}

recipes-art/elementaryicons/elementary-icon-theme_2.7.1.bb

@@ -0,0 +1,30 @@
+DESCRIPTION = "Icon theme from the Elementary project"
+SECTION = "x11/icons"
+HOMEPAGE = "http://www.elementary-project.com/"
+
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://elementary-icon-theme/elementary/COPYING;md5=94d55d512a9ba36caa9b7df079bae19f"
+
+inherit gtk-icon-cache
+
+# We have to get the icons from a mirror (LaunchPad) as DeviantArt has a download 
+# wrapper to stop simple HTTP gets :(.
+
+SRC_URI = " \
+  http://launchpad.net/elementaryicons/2.0/${PV}/+download/elementary-icon-theme-${PV}.tar.gz;name=regular;subdir=${BPN}-${PV} \
+"
+
+SRC_URI[regular.md5sum] = "fc4580641089a09cbcf7df38ebddd807"
+SRC_URI[regular.sha256sum] = "4cfe73d9da3f6262a724bd787126dcbf0957b107e3f36d22a0baf60fef7706e6"
+
+do_install() {
+	install -d ${D}${datadir}/icons/elementary/
+	install -d ${D}${datadir}/icons/elementary-mono-dark/	
+
+	cp -R ${S}/elementary-icon-theme/elementary/* ${D}${datadir}/icons/elementary/
+	cp -R ${S}/elementary-icon-theme/elementary-mono-dark/* ${D}${datadir}/icons/elementary-mono-dark/
+}
+
+FILES_${PN} = "${datadir}/icons/elementary*"
+RDEPENDS_${PN} += "gnome-icon-theme"
+PACKAGE_ARCH = "all"