Merge pull request #5 from grondilu/master

adding six other solutions for Rosalind

Author: grondilu

rosalind/cons-grondilu.pl

@@ -0,0 +1,24 @@
+use v6;
+my @s = $*IN.lines;
+my \N = @s.pick.chars;
+
+my %profile;
+%profile{$_} = [0 xx N] for <A C G T>;
+
+for @s[] {
+    my @dna = .comb;
+    for kv classify { @dna[$_] }, ^@dna -> $k, $v {
+        %profile{$k}[$v[]]»++;
+    }
+}
+my @profile = %profile<A C G T>;
+
+say my $consensus = [~] gather
+for ^N -> \c {
+    my $max = max map { @profile[$_][c] }, ^4;
+    take <A C G T>[$_] given first { @profile[$_][c] == $max }, ^4;
+}
+
+say .key, ': ', @profile[.value] for enum <A C G T>;
+
+# vim: ft=perl6

rosalind/conv-grondilu.pl

@@ -0,0 +1,8 @@
+#!/usr/bin/perl
+use v6;
+my ($a, $b) = $*IN.lines;
+
+my %conv; %conv{$_}++ for $a.split(/\s+/) X- $b.split(/\s+/);
+.say for max(:by(*.value), %conv).kv.reverse;
+
+# vim: ft=perl6

rosalind/mrna-grondilu.pl

@@ -0,0 +1,35 @@
+use v6;
+constant RNA-codon = Hash.new: <
+UUU F      CUU L      AUU I      GUU V
+UUC F      CUC L      AUC I      GUC V
+UUA L      CUA L      AUA I      GUA V
+UUG L      CUG L      AUG M      GUG V
+UCU S      CCU P      ACU T      GCU A
+UCC S      CCC P      ACC T      GCC A
+UCA S      CCA P      ACA T      GCA A
+UCG S      CCG P      ACG T      GCG A
+UAU Y      CAU H      AAU N      GAU D
+UAC Y      CAC H      AAC N      GAC D
+UAA Stop   CAA Q      AAA K      GAA E
+UAG Stop   CAG Q      AAG K      GAG E
+UGU C      CGU R      AGU S      GGU G
+UGC C      CGC R      AGC S      GGC G
+UGA Stop   CGA R      AGA R      GGA G
+UGG W      CGG R      AGG R      GGG G 
+>;
+
+sub mrna($rna) {
+    my %count;
+    %count{.value}++ for RNA-codon;
+
+    my $count = 1;
+    for $rna.comb, 'Stop' {
+        $count *= %count{$_};
+        $count %= 1_000_000;
+    }
+    return $count;
+}
+
+say mrna $*IN.get;
+
+# vim: ft=perl6

rosalind/orf-grondilu.pl

@@ -0,0 +1,38 @@
+use v6;
+constant DNA-codon = Hash.new: <
+    TTT F      CTT L      ATT I      GTT V
+    TTC F      CTC L      ATC I      GTC V
+    TTA L      CTA L      ATA I      GTA V
+    TTG L      CTG L      ATG M      GTG V
+    TCT S      CCT P      ACT T      GCT A
+    TCC S      CCC P      ACC T      GCC A
+    TCA S      CCA P      ACA T      GCA A
+    TCG S      CCG P      ACG T      GCG A
+    TAT Y      CAT H      AAT N      GAT D
+    TAC Y      CAC H      AAC N      GAC D
+    TAA Stop   CAA Q      AAA K      GAA E
+    TAG Stop   CAG Q      AAG K      GAG E
+    TGT C      CGT R      AGT S      GGT G
+    TGC C      CGC R      AGC S      GGC G
+    TGA Stop   CGA R      AGA R      GGA G
+    TGG W      CGG R      AGG R      GGG G 
+>;
+sub revc($dna) {
+    $dna.comb.reverse.join.trans:
+    [<A C T G>] => [<T G A C>]
+}
+
+sub orf($dna) {
+    my %match;
+    my @match = gather for $dna, revc $dna {
+    take .match: rx/ ATG [ <[ACGT]>**3 ]*? <before TAA|TAG|TGA> /, :overlap;
+    };
+    %match{
+    [~] map { DNA-codon{$_} }, .match: rx/ <[ACGT]>**3 /, :g
+    }++ for @match;
+    return %match.keys;
+}
+
+.say for orf $*IN.get;
+
+# vim: ft=perl6

rosalind/spec-grondilu.pl

@@ -0,0 +1,36 @@
+use v6;
+constant monoisotopic-mass-table = Hash.new: <
+    A   71.03711
+    C   103.00919
+    D   115.02694
+    E   129.04259
+    F   147.06841
+    G   57.02146
+    H   137.05891
+    I   113.08406
+    K   128.09496
+    L   113.08406
+    M   131.04049
+    N   114.04293
+    P   97.05276
+    Q   128.05858
+    R   156.10111
+    S   87.03203
+    T   101.04768
+    V   99.06841
+    W   186.07931
+    Y   163.06333 
+>;
+
+sub spec(@weight, :$accuracy = .01) {
+    my @a = my @b = sort *.Num, @weight;
+    join '', gather
+    for @b[1..*] Z- @b[0..*] -> $mass {
+        take .key given
+        first { abs($_.value - $mass) < $accuracy },
+        monoisotopic-mass-table;
+    }
+}
+print spec $*IN.lines;
+
+# vim: ft=perl6

rosalind/sseq-grondilu.pl

@@ -0,0 +1,10 @@
+use v6;
+my ($dna, $search) = $*IN.lines;
+
+my $pos = 0;
+say gather for $search.comb -> $c {
+    $dna ~~ m:c($pos)/$c/;
+    take $pos = $/.from + 1;
+}
+
+# vim: ft=perl6