Ladybird/AppKit: Add color picker support

Author: bplaat

Ladybird/AppKit/UI/LadybirdWebView.mm

@@ -527,6 +527,20 @@ - (void)setWebViewCallbacks
                      returnCode:NSModalResponseCancel];
     };
 
+    m_web_view_bridge->on_request_color_picker = [self](Color current_color) {
+        auto* panel = [NSColorPanel sharedColorPanel];
+        [panel setColor:Ladybird::gfx_color_to_ns_color(current_color)];
+        [panel setShowsAlpha:NO];
+
+        NSNotificationCenter* notification_center = [NSNotificationCenter defaultCenter];
+        [notification_center addObserver:self
+                                selector:@selector(colorPickerClosed:)
+                                    name:NSWindowWillCloseNotification
+                                  object:panel];
+
+        [panel makeKeyAndOrderFront:nil];
+    };
+
     m_web_view_bridge->on_get_all_cookies = [](auto const& url) {
         auto* delegate = (ApplicationDelegate*)[NSApp delegate];
         return [delegate cookieJar].get_all_cookies(url);
@@ -603,6 +617,11 @@ - (void)setWebViewCallbacks
     };
 }
 
+- (void)colorPickerClosed:(NSNotification*)notification
+{
+    m_web_view_bridge->color_picker_closed(Ladybird::ns_color_to_gfx_color([[NSColorPanel sharedColorPanel] color]));
+}
+
 - (NSScrollView*)scrollView
 {
     return (NSScrollView*)[self superview];

Ladybird/AppKit/Utilities/Conversions.h

@@ -8,6 +8,7 @@
 
 #include <AK/String.h>
 #include <AK/StringView.h>
+#include <LibGfx/Color.h>
 #include <LibGfx/Point.h>
 #include <LibGfx/Rect.h>
 #include <LibGfx/Size.h>
@@ -30,4 +31,7 @@ NSSize gfx_size_to_ns_size(Gfx::IntSize);
 Gfx::IntPoint ns_point_to_gfx_point(NSPoint);
 NSPoint gfx_point_to_ns_point(Gfx::IntPoint);
 
+Gfx::Color ns_color_to_gfx_color(NSColor*);
+NSColor* gfx_color_to_ns_color(Gfx::Color);
+
 }

Ladybird/AppKit/Utilities/Conversions.mm

@@ -86,4 +86,25 @@ NSPoint gfx_point_to_ns_point(Gfx::IntPoint point)
         static_cast<CGFloat>(point.y()));
 }
 
+Gfx::Color ns_color_to_gfx_color(NSColor* color)
+{
+    auto rgb_color = [color colorUsingColorSpace:NSColorSpace.genericRGBColorSpace];
+    if (rgb_color != nil)
+        return {
+            static_cast<u8>([rgb_color redComponent] * 255),
+            static_cast<u8>([rgb_color greenComponent] * 255),
+            static_cast<u8>([rgb_color blueComponent] * 255),
+            static_cast<u8>([rgb_color alphaComponent] * 255)
+        };
+    return {};
+}
+
+NSColor* gfx_color_to_ns_color(Gfx::Color color)
+{
+    return [NSColor colorWithRed:(color.red() / 255.f)
+                           green:(color.green() / 255.f)
+                            blue:(color.blue() / 255.f)
+                           alpha:(color.alpha() / 255.f)];
+}
+
 }