Add a did-you-mean function for fuzzy matching

Previously only usable for finding the closest commit, now generalized
for everything else.

Author: AlexDaniel

lib/Whateverable/Bits.pm6

@@ -58,6 +58,25 @@ my token commit-list is export {
     [<-[\s] -[‘,’]>+]+ % [‘,’\s*]
 }
 
+#| Get the closest fuzzy match
+sub did-you-mean($string, @options, :$default=Nil,
+                 :$max-offset=7, :$max-distance=10) is export {
+    my $answer = $default;
+    my $answer-min = ∞;
+    my $distance-limit = $max-distance + 1;
+
+    use Text::Diff::Sift4;
+    for @options {
+        my $distance = sift4 $_, $string, $max-offset, $distance-limit;
+        if $distance < $answer-min {
+            $answer = $_;
+            $answer-min = $distance;
+        }
+    }
+    return $default if $answer-min > $max-distance;
+    $answer
+}
+
 sub time-left(Instant() $then, :$already-there?) is export {
     my $time-left = $then - now;
     return $already-there if $already-there and $time-left < 0;

lib/Whateverable/Builds.pm6

@@ -198,18 +198,8 @@ sub get-similar($tag-or-hash, @other?, :$repo=$CONFIG<rakudo>) is export {
                       .lines.map(*.substr: 0, $cutoff);
 
     # flat(@options, @tags, @commits).min: { sift4($_, $tag-or-hash, 5, 8) }
-    my $ans = ‘HEAD’;
-    my $ans_min = ∞;
-
-    use Text::Diff::Sift4;
-    for flat @options, @tags, @commits {
-        my $dist = sift4 $_, $tag-or-hash, $cutoff;
-        if $dist < $ans_min {
-            $ans = $_;
-            $ans_min = $dist;
-        }
-    }
-    $ans
+    did-you-mean $tag-or-hash, flat(@options, @tags, @commits),
+                 :default(‘HEAD’), :max-offset($cutoff);
 }
 
 # vim: expandtab shiftwidth=4 ft=perl6