Support configuring ENTRYPOINT and CMD

[vito]

This change brings Bass closer to alignment with Dagger and Docker with how ENTRYPOINT/CMD (aka "default args") are handled.

Quick terminology note: "default args" is a modern spin on CMD since everyone should be using ENTRYPOINT these days and in that context CMD actually behaves as default args to the entrypoint. Dagger uses this new terminology, and so will Bass.

The tl;dr:

• Thunks can now configure an entrypoint and default args. These are primarily useful for publishing containers, but they are also used within Bass in situations described below.

  (-> (from (linux/busybox)
        ($ sh -c "echo hello, world > /srv/index.html"))
      (with-entrypoint ["httpd" "-f" "-p" "8000"])
      (with-default-args ["-h" "/srv"])
      (with-port :http 8000))

• ($ foo) does use the entrypoint. This is intentional, and mirrors RUN in Dockerfiles.

  (from (linux/alpine/git)                        ; has entrypoint ["git"]
    ($ git clone "https://github.com/vito/bass")) ; same as before

• ($$) has been added for running a command using the entrypoint, replacing any default args.

  (from (linux/alpine/git)
    ($$ clone "https://github.com/vito/bass")) ; uses entrypoint ["git"]

• When a thunk has no args and is forced to run, it runs the entrypoint + default args.

  (run (linux/hello-world))

• (resolve) (and by extension (linux/foo)) now return a thunk instead of a nebulous "image type" that was really just a scope with certain fields.

  (assert thunk? (linux/alpine/git))

• (docker-build) also now returns a thunk, and (oci-load) has been added to assist with turning OCI tarballs into thunks.

  (assert thunk? (docker-build *dir* {:os "linux"}))
  (assert thunk? (oci-load build/image.tar {:os "linux"}))

• Internal refactor: thunks no longer have a "command" separate from "args" - just args.

Here are the tests, which probably tell the story more thoroughly:

(use (.strings)
     (*dir*/lib/oci.bass))

(defn entrypoint [thunk]
  (let [config (oci:config thunk)]
    (:Entrypoint config null)))

(defn read-all [thunk]
  (next (read thunk :raw)))

; entrypoint is not respected by ($)
(assert = "git version 2.36.3\n"
  (read-all
    (from (linux/alpine/git :2.36.3)
      ($ git --version))))

; entrypoint is respected by ($$)
(assert = "git version 2.36.3\n"
  (read-all
    (from (linux/alpine/git)
      ($$ --version))))

; entrypoint is preserved even after ($) ignores it
(assert = ["git"]
  (entrypoint
    (from (linux/alpine/git)
      ($ git --version))))

; entrypoint is used when running image directly
(assert null?
  (run (linux/hello-world)))

; entrypoint is used when reading output
(assert strings:includes?
  (read-all (linux/hello-world))
  "Hello from Docker")

; entrypoint is used when reading output path
(assert = "hello\n"
  (read-all
    (-> (linux/alpine)
        (with-entrypoint ["sh" "-c" "echo hello > index.html"])
        (subpath ./index.html))))

; entrypoint is removed when set to empty list
(assert null?
  (entrypoint
    (-> (linux/alpine/git :2.36.3)
        (with-entrypoint []))))

; entrypoint can be set by thunk
(def touch-and-run
  (-> (from (linux/busybox)
        ($ sh -c "echo hello from index.html > index.html"))
      (with-port :http 8000)
      (with-entrypoint ["httpd" "-f" "-p" "8000"])))

(assert = ["httpd" "-f" "-p" "8000"]
  (entrypoint touch-and-run))

; entrypoint is preserved from thunk to thunk
(assert = ["httpd" "-f" "-p" "8000"]
  (entrypoint
    (from touch-and-run
      ($ echo "Hello, world!"))))

; entrypoint is still used after running a command
(assert = "hello from index.html\n"
  (read-all
    (from (linux/alpine)
      ($ wget -O- (addr touch-and-run :http "http://$host:$port/")))))

• Documentation
• The implementation is, unfortunately, a bit confusing. But it works, and I think the surface-level semantics are intuitive. Probably ripe for a refactor/remodel someday.