Support for non-Unicode encodings (requested by SteP)

When the encoding option is set to something other than UTF-8 the
plug-in will no longer try to insert curly quotes, dashes or bullets in
the user's notes and special characters in shadow notes will be
transcoded on the fly to their ASCII equivalents.

Author: xolox

autoload/xolox/notes.vim

@@ -22,6 +22,9 @@ function! xolox#notes#edit(bang, title) abort " {{{1
     let fname = xolox#notes#select(title)
     if fname != ''
       execute 'edit' . a:bang fnameescape(fname)
+      if !xolox#notes#unicode_enabled() && xolox#misc#path#equals(fnamemodify(fname, ':h'), g:notes_shadowdir)
+        call s:transcode_utf8_latin1()
+      endif
       setlocal filetype=notes
       call xolox#misc#timer#stop('%s: Opened note in %s.', s:script, starttime)
       return
@@ -36,6 +39,9 @@ function! xolox#notes#edit(bang, title) abort " {{{1
     let fname = xolox#misc#path#merge(g:notes_shadowdir, 'New note')
     execute 'silent read' fnameescape(fname)
     1delete
+    if !xolox#notes#unicode_enabled()
+      call s:transcode_utf8_latin1()
+    endif
     setlocal nomodified
   endif
   if title != 'New note'
@@ -45,6 +51,31 @@ function! xolox#notes#edit(bang, title) abort " {{{1
   call xolox#misc#timer#stop('%s: Started new note in %s.', s:script, starttime)
 endfunction
 
+function! xolox#notes#edit_shadow() " {{{1
+  " People using latin1 don't like the UTF-8 curly quotes and bullets used in
+  " the predefined notes because there are no equivalent characters in latin1,
+  " resulting in the characters being shown as garbage or a question mark.
+  execute 'edit' fnameescape(expand('<amatch>'))
+  if !xolox#notes#unicode_enabled()
+    call s:transcode_utf8_latin1()
+  endif
+  setlocal filetype=notes
+endfunction
+
+function! xolox#notes#unicode_enabled()
+  return &encoding == 'utf-8'
+endfunction
+
+function! s:transcode_utf8_latin1()
+  let view = winsaveview()
+  silent %s/\%xe2\%x80\%x98/`/eg
+  silent %s/\%xe2\%x80\%x99/'/eg
+  silent %s/\%xe2\%x80[\x9c\x9d]/"/eg
+  silent %s/\%xe2\%x80\%xa2/\*/eg
+  setlocal nomodified
+  call winrestview(view)
+endfunction
+
 function! xolox#notes#select(filter) " {{{1
   " Interactively select an existing note whose title contains {filter}.
   let notes = {}
@@ -425,13 +456,22 @@ function! xolox#notes#insert_quote(style) " {{{3
   " XXX When I pass the below string constants as arguments from the file type
   " plug-in the resulting strings contain mojibake (UTF-8 interpreted as
   " latin1?) even if both scripts contain a UTF-8 BOM! Maybe a bug in Vim?!
-  let [open_quote, close_quote] = a:style == 1 ? ['‘', '’'] : ['“', '”']
+  if xolox#notes#unicode_enabled()
+    let [open_quote, close_quote] = a:style == 1 ? ['‘', '’'] : ['“', '”']
+  else
+    let [open_quote, close_quote] = a:style == 1 ? ['`', "'"] : ['"', '"']
+  endif
   return getline('.')[col('.')-2] =~ '\S$' ? close_quote : open_quote
 endfunction
 
-function! xolox#notes#insert_bullet(c) " {{{3
+function! xolox#notes#insert_bullet(chr) " {{{3
   " Insert a UTF-8 list bullet when the user types "*".
-  return getline('.')[0 : max([0, col('.') - 2])] =~ '^\s*$' ? '•' : a:c
+  if xolox#notes#unicode_enabled()
+    if getline('.')[0 : max([0, col('.') - 2])] =~ '^\s*$'
+      return '•'
+    endif
+  endif
+  return a:chr
 endfunction
 
 function! xolox#notes#indent_list(command, line1, line2) " {{{3
@@ -440,7 +480,7 @@ function! xolox#notes#indent_list(command, line1, line2) " {{{3
     call setline(a:line1, repeat(' ', &tabstop))
   else
     execute a:line1 . ',' . a:line2 . 'normal' a:command
-    if getline('.') =~ '•$'
+    if getline('.') =~ '\(•\|\*\)$'
       call setline('.', getline('.') . ' ')
     endif
   endif

ftplugin/notes.vim

@@ -1,6 +1,6 @@
 " Vim file type plug-in
 " Author: Peter Odding <peter@peterodding.com>
-" Last Change: January 7, 2011
+" Last Change: May 22, 2011
 " URL: http://peterodding.com/code/vim/notes/
 
 if exists('b:did_ftplugin')
@@ -22,7 +22,11 @@ setlocal tabstop=3 shiftwidth=3 expandtab
 let b:undo_ftplugin .= ' tabstop< shiftwidth< expandtab<'
 
 " Automatic formatting for bulleted lists. {{{1
-let &l:comments = ': • ,:> '
+if xolox#notes#unicode_enabled()
+  let &l:comments = ': • ,: * ,:> '
+else
+  let &l:comments = ': * ,:> '
+endif
 let &l:commentstring = '> %s'
 setlocal formatoptions=tcron
 let b:undo_ftplugin .= ' commentstring< comments< formatoptions<'
@@ -44,8 +48,10 @@ setlocal includeexpr=xolox#notes#include_expr(v:fname)
 let b:undo_ftplugin .= ' includeexpr<'
 
 " Change double-dash to em-dash as it is typed. {{{1
-imap <buffer> -- —
-let b:undo_ftplugin .= ' | execute "iunmap <buffer> --"'
+if xolox#notes#unicode_enabled()
+  imap <buffer> -- —
+  let b:undo_ftplugin .= ' | execute "iunmap <buffer> --"'
+endif
 
 " Change plain quotes to curly quotes as they're typed. {{{1
 imap <buffer> <expr> ' xolox#notes#insert_quote(1)
@@ -54,10 +60,12 @@ let b:undo_ftplugin .= ' | execute "iunmap <buffer> ''"'
 let b:undo_ftplugin .= ' | execute ''iunmap <buffer> "'''
 
 " Change ASCII style arrows to Unicode arrows. {{{1
-imap <buffer> -> →
-imap <buffer> <- ←
-let b:undo_ftplugin .= ' | execute "iunmap <buffer> ->"'
-let b:undo_ftplugin .= ' | execute "iunmap <buffer> <-"'
+if xolox#notes#unicode_enabled()
+  imap <buffer> -> →
+  imap <buffer> <- ←
+  let b:undo_ftplugin .= ' | execute "iunmap <buffer> ->"'
+  let b:undo_ftplugin .= ' | execute "iunmap <buffer> <-"'
+endif
 
 " Convert ASCII list bullets to Unicode bullets. {{{1
 imap <buffer> <expr> - xolox#notes#insert_bullet('-')
@@ -68,12 +76,10 @@ let b:undo_ftplugin .= ' | execute "iunmap <buffer> +"'
 let b:undo_ftplugin .= ' | execute "iunmap <buffer> *"'
 
 " Indent list items using <Tab>. {{{1
-
 imap <buffer> <silent> <Tab> <C-o>:call xolox#notes#indent_list('>>', line('.'), line('.'))<CR>
 smap <buffer> <silent> <Tab> <C-o>:<C-u>call xolox#notes#indent_list('>>', line("'<"), line("'>"))<CR><C-o>gv
 let b:undo_ftplugin .= ' | execute "iunmap <buffer> <Tab>"'
 let b:undo_ftplugin .= ' | execute "sunmap <buffer> <Tab>"'
-
 imap <buffer> <silent> <S-Tab> <C-o>:call xolox#notes#indent_list('<<', line('.'), line('.'))<CR>
 smap <buffer> <silent> <S-Tab> <C-o>:<C-u>call xolox#notes#indent_list('<<', line("'<"), line("'>"))<CR><C-o>gv
 let b:undo_ftplugin .= ' | execute "iunmap <buffer> <S-Tab>"'

misc/notes/shadow/Note taking syntax

@@ -7,7 +7,7 @@ notes plug-in.
 
 Lines prefixed with one or more ‘#’ symbols are headings which can be used for
 automatic text folding. There’s also an alternative heading format which isn’t
-folded, it consists of a line shorten than 60 letters that starts with an
+folded, it consists of a line shorter than 60 letters that starts with an
 uppercase letter and ends in a colon (the hard wrapping in this paragraph
 illustrates why the “starts with uppercase” rule is needed):
 
@@ -26,7 +26,7 @@ Hyper links and such:
 
 # Lists
 
-Bulleted lists can be used for to do lists:
+Bulleted lists can be used for to-do lists:
  • DONE Publish my notes.vim plug-in
  • TODO Write an indent script for atx headings
  • XXX This one is really important
@@ -39,7 +39,7 @@ Numbered lists are also supported:
 # Block quotes
 
 > Quotes are written using
-> the convention from e-mail 
+> the convention from e-mail
 
 # Embedded syntax highlighting
 

plugin/notes.vim

@@ -3,7 +3,7 @@
 " Last Change: May 22, 2011
 " URL: http://peterodding.com/code/vim/notes/
 " License: MIT
-" Version: 0.8.6
+" Version: 0.8.7
 
 " Support for automatic update using the GLVS plug-in.
 " GetLatestVimScripts: 3375 1 :AutoInstall: notes.zip
@@ -65,6 +65,7 @@ augroup PluginNotes
   " NB: "nested" is used here so that SwapExists automatic commands apply
   " to notes (which is IMHO better than always showing the E325 prompt).
   au BufReadCmd note:* nested call xolox#notes#shortcut()
+  call s:DAC('BufReadCmd', g:notes_shadowdir, 'call xolox#notes#edit_shadow()')
   call s:DAC('BufWriteCmd', g:notes_directory, 'call xolox#notes#save()')
   au SwapExists * call xolox#notes#swaphack()
   au WinEnter * if &ft == 'notes' | call xolox#notes#highlight_names(0) | endif

syntax/notes.vim

@@ -1,6 +1,6 @@
 " Vim syntax script
 " Author: Peter Odding <peter@peterodding.com>
-" Last Change: March 25, 2011
+" Last Change: May 22, 2011
 " URL: http://peterodding.com/code/vim/notes/
 
 " Note: This file is encoded in UTF-8 including a byte order mark so
@@ -28,13 +28,17 @@ syntax cluster notesInline add=notesName
 highlight def link notesName Underlined
 
 " Highlight list bullets and numbers. {{{2
-syntax match notesListBullet /^\s*\zs•/
+syntax match notesListBullet /^\s*\zs\(•\|\*\)/
 highlight def link notesListBullet Comment
 syntax match notesListNumber /^\s*\zs\d\+[[:punct:]]\?\ze\s/
 highlight def link notesListNumber Comment
 
 " Highlight quoted fragments (inside single quotes). {{{2
-syntax match notesQuotedFragment /‘.\{-}’/
+if xolox#notes#unicode_enabled()
+  syntax match notesQuotedFragment /‘.\{-}’/
+else
+  syntax match notesQuotedFragment /`.\{-}'/
+endif
 highlight def link notesQuotedFragment Special
 
 " Highlight text emphasized in italic font. {{{2