Reflect.field issues

[ubald]

The following code:

package ;
class Main {
    static public function main( ) {
        trace(Reflect.field(A,'STATIC_FIELD'));
        trace(Reflect.field(new A(),'STATIC_FIELD'));
        trace(Reflect.field(B,'STATIC_FIELD'));
        trace(Reflect.field(new B(),'STATIC_FIELD'));
        trace(Reflect.field(C,'STATIC_FIELD'));
        trace(Reflect.field(new C(),'STATIC_FIELD'));
    }
}

class A {
    static public var STATIC_FIELD : String = "A: hello world";
    public function new() {}
}

class B extends A {
    public function new() { super(); }
}

class C extends B {
    static public var STATIC_FIELD : String = "C: hello world";
    public function new() { super(); }
}

Running with Haxe 3.1.3, mac cpp target, traces the following:

Main.hx:4: A: hello world
Main.hx:5: A: hello world
Main.hx:6: A: hello world
Main.hx:7: A: hello world
Main.hx:8: C: hello world
Main.hx:9: C: hello world

While running with Haxe 3.2 rc2, mac cpp target, it traces the following:

Main.hx:4: A: hello world
Main.hx:5: null
Main.hx:6: null
Main.hx:7: null
Main.hx:8: C: hello world
Main.hx:9: null

[Simn]

This is a bugfix, static fields should not be listed as part of the instance fields. I have added a note in the breaking change overview: https://github.com/HaxeFoundation/haxe/wiki/Breaking-changes-in-Haxe-3.2.0

[ncannasse]

This is a fix in Haxe 3.2, CPP is now correctly aligned with other targets behaviors : Reflect.field on instance will not be able to access statics, you need to use Reflect.field(Type.getClass(new A()),"STATIC_FIELD") for that.

[ubald]

I was more relying on the fact that the static fields were kind of inherited using this method ;)

[ubald]

I ended up making a utility class to handle my needs

package com.ubald.utils;
class ReflectionUtil {
    static public function staticClassField( obj : Class<Dynamic>, field : String ) : Dynamic {
        var type : Class<Dynamic> = obj;
        var value : Dynamic = null;
        while( type != null ) {
            value = Reflect.field( type, field );
            if ( value != null ) {
                break;
            }
            type = Type.getSuperClass( type );
        }
        return value;
    }
    static public function staticInstanceField( obj : Dynamic, field : String ) : Dynamic {
        return staticClassField( Type.getClass( obj ), field );
    }
}

It works for me but while coding it I found out that Reflect.hasField( ChildClass, 'SOME_FIELD' ); returns true if the static field is on a parent class, but Reflect.field( ChildClass, 'SOME_FIELD'); returns null. They should at least have the same behavior.

[Simn]

@hughsando: Could you check that?

[hughsando]

This is now fixed on hxcpp to match neko. @Simn - Not sure if this is the "official" behaviour, and whether you want to add a test.