Basic MOP-level support for role arguments.

There's no syntactic sugar for it, but this allows provision of role
arguments in order to do a mix-in of the parameterized role.

Author: jnthn

src/how/NQPCurriedRoleHOW.pm

@@ -0,0 +1,37 @@
+knowhow NQPCurriedRoleHOW {
+    has $!curried_role;
+    has @!pos_args;
+    
+    my $archetypes := Archetypes.new( :nominal(1), :composable(1), :parametric(1) );
+    method archetypes() {
+        $archetypes
+    }
+    
+    method new(:$curried_role!, :@pos_args!) {
+        my $obj := nqp::create(self);
+        $obj.BUILD(:$curried_role, :@pos_args);
+        $obj
+    }
+
+    method BUILD(:$curried_role!, :@pos_args!) {
+        $!curried_role := $curried_role;
+        @!pos_args := @pos_args;
+    }
+    
+    method new_type($curried_role!, *@pos_args) {
+        my $meta := self.new(:curried_role($curried_role), :pos_args(@pos_args));
+        pir::repr_type_object_for__PPS($meta, 'Uninstantiable');
+    }
+    
+    method specialize($obj, $class_arg) {
+        $!curried_role.HOW.specialize($!curried_role, $class_arg, |@!pos_args);
+    }
+    
+    method name($obj) {
+        $!curried_role.HOW.name($!curried_role)
+    }
+    
+    method curried_role($obj) {
+        $!curried_role
+    }
+}

src/how/NQPParametricRoleHOW.pm

@@ -108,13 +108,18 @@ knowhow NQPParametricRoleHOW {
     method parametric($obj) {
         1
     }
+    
+    # Curries this parametric role with arguments.
+    method curry($obj, *@args) {
+        NQPCurriedRoleHOW.new_type($obj, |@args)
+    }
 
     # This specializes the role for the given class and builds a concrete
     # role.
-    method specialize($obj, $class_arg) {
+    method specialize($obj, $class_arg, *@args) {
         # Run the body block to capture the arguments into the correct
         # type argument context.
-        $!body_block($class_arg);
+        $!body_block($class_arg, |@args);
 
         # Construct a new concrete role.
         my $irole := NQPConcreteRoleHOW.new_type(:name($!name), :instance_of($obj));

tools/build/Makefile.in

@@ -179,9 +179,10 @@ NQP_SOURCES = \
 
 NQP_MO_SOURCES = src/how/Archetypes.pm src/how/RoleToRoleApplier.pm \
                  src/how/NQPConcreteRoleHOW.pm src/how/RoleToClassApplier.pm \
-                 src/how/NQPParametricRoleHOW.pm src/how/NQPClassHOW.pm \
-                 src/how/NQPNativeHOW.pm src/how/NQPAttribute.pm \
-                 src/how/NQPModuleHOW.pm src/how/EXPORTHOW.pm \
+                 src/how/NQPCurriedRoleHOW.pm src/how/NQPParametricRoleHOW.pm \
+                 src/how/NQPClassHOW.pm src/how/NQPNativeHOW.pm \
+                 src/how/NQPAttribute.pm src/how/NQPModuleHOW.pm \
+                 src/how/EXPORTHOW.pm \
 
 NQP_MO_PBC      = nqpmo.pbc
 NQP_MO_PIR      = gen/nqp-mo.pir