Oracle: Add DATE and TIMESTAMP support

Closes #41

Author: salortiz

lib/DBDish/Connection.pm6

@@ -40,6 +40,7 @@ method drv { $.parent }
 method new(*%args) {
     my \con = ::?CLASS.bless(|%args);
     con.reset-err;
+    con.?set-defaults;
     %args<parent>.Connections{con.WHICH} = con;
 }
 

lib/DBDish/Oracle/Connection.pm6

@@ -32,6 +32,13 @@ method prepare(Str $statement, :$RaiseError = $!RaiseError, *%attr) {
     } else { .fail }
 }
 
+method set-defaults {
+    self.do(
+	q|ALTER SESSION SET nls_timestamp_tz_format='YYYY-MM-DD"T"HH24:MI:SS.FFTZR'|
+    );
+    $!last-sth-id = Nil; # Lie a little.
+}
+
 method commit {
     if $!AutoCommit {
         warn "Commit ineffective while AutoCommit is on";

lib/DBDish/Oracle/Native.pm6

@@ -84,14 +84,18 @@ constant SQLT_NUM               is export = 2;
 constant SQLT_INT               is export = 3;
 constant SQLT_FLT               is export = 4;
 constant SQLT_STR               is export = 5;
+constant SQLT_DAT               is export = 12;
 constant SQLT_BIN               is export = 23;
+constant SQLT_TIMESTAMP_TZ      is export = 188;
 
 constant %sqltype-map is export = {
     +(SQLT_CHR) => Str,
     +(SQLT_NUM) => Rat,
     +(SQLT_INT) => Int,
     +(SQLT_FLT) => Num,
-    +(SQLT_BIN) => Buf
+    +(SQLT_BIN) => Buf,
+    +(SQLT_TIMESTAMP_TZ) => DateTime,
+    +(SQLT_DAT) => Date,
 };
 
 constant OCISnapshot  is export = Pointer;

lib/DBDish/Oracle/StatementHandle.pm6

@@ -59,7 +59,7 @@ method !get-meta {
                 my $col_name = $parmd.AttrGet($!errh, utf8, OCI_ATTR_NAME);
                 my $dtype    = $parmd.AttrGet($!errh, ub2, OCI_ATTR_DATA_TYPE);
                 my $datalen  = $parmd.AttrGet($!errh, ub4, OCI_ATTR_DATA_SIZE);
-                my $wtype    = SQLT_CHR;
+                my $wtype    = SQLT_CHR; # Sane default
                 my $buff     = do given $dtype {
                     #note "$col_name: $dtype ($datalen)";
                     when SQLT_NUM {
@@ -72,6 +72,8 @@ method !get-meta {
                     when SQLT_FLT { $wtype = $_; array[num64].new(0e0); }
                     when SQLT_INT { $wtype = $_; Buf[int64].new(0); }
                     when SQLT_BIN { $wtype = $_; proceed; }
+                    when SQLT_DAT { $wtype = $_; proceed; }
+                    when SQLT_TIMESTAMP_TZ { $datalen = 50; proceed; }
                     default { blob-allocate(Buf, $datalen); }
                 }
                 my $bind = OCIDefine.new;
@@ -103,6 +105,11 @@ method execute(*@params) {
                 $!in-indicator[$k] = 0;
                 when Blob { $btype = SQLT_BIN; $v }
                 when Str { .encode }
+                when Date {
+                    $btype = SQLT_DAT;
+                    Blob.new($v.year div 100 + 100, $v.year mod 100 + 100,
+                             $v.month, $v.day, 1, 1, 1);
+                }
                 default { .Str.encode}
             } else {
                 $!in-indicator[$k] = -1;
@@ -151,7 +158,19 @@ method _row() {
                             when Int | Num { $res[0] }
                             $res .= subbuf(0, $!out-lengths[$col]);
                             when Blob { $res }
+                            when Date {
+                                my $year = ($res[0]-100)*100 + $res[1]-100;
+                                Date.new(:$year,:month($res[2]),:day($res[3]));
+                            }
+                            when DateTime {
+                                if $res.bytes == 7 {
+                                    my $year = ($res[0]-100)*100 + $res[1]-100;
+                                    DateTime.new(:$year,:month($res[2]),:day($res[3]),
+                                         :hour($res[4]),:minute($res[5]),:second($res[6]));
+                                } else { proceed; }
+                            }
                             $res .= decode;
+                            when DateTime { DateTime.new($res) }
                             when Rat { $res.Rat }
                             default { $res }
                         }

t/47-oracle-datetime.t

@@ -0,0 +1,82 @@
+use v6;
+use Test;
+use DBIish;
+
+plan 13;
+
+my %con-parms = :database<XE>, :username<TESTUSER>, :password<Testpass>;
+my $dbh;
+
+try {
+  $dbh = DBIish.connect('Oracle', |%con-parms);
+  CATCH {
+	    when X::DBIish::LibraryMissing | X::DBDish::ConnectionFailed {
+		diag "$_\nCan't continue.";
+	    }
+            default { .throw; }
+  }
+}
+without $dbh {
+    skip-rest 'prerequisites failed';
+    exit;
+}
+
+ok $dbh,    'Connected';
+my $dropper = q|
+    BEGIN
+       EXECUTE IMMEDIATE 'DROP TABLE test';
+    EXCEPTION
+       WHEN OTHERS THEN
+          IF SQLCODE != -942 THEN
+             RAISE;
+          END IF;
+    END;|;
+
+lives-ok { $dbh.do($dropper) }, 'Clean';
+lives-ok {
+    $dbh.do(qq|
+    CREATE TABLE test (
+	adate DATE,
+	atimestamp TIMESTAMP(6) WITH TIME ZONE
+    )|);
+}, 'Table created';
+
+my $sth = $dbh.prepare(
+    q|INSERT INTO test (adate, atimestamp) VALUES(?, ?)|);
+my $now = DateTime.now;
+
+lives-ok {
+    $sth.execute(
+	$now.Date, # Need a date
+	$now,
+    );
+},                                           'Can insert Perl6 values';
+$sth.dispose;
+
+$sth = $dbh.prepare('SELECT adate, atimestamp FROM test');
+my @coltype = $sth.column-types;
+ok @coltype eqv [Date, DateTime],	    'Column-types match';
+
+$sth.execute;
+my ($date, $datetime) = $sth.row;
+isa-ok $date, Date;
+isa-ok $datetime,  DateTime;
+
+is $date, $now.Date,			    'Today';
+is $datetime, $now,			    'Right now';
+$sth.dispose;
+
+$sth = $dbh.prepare('SELECT SYSDATE FROM dual');
+isa-ok $sth.column-types[0], Date, 'SYSDATE is Date';
+$sth.execute;
+is $sth.row[0], Date.today,		    'Today';
+$sth.dispose;
+
+$sth = $dbh.prepare('SELECT CURRENT_TIMESTAMP FROM dual');
+isa-ok $sth.column-types[0], DateTime, 'CURRENT_TIMESTAMP is DateTime';
+$sth.execute;
+my $datetime2 = $sth.row[0];
+isnt $datetime, $datetime2,		    'Server drift';
+diag $datetime2.Instant - $datetime.Instant;
+
+$dbh.do($dropper);