WDT doesn't work on Portenta C33

[Spinnaker-design]

The WDT example doesn't reset the Portenta C33 if WDT.refresh() is commented out. It simply keeps running. This feature doesn't seem to be working at all.

Steps to Reproduce:

1. Run the WatchdogRefresh example on the Portenta C33
2. Comment out Line 62. WDT.refresh();
3. See the board does not reset.

[facchinm]

Hi Kyle,
I just retested the example and the C33 work as intended (blinks once, then resets and restarts executing the sketch). To confirm this behaviour just run this sketch

/*
  Watchdog Refresh

  This sketch shows how to enable the watchdog and
  refresh the timer to avoid resets

  Watchdog intervals are limited to 7 timeout periods
  the library will select the best clock divisor and timeout
  according to the selected wdtInterval.

  UNO R4 min wdtInterval 1ms / max wdtInterval 5592ms
  Comment out Serial.print() in the setup to make it work with
  small intervals

  Portenta C33 min wdtInterval 1ms / max wdtInterval 2684ms

  Circuit:
   - Portenta C33
   - UNO R4
*/

#include <WDT.h>

const long ledInterval = 1000;
unsigned long ledMillis = 0;
bool ledState = true;
const long wdtInterval = 2684;
unsigned long wdtMillis = 0;

void setup() {
  Serial.begin(9600);

  pinMode(LEDR, OUTPUT);
  pinMode(LEDG, OUTPUT);
  pinMode(LEDB, OUTPUT);

  if(wdtInterval < 1) {
    Serial.println("Invalid watchdog interval");
    while(1){}
  }

  if(WDT.begin(wdtInterval)) {
    Serial.print("WDT interval: ");
    WDT.refresh();
    Serial.print(WDT.getTimeout());
    WDT.refresh();
    Serial.println(" ms");
    WDT.refresh();
  } else {
    Serial.println("Error initializing watchdog");
    while(1){}
  }
}

void loop() {
  if(millis() - ledMillis >= ledInterval) {
    uint8_t led;
    int8_t index = (ledMillis / ledInterval) % 3;
    if (index == 0) {
      led = LEDR;
    } else if (index == 1) {
      led = LEDG;
    }  else {
      led  = LEDB;
    }
    digitalWrite(led, !digitalRead(led));
    ledState = !ledState;
    ledMillis = millis();
  }

  if(millis() - wdtMillis >= wdtInterval - 1) {
    WDT.refresh(); // Comment this line to stop refreshing the watchdog
    wdtMillis = millis();
  }
}

In the original sketch both the while !Serial and the fact that the led pattern is always the same could make you think that things are not working, while everything is good.
This was tested with core 1.0.5 and official Arduino IDE (not platform.io)